Matrix Suche

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Heiner,
... wäre möglich, wenn es nicht viele hunderte Datensätze sind, die auszuwerten sind.
Es wäre aber auf jeden Fall dazu zu raten, die Datenliste in eine "intelligente" Datenliste um zu formatieren, damit man die Formelauswertung auf diese beziehen kann und damit unabhängig von evtl. nachträglicher Datenerweiterung ist.
Nachfolgend mal für bis zu 4 Kriterien und ohne "intelligente" Datenliste für z.B. 98 Datensätze. Wenn mehr Kriterien vorh./notwendig sind, kann die Formeldef. relativ einfach angepasst werden.
Auswahl der Kriterien erfolgt im Beispiel in E2:E5 (jeweils über Datengültigkeit; die aus E2 nach unten kopieren).
Die Formel A3 ist lediglich weit genug nach unten und bis in C3 zu kopieren.

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F	G
1	Name	Adresse	Ort	Krit. 1	Krit. 2	Krit. 3	Krit. 4
2	Name_1	Adr. 1	Ort_1			x
3	Name_2	Adr. 2	Ort_1	x	x	x	x
4	Name_3	Adr. 3	Ort_2	x
5	Name_4	Adr. 4	Ort_1		x		x
6	Name_5	Adr. 5	Ort_2	x	x
7	Name_6	Adr. 6	Ort_3		x	x	x
8	Name_7	Adr. 7	Ort_2	x		x	x
9

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

Arbeitsblatt mit dem Namen 'Tabelle3'
	A	B	C	D	E
1	Ergebnisliste				Kriterien
2	Name	Adresse	Ort		Krit. 4
3	Name_2	Adr. 2	Ort_1		Krit. 2
4	Name_6	Adr. 6	Ort_3		Krit. 3
5
6

Zelle	Formel
A3	=WENNFEHLER(INDEX(Tabelle1!A:A;AGGREGAT(15;6;ZEILE(A$2:A$99)/(MMULT(((Tabelle1!$D$2:$G$99="x")+0)*ZÄHLENWENN($E$2:$E$5;Tabelle1!$D$1:$G$1);ZEILE(E2:E5)^0)=ANZAHL2($E$2:$E$5));ZEILE(E1)));"")

Zelle	Gültigkeitstyp	Operator	Wert1	Wert2
E2	Liste		=Tabelle1!$D$1:$G$1

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010

Gruß Werner
.. , - ...

Hallo Heiner,
... würde ich momentan dazu raten, Deine "Auswahlliste" bis J10 zu erweitern (in der neuen Beispieldatei; bzw. allg. soviel Zellen, wie Du Kriterien in Deinen Rohdaten hast), auch wenn Du vielleicht max drei/vier Kriterien auswählen möchtest. Z.B. in der Datengültigkeit mit der Formel:
=WENN(ANZAHL2(J$2:J2)&lt4;Lagersystem;"")
Und in A3:

=WENNFEHLER(INDEX(Daten[[Firma]:[Referenzen]];
AGGREGAT(15;6;ZEILE(Daten[Firma])-ZEILE(Daten[#Kopfzeilen])/
(MMULT(((Daten[[Palettenregale]:[Sprinklerung]]="x")+0)*
ZÄHLENWENN(Auswahl[Kriterienauswahl];Lagersystem);ZEILE(Auswahl[Kriterienauswahl])^0)
=ANZAHL2(Auswahl[Kriterienauswahl]));ZEILE()-ZEILE(A$2));
VERGLEICH(A$2;Daten[#Kopfzeilen];0));"")
und Formel nach rechts und unten ziehend kopieren (Format für PLZ ... E-Mail danach noch anpassen)
Der Vorteil der "intelligenten" Tabellen ist neben der automatischen Berücksichtigung von Datenerweiterungen in den Rohdaten, dass Du beide Tabellen innerhalb der Arbeitsmappe beliebig verschieben kannst, ohne das die Formel angepasst werden muss.
Gruß Werner
.. , - ...

Beliebteste Forumthreads (12 Monate)

10 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

10
Beiträge zum Forumthread

Beiträge zu diesem Forumthread