Microsoft Excel

Herbers Excel/VBA-Archiv

Auslastungsplanung/Projekt/Wochenplanung

Betrifft: Auslastungsplanung/Projekt/Wochenplanung von: Tinu
Geschrieben am: 02.08.2020 14:05:08

Guten Tag Zusammen


Ich möchte eine Auslastungsplanung für ein KMU erstellen.

Zurzeit funktioniert es bei uns so das mein Chef in einem Excel Zeilen je Woche anfärbt und uns die Tabelle ausdruckt, da sich jedoch immer wieder etwas ändert und sich ein Fehler einschleichen müssen wir Ihm den Ausdruck korrigieren und zurück geben er, übernimmt das in seine Tabelle und irgendwann erhalten wir den "aktuellen" Ausdruck. Format A3-Quer

Für uns in der Projektleitung ist das mühsam, da wir in der Regel nie einen aktuellen Ausdruck haben, nicht in der Lage sind falls ein Kunde anruft von uns aus einen Termin zu verschieben da wir die Auslastung nicht kennen und wenn unser Chef nicht da ist, blind sind.


Die Bedienung der Tabelle muss so einfach wie möglich sein, da sonst die Akzeptanz nicht vorhanden ist.


Entwurfs Datei

https://www.herber.de/bbs/user/139417.xlsx


Zur Zeit habe ich zwei Tabellen "Eingabe" & "Eingeschränkt" Die Tabelle Eingabe ist über das ganze Jahr plus ein paar Wochen im neuen Jahr, die Tabelle Eingeschränkt ist entstanden weil es mir nicht möglich war die Jahres Tabelle so zu formatieren das mir die Ausgabe auf ein A3-Quer im Sinne von Eingeschränkt ausdruckt, Falls sich das mit VBA beheben lässt, ist mir das lieber.

Die anderen Tabellen sind erstmals Ideen und Wünsche, ich bin schon froh wenn das andere klappt. Unten stehen wären jedoch so Grob die Ideen…

Die Tabelle « Detailliert Projektleiter» wäre das Ziel das jeder Projektleiter seine Projekte Filtern kann und die Vorgabe vom Chef sieht und sein Projekt so einplanen kann, in der Projektleitung haben wir jeweils viel Detailliertere angaben wie bis wann muss die Planung abgeschlossen sein biss wann muss der Stahl angeliefert werden wann kommt das Glas, Oberflächenbehandlung, Montage Start usw.


Die Tabelle «Wochenplan» soll automatisiert einen Wochenplan ausgeben, so das ich als Projektleiter sagen kann ich möchte Mitarbeiter 1 und 2 von dann bis dann für die Montage, wenn dieser jedoch bereits ausgelastet ist soll das ein anderer Mitarbeiter machen, der generierte Wochenplan sollte noch Möglichkeiten zum anpassen haben…. Wicht je Arbeitstag können Mehrere Objekte sein, bei gewissen Mitarbeiter sind täglich/Wochentlich wiederholende Arbeiten fix einzuplanen z.B.: Reinigung, Material eingangs Kontrolle


Ich habe nur bedingte VBA Kenntnisse im Excel selber bin ich geübter.


Es würde mich sehr freuen wenn es für mein Problem eine Lösung gibt und mich jemand unterstützen könnte.


Ich arbeite zuhause mit einem Office 365 im Betrieb haben wir jedoch Excel 2016


Gruss Tinu

Betrifft: AW: liest sich eher nach Auftragsarbeit ...
von: neopa C
Geschrieben am: 02.08.2020 16:34:44

Hallo Tinu,

... die den Rahmen der Hilfe für Selbsthilfe "sprengen" dürfte. Auch wäre mE eine solche von vornherein möglicherweise zum Scheitern verurteilt, wenn es Dir /euch nicht gelingt, den Chef "mit ins Boot zu holen".

Gruß Werner
.. , - ...

Betrifft: AW: liest sich eher nach Auftragsarbeit ...
von: Armin
Geschrieben am: 02.08.2020 17:40:44

Hallo Tinu,
vor einiger Zeit habe ich ein ähnliche Projektablauf-Übersicht natürlich per VBA erstellt. Aber das bringt Ihr ohne prof. Hilfe nicht auf den Weg (hat Dir ja Werner auch schon geschrieben).
Da man im Excel nichts schützen kann, hier ein Bild von meinen Projekt.


Gruß Armin

Betrifft: AW: liest sich eher nach Auftragsarbeit ...
von: Tinu
Geschrieben am: 02.08.2020 19:37:25

Guten Tag Werner

Erstmal Danke für deine rasche und Ehrliche Antwort.
Ja das es den Rahmen sprengen könnte habe ich geahnt.
Mein Chef ist schon mit im Boot möchte jedoch nicht das es zu kompliziert ist da er die Möglichkeit will Änderungen raschen vorzunehmen. Deshalb will er auch nur eine Zeile je Auftrag wo Produktion und Montage ersichtlich ist. Wir in der Projektleitung brauchen/wollen jedoch mehr.
Wir haben uns auch Ressourcen-Planungs Programme angeschaut dort muss jedoch schon in einer sehr frühen Phase definiert werden wer den Auftrag ausführen will, ein Ausdruck auf ein A3-Quer ist oftmals nicht möglich oder nur mit sehr bescheidenen Informationen. Auch Änderungen sind nicht leicht vorzunehmen, dies ist jedoch oftmals der Fall.
Die Auslastung Auswertung mit einem Diagramm braucht er auch.
Den Wochenplan können wir wie bisher auf einer ausgedruckten Tabelle von Hand ausfüllen.
Die Tabelle die Armin hochgeladen hat würde schon ziemlich entsprechen.
Du bietest selber ja solche Auftragsprogrammierung an.
Kannst Du abschätzen was das für ein Aufwand ist und wie hoch die Kosten sind?
Brauchst Du noch mehr Informationen?


Gruss Tinu

Betrifft: AW: nein ...
von: neopa C
Geschrieben am: 02.08.2020 20:10:59

Hallo Tinu,

... ich persönlich biete keine Auftragsprogrammierung an. Aber Du kannst Dich per E-Mail an https://www.herber.de/kontakt.html ja an Hans und Partner wenden.

Gruß Werner
.. , - ...

Betrifft: AW: nein ...
von: Armin
Geschrieben am: 03.08.2020 10:01:00

Hallo Tinu,

wenn Du/Ihr Interesse habt, meine Mail-Adr. findetest Du im Formum-Services - Profile - Profilliste - Armin (anklicken).

Genaueres kann man erst sagen wenn ich mehr Einzelheiten kenne.



Gruß Armin

Betrifft: AW: Auslastungsplanung/Projekt/Wochenplanung
von: fcs
Geschrieben am: 03.08.2020 22:22:00

Hallo Tino,

die Ausgabe des Eingabeblatts mit einem bestimmten Bereich der Wochen kann man noch verhältnismäßig "einfach" umsetzen.
Dazu muss man unter Seiten-Layout -- Seite einrichten, zu wiederholende Zeilen und Spalten festlegen und den eigentlichen Druckbereich. Dann geht das reibungslos. Das Blatt "eingeschränkt" brauchst du also nicht.

Nachfolgend ein entsprechendes Makro. Als Abfallprodukt des Druckmakros hab ich noch eine Variante geschrieben, um zur Woche mit dem aktuellen Datum zu scrollen.

Wie schon die anderen User schrieben ist die Umsetzung der anderen Wünsche erheblich aufwendiger und sprengt den Rahmen des Forums.
Insbesondere muss da erst einmal ein genauerer Plan vorbereitet werden (PAP) in dem beschrieben wird:
- Welche Daten sind vorhanden
- welche Daten müssen wie, von wem, wo noch erfasst werden
- Wie sollen die Daten ausgewertet werden, Aufbereitung als Tabelle, Diagramm etc.

LG
Franz
'Code in einem allgemeinen Modul der Datei
Sub Drucken_PL_Plan()
  'Ausgabe des Eingabeblattes für Projektleitung
  Dim wksEingabe As Worksheet
  Dim spa As Long, spa1 As Long, spaL As Long, zei1 As Long, ZeiL As Long
  Dim sPrintArea As String
  
  Set wksEingabe = ActiveWorkbook.Worksheets("Eingabe")
  
  If MsgBox("Blatt """ & wksEingabe.Name & """ mit speziellem Druckbereich für Projektleiter  _
drucken?" _
    & vbLf & vbLf & "Drucker: " & Application.ActivePrinter, _
      vbQuestion + vbOKCancel, "Drucken Blatt ""Eingabe""") = vbCancel Then Exit Sub
  
  With wksEingabe
    .Activate
    zei1 = 4  'Zeile mit 1. Auftrag
    'Spalte mit 1. Tag der ersten KW
    spa1 = .Range("S3").Column
    'Letzte Spalte mit Datum in Zeile 3
    spaL = .Cells(3, .Columns.Count).End(xlToLeft).Column
    'Zeile mit letzter Auftragsnummer in Spalte B bzw. letzte Zeile des als Tabelle definierten  _
Bereichs
    ZeiL = .Cells(.Rows.Count, 2).End(xlUp).Row
    If .Cells(ZeiL, 2) = "" Then
      ZeiL = .Cells(ZeiL, 2).End(xlUp).Row
    End If
    If ZeiL < zei1 Then
      MsgBox "Es sind noch keine Aufträge angelegt oder Zeilen sind ausgeblendet.", _
        vbInformation + vbOKOnly, "Drucken Blatt ""Eingabe"""
        Exit Sub
    End If
    'KW mit aktuellem Datum suchen
    For spa = spa1 + 5 To spaL Step 5
      If .Cells(3, spa).Value >= Date Then
        '1. zu druckende Spalte (Montag der Vorwoche)
        spa1 = spa - 5
        'letzte zu druckende Spalte (Freitag 11 Wochen später)
        spaL = spa + 11 * 5 + 4
        Exit For
      End If
      If spa = spaL Then Exit For
    Next
    sPrintArea = .Range(.Cells(1, spa1), .Cells(ZeiL, spaL)).Address
    With .PageSetup
      .PrintTitleRows = "$1:$3"
      .PrintTitleColumns = "$A:$L"
      .PrintArea = sPrintArea
      .Orientation = xlLandscape
      .PaperSize = xlPaperA3
    End With
    
    'Drucken mit Seitenvorschau
    .PrintOut preview:=True
    
    'Druckbereich zurücksetzen falls gewünscht
    With .PageSetup
      .PrintTitleRows = "$1:$3"
      .PrintTitleColumns = "$A:$L"
      .PrintArea = ""
      .Orientation = xlLandscape
      .PaperSize = xlPaperA3
    End With
  End With
End Sub

'Abfallprodukt des Druckmakros
Sub Scrollen_nach_Heute()
  'Scrollen zur KW mit heutigem Datum
  Dim wksEingabe As Worksheet
  Dim spa As Long, spa1 As Long, spaL As Long, zei1 As Long, ZeiL As Long
  Dim sPrintArea As String
  
  Set wksEingabe = ActiveWorkbook.Worksheets("Eingabe")
  
  With wksEingabe
    .Activate
    'Spalte mit 1. Tag der ersten KW
    spa1 = .Range("S3").Column
    'Letzte Spalte mit Datum in Zeile 3
    spaL = .Cells(3, .Columns.Count).End(xlToLeft).Column
    'KW mit aktuellem Datum suchen
    For spa = spa1 + 5 To spaL Step 5
      If .Cells(3, spa).Value >= Date Then
        '1. zu druckende Spalte (Montag der Vorwoche)
        spa1 = spa - 5
        Exit For
      End If
      If spa = spaL Then spa1 = spaL - 1
    Next
  End With
  ActiveWindow.ScrollColumn = spa1

End Sub