Zeitaufnahme Bogen

Hallo zusammen,
ich bin leider mit VBA nur so halbwegs vertraut und bei dem Projekt komme ich leider trotz Google nicht wirklich weiter.
Ich möchte gerne einen Zeitaufnahme Bogen haben, dazu benötige ich eine Stoppuhr.
Die Uhr soll über die folgenden Knöpfe verfügen
Start
Pause/Weiter
Zwischenzeit
Stopp
Bei Start soll die Zeitaufnahme beginnen.
Bei Zwischenzeit soll die seit Start vergangene Zeit in B5 eingetragen werden. Drücke ich dann wieder auf Zwischenzeit soll die seit der letzten Zwischenzeit vergangene Zeit in B6 eingetragen werden und so weiter.
Bei Pause soll die Zeitaufnahme pausieren und bei Weiter wieder loslegen.
Bei Stopp soll die Zeitaufnahme beendet werden.
Stoppuhr denke ich prinzipiell wie hier: https://www.online-excel.de/excel/singsel_vba.php?f=96
Leider bekomme ich das nicht zum Laufen...
Vielen lieben Dank für Eure Hilfe!
Martin

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

HI
probier mal folgenden Code in einem allgemeinen Modul:


Option Explicit
Dim StartZeit As Double
Dim SpeicherZeit As Double
Dim Pausieren As Boolean
Dim ZeitLäuft As Boolean


Sub Start()
If Not ZeitLäuft Then
Range(Cells(5, 2), Cells(4, 2).End(xlDown)).ClearContents
StartZeit = Timer
Range("A1").Value = "Zeit läuft"
ZeitLäuft = True
End If
End Sub


Sub Pause()
If Pausieren Then
StartZeit = Timer
Pausieren = False
Range("A1").Value = "Zeit läuft"
Else
SpeicherZeit = Timer - StartZeit + SpeicherZeit
Pausieren = True
Range("A1").Value = "Pause"
End If
End Sub


Sub Zwischenzeit()
If Not Pausieren Then
Cells(Rows.Count, 2).End(xlUp).Offset(1, 0).Value = SpeicherZeit + Timer - StartZeit
SpeicherZeit = 0
StartZeit = Timer
End If
End Sub


Sub Stoppen()
Cells(Rows.Count, 2).End(xlUp).Offset(1, 0).Value = SpeicherZeit + IIf(Pausieren, 0, Timer - StartZeit)
Range("A1").Value = ""
ZeitLäuft = False
Pausieren = False
End Sub

du musst dann noch die vier Buttons erstellen und jedem dieser Buttons eines dieser Makros zuweisen.
Als Buttons kannst du die Commandbuttons aus den Formularsteuerelementen verwenden, aber auch jede andere Grafik oder Form, dann kannst du deine Buttons auch einfacher "schick" aussehen lassen.
Gruß Daniel

Beliebteste Forumthreads (12 Monate)

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Zeitaufnahme Bogen

4 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread