Live-Forum - Die aktuellen Beiträge
Datum
Titel
28.03.2024 21:12:36
28.03.2024 18:31:49
Anzeige
Archiv - Navigation
1760to1764
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Titelzeile auch Importieren aus Access

Titelzeile auch Importieren aus Access
06.06.2020 09:14:57
Maria
Hallo und guten Morgen
das folgende VBA, das ich in diesem Forum gefunden haben funktioniert bestens.
Leider wir die die Titelzeile aus Access NICHT mitimportiert.
Hat jemand eine Idee
Danke für eine Hilfe
Maria
Function Import_Access_to_Excel()
' Datenimport aus Access
Dim oRS As Object, oConn As Object
Dim sSql As String, strCon As String
Dim iCount As Integer, strAccessFile As String
strAccessFile = "D:\TPSC\01_ACCESS_und_Listen\TPSC_MITG_2020.accdb"
sSql = "SELECT * FROM abfr_4000_mitgl_liste"
Set oConn = CreateObject("ADODB.Connection")
strCon = "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" & strAccessFile & ";"
oConn.Open strCon
Set oRS = oConn.Execute(sSql)
Sheets("Test").Cells.Clear ' Tabellen CLEAREN
iCount = Sheets("Test").Range("A1").CopyFromRecordset(oRS)
oRS.Close
oConn.Close
Set oRS = Nothing
Set oConn = Nothing
End Function

3
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Titelzeile auch Importieren aus Access
06.06.2020 09:41:49
Regina
Hi,
durch ein SQL-Statement werden aus der angegebenen Tabelle die Datensätze selektiert. Wenn Du von Titelzeile sprichst, meinst Du die Feldnamen der Access-Tabelle.
Von Excel aus wäre es (nach meiner Meinung) sehr aufwändig, diese Feldnamen auszulsen. Aus Access heraus könntest Du auch ohne VBA mit der Standard-Exportmethode die Datensätze und die Feldnamen nach Excel exportieren.
Gruß Regina
AW: Titelzeile auch Importieren aus Access
06.06.2020 09:46:05
Tino
Hallo,
hier mal eine Variante zum testen.
Function Import_Access_to_Excel()
' Datenimport aus Access
Dim oRS As Object, oConn As Object
Dim sSql As String, strCon As String
Dim iCount As Integer, strAccessFile As String
strAccessFile = "D:\TPSC\01_ACCESS_und_Listen\TPSC_MITG_2020.accdb"
sSql = "SELECT * FROM abfr_4000_mitgl_liste"
Set oConn = CreateObject("ADODB.Connection")
strCon = "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" & strAccessFile
oConn.Open strCon
Set oRS = oConn.Execute(sSql)
With Sheets("Test")
' Tabellen CLEAREN
.Cells.Clear
'Daten vorhanden?
If Not oRS.BOF Then
If Not oRS.EOF Then
'Überschrift auslesen
For iCount = 0 To oRS.Fields.Count - 1
.Cells(1, iCount + 1).Value = oRS.Fields(iCount).Name
Next
'Überschrift fett
.Rows(1).Font.Bold = True
'Überschrift zentriert
.Rows(1).HorizontalAlignment = xlCenter
'Daten ab in A2 kopieren
iCount = .Range("A2").CopyFromRecordset(oRS)
'autom. Zeilenbreite
.UsedRange.EntireColumn.AutoFit
End If
End If
End With
oRS.Close
oConn.Close
Set oRS = Nothing
Set oConn = Nothing
End Function
Gruß Tino
Anzeige
AW: Titelzeile auch Importieren aus Access
06.06.2020 10:23:38
Maria
Dank vielmals
Super!

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige