Excel-Daten nach Word-Vorlage

Forumthread: Excel-Daten nach Word-Vorlage

15.10.2002 10:58:04

Peer Semke

Aloha,

ich habe eine Excel-Tabelle und eine Word-Vorlage (*.dot) mit Formularfeldern. Die Vorlage ist schreibgeschützt, so dass nur Daten in die Formularfelder eingegeben werden können.
Nun möchte ich Daten bestimmter Zellen aus der Excel-Tabelle in die Formularfelder in ein Word-Dokument, welches auf der Vorlage basiert, eintragen lassen.

Im Excel-Datenblatt gibt es dafür eine Schaltfläche, der dann ein Makro zugewisen werden soll.

Was ich bisher erreicht habe:
Ein Klick auf die Schaltfläche in Excel startet Word. Es wird ein Dokument, basierend auf der Vorlage aufgerufen.

Was ich nicht schaffe:
Die Daten aus Excel werden nicht in die Formularfelder übernommen.

Für Hilfe bedanke ich mich schon mal vorab.
Peer Semke

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Re: Excel-Daten nach Word-Vorlage

15.10.2002 17:38:44

Simon Bruckmeier
Re: Excel-Daten nach Word-Vorlage

15.10.2002 17:48:07

Simon Bruckmeier
Re: Excel-Daten nach Word-Vorlage

16.10.2002 07:43:13

Peer Semke

Re: Excel-Daten nach Word-Vorlage

15.10.2002 17:38:44

Simon Bruckmeier

Hi.
Das ist ja lustig. Genau das gleiche Problem hab ich auch und wollt auch grad fragen.
Also, einen Tip hab ich schon. Erstelle in dem Formularfeld eine Textmarke (auch Bookmark) genannt. Die kann man irgendwie ansteuern. Von einem Word Makro aus geht das folgendermaßen:
Dann setzt er rechts von dem Bookmark "Name" das WOrt egal rein.

ActiveDocument.Bookmarks("Name").Range.Text = "egal"

Aber ich habe auch keine Ahnung, wie man spezielle Daten an Word überliefert.

Wer es weiß, nur zu.

Re: Excel-Daten nach Word-Vorlage

15.10.2002 17:48:07

Simon Bruckmeier

Lösung ???!!!:
Übergibt den Inhalt der Zelle A1 an die Stelle der Textmarke von "Name2"

nameexcel = Range("a1")

Set wrd = CreateObject("Word.Application")
ort = ("PLatz der Datei auf der Platte")

wrd.Visible = True
wrd.documents.Open ort
wrd.documents(ort).Bookmarks("Name2").Range.Text = nameexcel
wrd.documents.Close

Re: Excel-Daten nach Word-Vorlage

16.10.2002 07:43:13

Peer Semke

Aloha,

ich habs... ICH HABS... *grins*

Ich poste hier mal meinen Code:

Sub WordStarten()

'Statuszeile ausgeben
Application.StatusBar = "Starten von Word... Daten werden übertragen..."
'Word als Variable definieren
Dim appWD As Word.Application
'Word sichtbar starten
Set appWD = CreateObject("Word.Application")
appWD.Visible = True
'Vorlage als Dokument in Word öffnen
appWD.Documents.Add Template:="Z:\SemkeP\Vorlagen\Test.dot"
'Nach Word "umschalten"
AppActivate appWD

'Daten in Word übernehmen
BAProzentL = Range("BAProzentL").Value
LandProzentL = (100 - BAProzentL)
BAprozentS = (Range("BAProzentS").Value * 100)
LandProzentS = (Range("LandProzentS").Value * 100)

With appWD.ActiveDocument
.FormFields("abmnr1").Result = Range("MAnr").Value

.FormFields("beginn1").Result = Range("von").Value
.FormFields("ende1").Result = Range("bis").Value

.FormFields("trname").Result = Range("TrName").Value
.FormFields("tradresse").Result = Range("TrAdresse").Value
.FormFields("trort").Result = Range("TrOrt").Value
.FormFields("kbz").Result = Range("KBz").Value
.FormFields("gesabr").Result = Range("GesAbr").Value

.FormFields("pbal").Result = BAProzentL
.FormFields("plandl").Result = LandProzentL
.FormFields("pbas").Result = BAprozentS
.FormFields("plands").Result = LandProzentS

.FormFields("fbal").Result = Range("LohnBA").Value
.FormFields("gbal").Result = Range("LohnBA").Value
.FormFields("flandl").Result = Range("LohnLand").Value
.FormFields("glandl").Result = Range("LohnLand").Value
.FormFields("fbas").Result = Range("SachBA").Value
.FormFields("flands").Result = Range("SachLand").Value

.Fields.Update
End With
End Sub

Beliebteste Forumthreads (12 Monate)

Forumthread: Excel-Daten nach Word-Vorlage

3 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Beliebteste Forumthreads (12 Monate)

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread