Live-Forum - Die aktuellen Beiträge
Datum
Titel
16.10.2025 11:48:44
Makro von Excel in Word aufrufen
16.10.2025 11:16:26
SUMMEWENN erweitern
16.10.2025 09:40:53
Mehrere Konferenzen ohne Personenüberschneidung terminieren
16.10.2025 00:15:51
Passwort im Herbersforum ändern
Keine passende Antwort im Forumarchiv gefunden?
Stelle deine Frage im Live-Forum
Anzeige
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Vorheriger Thread
Vorheriger Thread
Rückwärts Blättern
1812to1816
1812to1816
Aktuelles Verzeichnis
Verzeichnis Übersicht
Verzeichnis Übersicht
Übersicht Verzeichnisse
Nächster Thread
Nächster Thread
Vorwärts blättern
Inhaltsverzeichnis

Max Wert aus Text Zahlen kombination

Forumthread: Max Wert aus Text Zahlen kombination

Max Wert aus Text Zahlen kombination
13.02.2021 13:27:24
Robert
Hallo,
ich habe schon einige Sachen ausprobiert aber ohne Erfolg.
Und zwar habe ich der Spalte G ab Zeile 6 folgende Text Zahlen Kombination.
BF-21-002
BF-21-005
BF-21-007
BF-21-008
BF-21-108
BF-21-510
Nun möchte ich die Zelle wiedergegeben die den höchsten Zahlen Wert hat oder den Zahlenwert selbst wiedergeben.
Der vordere Teil "BF-21-" bleibt gleich. Es gibt nicht mehr als 3 Zahlen am Ende.
Allerdings gibt es auch leere Zeilen und anderen Text dazwischen.
Ich hoffe einer von euch kann mir helfen.
Anzeige

25
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: verschiedene Lösungsformelnvarianten ...
13.02.2021 13:54:22
neopa
Hallo Robert,
... möglich, z.B. so: =MAX(INDEX(--WECHSELN(0&G6:G99;"BF-21-";"");))
Gruß Werner
.. , - ...
AW: verschiedene Lösungsformelnvarianten ...
13.02.2021 17:51:27
Robert
Hallo leider haben beide Vorschläge nicht funktioniert.
:-(
ICh habe meine Beispieldatei hochgeladen.
https://www.herber.de/bbs/user/143888.xlsx
Anzeige
das liegt an Leerzellen und Text
13.02.2021 18:21:03
WF
folgende Arrayformel:
{=MAX(WENN(ISTZAHL(RECHTS(G6:G250)*1);RECHTS(G6:G250;3))*1)}
WF
Eingabe Arrayformel:
Du kopierst Dir die Formel.
Dann gehst Du in die Bearbeitungszeile, löschst die {geschweiften Klammern} am Anfang und Ende und schließt ab mit GLEICHZEITIG: Strg Shift Enter (statt Enter allein). Dadurch werden diese Klammern erzeugt.
Anzeige
Anhand deiner BspDatei ergibt sich Anderes, ...
13.02.2021 19:24:56
Luc:-?
…Robert,
nämlich BF-20-057 als Maximum, nicht etwa ein BF-21-Wert. Das kann dann auch kürzer (und hier sogar als volle Angabe) erreicht wdn, falls du wenigstens Xl12/2007 hast:
{=INDEX(G6:G250;VERGLEICH("*"&TEXT(MAX(WENNFEHLER(--RECHTS(G6:G250;3);""));"-000");G6:G250;0))}
Gruß, Luc :-?
„Die universelle Befähigung zur Unfähigkeit macht jede menschliche Leistung zu einem unglaublichen Wunder.“ Stapps ironisches Paradoxon
Anzeige
AW: geht einfacher; sieh mein Beitrag 19:11 owT
13.02.2021 19:34:13
neopa
Gruß Werner
.. , - ...
Aber nur unter der Voraussetzung, dass es ...
14.02.2021 01:22:32
Luc:-?
…stets nur um BF-21-Werte geht, Werner,
dessen Du im späteren Thread-Verlauf anscheinend gar nicht mehr so sicher warst (AW an WF).
Ich habe natürlich noch andere Möglichkeiten, aber damit wird's (bisher) auch nicht kürzer.
Morhn, Luc :-?
Anzeige
AW: diese war so vorgegeben ...
14.02.2021 09:31:40
neopa
Hallo Luc,
... und deshalb ist ein Abgleich mit "BF-21-", wie ich z.B. mit WECHSELN() getan habe, zwingend notwendig. Denn schließlich hat auch seine Datei gezeigt, dass noch andere Texte vorkommen können, die vielleicht eine abschließende Ziffernfolge haben können dessen Wert größer sein könnte als der mit seinem evtl. Schreibfehler in G176. Aber ob es da ein Schreibfehler war oder nicht kann natürlich nur Robert entscheiden.
Gruß Werner
.. , - ...
Anzeige
Ich bin bei so etwas immer misstrauisch, ...
14.02.2021 15:09:55
Luc:-?
…Werner,
vor allem, wenn behauptet wird, dass nur das Eine vorkommt und dann doch auch Anderes zu finden ist. Das kann ein Schreibfehler sein, aber die kommen ja auch in der Praxis vor, weshalb man Primärdaten auch immer prüfen sollte (DatenPrüfPgmm scheinen heute aus der Mode gekommen zu sein). Deine ursprünglichen 3 Fmln (die 1. nur, wenn sie hier denn fktionieren könnte) würden das ebenso Verschleiern wie Walters, obwohl beide dann unterschiedliche Ergebnisse hätten. Sollten aber nur die BF-21-Werte berücksichtigt wdn, obwohl auch andere vorkommen können, hätte er das erwähnen müssen.
SchöSo, Luc :-?
Anzeige
AW: Ich bin bei so etwas immer misstrauisch, ...
14.02.2021 17:18:50
Robert
Um das ganze aufzulösen.
in G176 ist kein Schreibfehler. Das sind Daten aus dem Jahr 2020.
Im Ergebnis sollen aber nur Werte von 2021 mit BF-21- aufgelistet werden.
Danke für eure Mühe.
AW: bitteschön und danke für Deine Aufklärung owT
14.02.2021 19:51:32
neopa
Gruß Werner
.. , - ...
Und eben das hättest du erwähnen müssen! :-[ owT
15.02.2021 01:43:35
Luc:-?
:-?
Anzeige
AW: im Eröffnungsbeitrag stand es aber doch owT
15.02.2021 11:01:46
neopa
Gruß Werner
.. , - ...
Dann musst Du ...
15.02.2021 14:25:13
Luc:-?
…Der vordere Teil "BF-21-" bleibt gleich anders interpretiert haben als ich, Werner,
und das ist kein Zeichen von Eindeutigkeit, die Du doch sonst immer forderst… ;-]
Exakter wäre wohl so etwas wie es sollen nur Daten mit "BF-21-" am Anfang ausgewertet wdn gewesen. Es hätte auch nichts geschadet, gleich darauf hinzuweisen, dass es sich um Jahresdaten handelt, wobei die 21 2021 bedeutet und nur dieses Jahr relevant ist.
Jeder FrageSteller sollte sich seinen AnfrageText vor Absenden nochmals durchlesen (deshalb Vorschau) und auf Fehler, Verständlichkeit und Eindeutigkeit prüfen, was anscheinend oft nicht gemacht wird. Diese Beliebig- und Schnoddrigkeit scheint zuzunehmen. Andererseits sollen wir dann daraus qualifizierte AWen ableiten…
Luc :-?
Anzeige
AW: warum nicht eine Datei? ...
13.02.2021 18:57:30
neopa
Hallo Robert,
... denn das Textdaten zwischen den auszuwertenden Datenwerten stehen, war inDeinem Eröffnungstrhread nicht zu lesen. Doch in diesem steht auch: "Der vordere Teil "BF-21-" bleibt gleich".
Somit ist das Ergebnis 13 und nicht 57, es sei denn Du hast Dich in G176 verschrieben.
Wenn Du Excel 2010 im Einsatz hast, folgende einfache Formel :
=AGGREGAT(14;6;--WECHSELN(G6:G250;"BF-21-";"");1)
Gruß Werner
.. , - ...
Anzeige
AW: da fehlt nach "nicht" noch ein "gleich" und...
13.02.2021 19:11:07
neopa
Hallo Robert,
... solltest Du doch noch XL2007 im Einsatz haben, dann als Matrixformel:

={MAX(WENN(LINKS(G6:G250;6)="BF-21-";RECHTS(G6:G250;3)+0))}
Gruß Werner
.. , - ...
AW: Max Wert aus Text Zahlen kombination
13.02.2021 13:57:06
Hajo_Zi

Tabelle1
 AB
1BF-21-002725
2BF-21-005 
3BF-21-725 
4BF-21-008 
5BF-21-108 
6BF-21-510 

verwendete Formeln
Zelle Formel Bereich N/A
B1{=MAX(RECHTS(A1:A6;3)*1)}$B$1 
{} Matrixformel mit Strg+Umschalt+Enter abschließen
Matrixformeln sind durch geschweifte Klammern {} eingeschlossen
Diese Klammern nicht eingeben!!



Anzeige
AW: Max Wert aus Text Zahlen kombination
13.02.2021 19:23:02
Robert
Danke für die Antworten.
Es funktioniert aber ich würde gern wissen wollen um es zu verstehen für was steht die
"1" in den beiden Formeln
{=MAX(WENN(ISTZAHL(RECHTS(G6:G250)*1);RECHTS(G6:G250;3))*1)}
=AGGREGAT(14;6;--WECHSELN(G6:G250;"BF-21-";"");1)
Zwecks Umwandlung in eine echte Zahl! owT
13.02.2021 19:27:52
Luc:-?
:-?
AW: das erklärt aber nur die *1 owT
13.02.2021 19:35:54
neopa
Gruß Werner
.. , - ...
Anzeige
AW: in Kurzform: *1 <>;1 ...
13.02.2021 19:31:34
neopa
Hallo Robert,
... weil in der ersten Formel wird mit der 1 eine Operation - nämlich Multiplikation mit 1 - durchgeführt und in der zweiten Formel steht die 1 als 4. Argument der Funktion AGGREGAT() und bedeutet da, dass der Erstgrößte Wert aus der Matrix --WECHSELN(G6:G250;"BF-21-";"") ermittelt wird.
Aber noch mal darauf hingewiesen. In Deiner Datei liefern beide Formeln unterschiedliche! Ergebniswerte. Nur die AGGREGAT()-Formel entspricht exakt Deiner Bedingungsvorgabe.
Gruß Werner
.. , - ...
Anzeige
er schrieb: "BF-21-" bleibt gleich
13.02.2021 19:42:43
WF
BF-20 ist also ein Tippfehler.
AW: kann, muss aber kein Tippfehler sein owT
13.02.2021 19:47:21
neopa
Gruß Werner
.. , - ...
AW: kann, muss aber kein Tippfehler sein owT
13.02.2021 21:19:17
Robert
Danke für die ganzen Infos.
Es funktioniert alles bestens.
Anzeige
AW: wirklich alles? owT
14.02.2021 09:23:25
neopa
Gruß Werner
.. , - ...
RECHTS ergibt als Ergebnis Text
13.02.2021 19:33:45
WF
MAX funktioniert nur bei Zahlen.
Mit *1 wir aus Text ne Zahl.
Bei dem Aggregatzeug erklärt Dir das jemand anders.
WF
;
Anzeige
Anzeige

Infobox / Tutorial

Maximaler Wert aus Text-Zahlen-Kombination in Excel ermitteln

Schritt-für-Schritt-Anleitung

Um den maximalen Wert aus einer Liste von Text-Zahlen-Kombinationen in Excel zu ermitteln, kannst du folgende Schritte ausführen:

  1. Daten vorbereiten: Stelle sicher, dass deine Daten in einer Spalte (z.B. Spalte G) ab Zeile 6 angeordnet sind. Beispielwerte könnten so aussehen:

    G6: BF-21-002
G7: BF-21-005
G8: BF-21-007
G9: BF-21-108
G10: BF-21-510

  2. Formel eingeben: Um den maximalen Zahlenwert zu ermitteln, kannst du verschiedene Formeln verwenden. Eine der einfachsten ist:

    =MAX(INDEX(--WECHSELN(G6:G99, "BF-21-", ""), 0))

    Diese Formel entfernt den Text "BF-21-" und gibt die maximalen Zahlenwerte zurück.

  3. Array-Formel verwenden: Eine alternative Methode ist die Verwendung einer Array-Formel. Gib folgendes in eine Zelle ein und drücke Strg + Shift + Enter, um die Formel abzuschließen:

    {=MAX(WENN(ISTZAHL(RECHTS(G6:G250) * 1); RECHTS(G6:G250; 3) * 1))}

  4. Ergebnisse prüfen: Überprüfe, ob die Formel die erwarteten Ergebnisse liefert. Leere Zellen und nicht-numerische Werte können das Ergebnis beeinflussen.

Häufige Fehler und Lösungen

  • Leere Zellen: Wenn leere Zellen in deinem Datenbereich vorhanden sind, kann dies zu Fehlern führen. Stelle sicher, dass deine Formeln so gestaltet sind, dass sie mit leeren Zellen umgehen können.

  • Falsche Eingabe: Achte darauf, dass die Formeln korrekt eingegeben werden, insbesondere bei der Verwendung von Array-Formeln. Die geschweiften Klammern {} werden automatisch erzeugt, wenn du die Eingabe mit Strg + Shift + Enter abschließt.

  • Formatierungsprobleme: Wenn die Ergebnisse nicht als Zahlen angezeigt werden, könnte das an der Formatierung der Zellen liegen. Stelle sicher, dass die Zellen im richtigen Zahlenformat sind.

Alternative Methoden

Neben den oben genannten Formeln gibt es auch andere Möglichkeiten, um den maximalen Wert aus einer Text-Zahlen-Kombination zu ermitteln:

  1. AGGREGAT-Funktion: Eine weitere Methode ist die Verwendung der AGGREGAT-Funktion. Hier ist ein Beispiel:

    =AGGREGAT(14, 6, --WECHSELN(G6:G250, "BF-21-", ""), 1)

    Diese Funktion kann auch mit Fehlern umgehen und ignoriert leere Zellen.

  2. Text in Spalten: Du kannst die Funktion "Text in Spalten" verwenden, um die Zahlen von den Texten zu trennen und anschließend die MAX-Funktion auf die resultierende Spalte anzuwenden.

Praktische Beispiele

Hier sind einige praktische Beispiele, die zeigen, wie du den maximalen Wert aus Text-Zahlen-Kombinationen in Excel ermitteln kannst:

  • Beispiel 1: Angenommen, du hast die folgenden Werte in Spalte G:

    BF-21-002
BF-21-005
BF-21-725
BF-21-108
BF-21-510

    Verwende die Formel:

    =MAX(INDEX(--WECHSELN(G6:G10, "BF-21-", ""), 0))

    Das Ergebnis wird 725 sein.

  • Beispiel 2: Wenn du eine Array-Formel verwendest:

    {=MAX(WENN(ISTZAHL(RECHTS(G6:G250) * 1); RECHTS(G6:G250; 3) * 1))}

    Dies gibt dir ebenfalls den maximalen Wert 725 zurück.

Tipps für Profis

  • Datenvalidierung: Überprüfe regelmäßig deine Daten, um sicherzustellen, dass keine unerwarteten Werte vorhanden sind, die deine Berechnungen beeinflussen könnten.

  • Dynamische Bereiche: Nutze dynamische Bereiche (z.B. mit der Funktion BEREICH.VERSCHIEBEN), um deine Formeln flexibler zu gestalten, insbesondere wenn du häufig neue Daten hinzufügst.

  • Benutzerdefinierte Formate: Experimentiere mit benutzerdefinierten Zellformaten, um die Anzeige deiner Ergebnisse zu optimieren.

FAQ: Häufige Fragen

1. Warum funktioniert die MAX-Funktion nicht mit Text?
Die MAX-Funktion kann nur mit numerischen Werten arbeiten. Um Text in Zahlen zu konvertieren, kannst du Multiplikation mit 1 verwenden (z.B. *1).

2. Was bedeutet die 1 in der AGGREGAT-Formel?
Die 1 in der AGGREGAT-Funktion steht für den ersten größten Wert, der aus der Liste ermittelt werden soll.

Beliebteste Forumthreads (12 Monate)

Jetzt das Excel-Portal bewerten: Deine Stimme zählt!
Anzeige
Anzeige
Entdecke mehr
Finde genau, was du suchst

Die erweiterte Suchfunktion hilft dir, gezielt die besten Antworten zu finden

Suche nach den besten Antworten
Unsere beliebtesten Threads

Entdecke unsere meistgeklickten Beiträge in der Google Suche

Top 100 Threads jetzt ansehen
Anzeige