Microsoft Excel

Herbers Excel/VBA-Archiv

summewenns

Betrifft: summewenns von: Pascal
Geschrieben am: 11.09.2020 16:52:11

Liebes Forum

Ich bin dabei eine Auswertung im Excel zu erstellen. Dabei verwende ich unter anderem die SUMMEWENNS-Funktion. Jedoch komme ich mit der Funktion nicht weiter. Mein Problem sieht wie folgt aus:

Bei der Benötigten Kalkulation muss als erstes Kriterium die Kundennummer gefunden werden um aus dem Summenbereich die relevanten Zahlen heranzuziehen. Mein Problem kommt beim zweiten Kriterium. Da auf dieses Kriterium mehrere Produktnummern fallen und jeden der Produktnummern berücksichtigt werden muss komme ich nicht weiter.

Meine momentane Lösung sieht wie folgt aus:

=(SUMMEWENNS('LER-Export'!$C$2:$C$55000;'LER-Export'!$B$2:$B$55000;'Pivot-Daten'!B2; 'LER-Export'!$H$2:$H$55000;3011)+SUMMEWENNS('LER-Export'!$C$2:$C$55000;'LER-Export'!$B$2:$B$55000; 'Pivot-Daten'!B2;'LER-Export'!$H$2:$H$55000;3012)+SUMMEWENNS('LER-Export'!$C$2:$C$55000; 'LER-Export'!$B$2:$B$55000;'Pivot-Daten'!B2;'LER-Export'!$H$2:$H$55000;3013) +SUMMEWENNS('LER-Export'!$C$2:$C$55000;'LER-Export'!$B$2:$B$55000;'Pivot-Daten'!B2; 'LER-Export'!$H$2:$H$55000;3014)+SUMMEWENNS('LER-Export'!$C$2:$C$55000;'LER-Export'!$B$2:$B$55000; 'Pivot-Daten'!B2;'LER-Export'!$H$2:$H$55000;3014)+SUMMEWENNS('LER-Export'!$C$2:$C$55000; 'LER-Export'!$B$2:$B$55000;'Pivot-Daten'!B2;'LER-Export'!$H$2:$H$55000;3021) +SUMMEWENNS('LER-Export'!$C$2:$C$55000;'LER-Export'!$B$2:$B$55000;'Pivot-Daten'!B2; 'LER-Export'!$H$2:$H$55000;3060)+SUMMEWENNS('LER-Export'!$C$2:$C$55000;'LER-Export'!$B$2:$B$55000; 'Pivot-Daten'!B2;'LER-Export'!$H$2:$H$55000;3070))

jede Produktnummer wird gesucht und die Ergebnisse addiert. Diese Formel ist aber zu gross und das Excel wird sehr langsam. Hat jemand eine Idee wie das Ergebnis einfacher gefunden werden kann?

Vielen Dank für eure Antworten.

Lg Pascal

Betrifft: AW: summewenns
von: Hajo_Zi
Geschrieben am: 11.09.2020 16:54:39

Hallo Pascal,

benutze Summenprodukt mit "+"

Gruß Hajo

Betrifft: AW: summewenns
von: Günther
Geschrieben am: 11.09.2020 19:10:18

Moin,
ich schätze mal, dass du über Daten | Abrufen und transformieren eine deutlich bessere Performance erzielst. Aber ohne Muster-xlsx mit einer klaren, händischen Lösung mache ich mir keine Gedanken darüber und deine Formel müsste ich gewiss zu lange analysieren, um zu verstehen, was du im Endeffekt wirklich erreichen willst.
 
Gruß
Günther  |  mein Excel-Blog

Betrifft: AW: summewenns
von: SF
Geschrieben am: 11.09.2020 16:59:44

Hola,

ungetestet:

=Summe(SUMMEWENNS('LER-Export'!$C$2:$C$55000;'LER-Export'!$B$2:$B$55000;'Pivot-Daten'!B2; 'LER-Export'!$H$2:$H$55000;{3011;3012;3013}))
Evtl das Semikolon gegen einen Punkt austauschen.

In deiner Formel summierst du übrigens die 3014 zweimal.

Gruß,
steve1da

Betrifft: AW: summewenns
von: Daniel
Geschrieben am: 11.09.2020 17:05:47

ich vermute mal, das macht die Formel zwar kürzer, aber nicht schneller.
Gruß Daniel

Betrifft: AW: summewenns
von: Daniel
Geschrieben am: 11.09.2020 17:04:27

HI
beispielsweise so, wenn die Produktnummern immer 4-STellig sind und nur bestimmte produktnummern relevant sind:

=SummenProdukt('LER-Export'!$C$2:$C$55000*('LER-Export'!$B$2:$B$55000='Pivot-Daten'!B2)*Istzahl(finden('LER-Export'!$H$2:$H$55000;";3011;3012;...;3060;3070;")))

im Text musst du alle relevanten Produktnummern auflisten.
Der Text mit den Produktnummern kann auch in einer Zelle stehen.
sollten die Produktnummern unterschiedliche Längen haben können, müsstest du die Trennzeichen auch beim Suchwert hinzufügen: ...Finden(";"&'LER-Export'!$H$2:$H$55000&";";...

Gruß Daniel