AW: Formatierung übernehmen in Outlook
07.10.2021 15:10:04
{Boris}
Hi Mike,
ich habe dazu eine alte Function (von Ron de Bruin) im Einsatz. Ob die so noch "state of the art" ist, weiß ich nicht, aber sie läuft, will heißen: Sie fügt einen Bereich aus einem Excelarbeitsblatt mit Formaten in den Mailkörper ein.
Function RangetoHTML(rng As Range)
' Changed by Ron de Bruin 28-Oct-2006
' Working in Office 2000-2016
Dim fso As Object
Dim ts As Object
Dim TempFile As String
Dim TempWB As Workbook
TempFile = Environ$("temp") & "\" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"
'Copy the range and create a new workbook to past the data in
rng.Copy
Set TempWB = Workbooks.Add(1)
With TempWB.Sheets(1)
.Cells(1).PasteSpecial Paste:=8
.Cells(1).PasteSpecial xlPasteValues, , False, False
.Cells(1).PasteSpecial xlPasteFormats, , False, False
.Cells(1).Select
Application.CutCopyMode = False
On Error Resume Next
.DrawingObjects.Visible = True
.DrawingObjects.Delete
On Error GoTo 0
End With
'Publish the sheet to a htm file
With TempWB.PublishObjects.Add( _
SourceType:=xlSourceRange, _
Filename:=TempFile, _
Sheet:=TempWB.Sheets(1).Name, _
Source:=TempWB.Sheets(1).UsedRange.Address, _
HtmlType:=xlHtmlStatic)
.Publish (True)
End With
'Read all data from the htm file into RangetoHTML
Set fso = CreateObject("Scripting.FileSystemObject")
Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
RangetoHTML = ts.readall
ts.Close
RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
"align=left x:publishsource=")
'Close TempWB
TempWB.Close savechanges:=False
'Delete the htm file we used in this function
Kill TempFile
Set ts = Nothing
Set fso = Nothing
Set TempWB = Nothing
End Function
Im Code dann so in der Art:
Dim MyOutApp As Object
Dim MyMessage As Object
Dim rng As Range
Set MyOutApp = CreateObject("Outlook.application")
Set MyMessage = MyOutApp.createitem(0)
Set rng = Tabelle6.Range("B2:C14") 'das ist der Bereich, der in den Mailkörper eingefügt werden soll
With MyMessage
.To = "Hans@mustermann.de"
.Subject = "Dein Mailbetreff"
.HTMLBody = RangetoHTML(rng) 'Hier wird die Function aufgerufen
.Display ' Mail anzeigen ohne automatischen Versand
End with
VG, Boris