Microsoft Excel

Herbers Excel/VBA-Archiv

index suchen

Betrifft: index suchen von: Udo
Geschrieben am: 29.03.2020 11:22:37

Hallo ich habe eine Tabelle gemacht, in der die Platzierungen mehrerer Saisonen festgehalten werden. Nun möchte ich unter Statistik das es mir den Namen des Spielers schreibt der die meisten ersten Plätze in welcher Saison usw anzeigt. Ich bitte um eure Hilfe.

mfg Udo


https://www.herber.de/bbs/user/136197.xlsx

Betrifft: AW: index suchen
von: Michel
Geschrieben am: 29.03.2020 13:02:11

Ciao Udo,

Ich würde die Daten anders anordnen.

https://www.herber.de/bbs/user/136201.xlsx

Somit kannst du eine einfache auswertung durchführen.
Du könntest auch pro Session ein eigenes Sheet erstellen, dann müsste man noch alle Daten einfach konsolidieren.

Liebe Grüsse
Michel

Betrifft: AW: index suchen
von: Udo
Geschrieben am: 29.03.2020 13:46:06

Dankesehr

Betrifft: AW: für die Tab mit drei Formeln realisierbar ...
von: neopa C
Geschrieben am: 29.03.2020 13:52:42

Hallo Udo,

... und zwar auch wenn es mehr Spieler mit mit der gleichen Anzahl an Plätzen gibt (dafür hab ich beispielhaft den Spieler xyz im Datenblatt mit drei 1. Plätzen ergänzt) nd auch für beliebigen Platz (einfach Dropdownzelle in A3 nutzen und evtl. entsprechend anpassen).

Formel B3:D3 weit genug nach nach unten und Formeln Spalte D zusätzlich weit genug nach rechts ziehend kopieren.

Solltest Du noch die alte Version Excel 2007 haben, müssten die Formeln B3 und D3 noch an diese Version angepasst werden.

Arbeitsblatt mit dem Namen 'Statistik'
 ABCDEFG
2mit meisten # PlätzenNameAnzahlSaisonSaisonSaisonSaison
31Spieler 3932016 / 20172017 / 20182018 / 2019 
4 Spieler xyz32015 / 20162016 / 20172018 / 2019 
5       

ZelleFormel
B3=WENNFEHLER(INDEX(Datenblatt!B:B;AGGREGAT(15;6;ZEILE(A$2:A$199)/(MAX(MMULT(ZÄHLENWENN(A$3;Datenblatt!H$2:AD$199);ZEILE(A$1:A$23)^0))=(MMULT(ZÄHLENWENN(A$3;Datenblatt!H$2:AD$199);ZEILE(A$1:$A$23)^0)));ZEILE(A1)));"")
C3=SUMMENPRODUKT((Datenblatt!H$2:AD$199=A$3)*(Datenblatt!B$2:B$199=B3))
D3=WENNFEHLER(WECHSELN(GLÄTTEN(INDEX(Datenblatt!$1:$1;AGGREGAT(15;6;SPALTE($G3:$AC3)/(Datenblatt!$B$2:$B$199=$B3)/(Datenblatt!$H$2:$AD$199=$A$3);SPALTE(A3))));" Liga";"");"")

ZelleGültigkeitstypOperatorWert1Wert2
A3Liste 1;2;3;4;5 
Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010
Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg


Gruß Werner
.. , - ...

Betrifft: AW: um auch die jeweilige Liga mit zu listen...
von: neopa C
Geschrieben am: 29.03.2020 14:06:36

Hallo,

... würde ich die Formel in D3 erweitern zu:

=WENNFEHLER(INDEX(Datenblatt!$A:$AZ;VERGLEICH($B3;Datenblatt!$B:$B;0);
AGGREGAT(15;6;SPALTE($G3:$AC3)/(Datenblatt!$B$2:$B$199=$B3)/
(Datenblatt!$H$2:$AD$199=$A$3);SPALTE(A3)))&" "&

WECHSELN(GLÄTTEN(INDEX(Datenblatt!$1:$1;AGGREGAT(15;6;SPALTE($G3:$AC3)
/(Datenblatt!$B$2:$B$199=$B3)/(Datenblatt!$H$2:$AD$199=$A$3);SPALTE(A3))));" Liga";"");"")

Gruß Werner
.. , - ...

Betrifft: AW: für die Tab mit drei Formeln realisierbar ...
von: Udo
Geschrieben am: 29.03.2020 14:10:18

Wow Dankeschön

Betrifft: AW: für die Tab mit drei Formeln realisierbar ...
von: Udo
Geschrieben am: 29.03.2020 14:25:29

Will nicht unverschämt sein, ginge das auch, das wenn ich platz 1 eingebe das es alle Spieler findet mit Platz 1 und die dann gereiht auflistet.

LG Udo

Betrifft: AW: ist doch im Vorschlag schon beinhaltet ...
von: neopa C
Geschrieben am: 29.03.2020 16:43:03

Hallo Udo,

... das hatte ich mit meinem zusätzlich aufgenommen "Spieler xxz" im Datenblatt aufgezeigt. Das geht auch mit weiteren Spielern. Du musst halt nur die Formeln weit genug nach unten kopieren.

Gruß Werner
.. , - ...

Betrifft: AW: ist doch im Vorschlag schon beinhaltet ...
von: Udo
Geschrieben am: 29.03.2020 16:58:38

Ja das stimmt schon, aber es zeigt dann nur die an die gleich oft platz 1 belegten, ich meine i such nach platz 1 und es zeigt mir alle spieler an die platz 1 belegt haben spieler 1 4 mal spieler 2 3 mal usw

LG Udo

Betrifft: AW: ist doch im Vorschlag schon beinhaltet ...
von: Udo
Geschrieben am: 29.03.2020 18:44:29

Das ich quasi in 10 jahren platz 1 eingebe und uch sehe genau wer wie oft in welcher Saison usw. jetzt sieht man auch mehere Spieler aber nur wenn sie gleich oft denselben Platz belegten LG Udo

Betrifft: AW: das geht auch, allerdings ...
von: neopa C
Geschrieben am: 29.03.2020 18:53:10

Hallo Udo,

... wird die Formel für B2 noch komplexer und muss entsprechend auch etwas weiter nach unten kopiert werden.

=WENNFEHLER(INDEX(Datenblatt!B:B;AGGREGAT(15;6;ZEILE(A$2:A$199)/(KGRÖSSTE(MMULT(ZÄHLENWENN(A$3;Datenblatt!H$2:AD$199);ZEILE(A$1:A$23)^0)-ZEILE(Datenblatt!H$2:AD$199)%%;ZEILE(A1))=(MMULT(ZÄHLENWENN(A$3;Datenblatt!H$2:AD$199);ZEILE(A$1:$A$23)^0)-ZEILE(Datenblatt!H$2:AD$199)%%))/(MMULT(ZÄHLENWENN(A$3;Datenblatt!H$2:AD$199);ZEILE(A$1:$A$23)^0)>0);1));"")

Gruß Werner
.. , - ...

Betrifft: AW: das geht auch, allerdings ...
von: Udo
Geschrieben am: 30.03.2020 07:25:59

Vielen Dank Perfekt

Betrifft: AW: bitteschön, freut mich owT
von: neopa C
Geschrieben am: 30.03.2020 08:57:03

Gruß Werner
.. , - ...

Beiträge aus dem Excel-Forum zum Thema "index suchen "