Status der Num-Lock-Taste

Josef Schindler · 2023-04-08T21:20:40+00:00

Hallo und guten Abend an das Excelforum, kann ich, während Excel "läuft" den Status der Num-Lock-Taste via Code abfragen und ggf. ändern, wenn diese inaktiv ist? Wer kann mir bitte helfen? Ich bin leider VBA - Memme. Und wer gibt mir Hilfestellung und kann mir einen VBA - Code aufzeigen und vor allem erklären? Ich bin für jede erdenkliche Hilfestellung sehr dankbar! Mit freundlichem Gruß Josef

Hallo Josef,

hier ein wenig Spielmaterial....
Ich denke, der Code ist selbsterklärend. Wichtig ist die Declarefunktion, da mit einer API-Funktion gearbeitet wird.

Code:


Private Declare PtrSafe Function GetKeyboardState Lib "user32" ( _
        pbKeyState As Byte) As Long
 
Sub NumBlockEinschalten()
  Dim Keys(0 To 255) As Byte

  GetKeyboardState Keys(0)
  If Keys(vbKeyNumlock) = False Then SendKeys "{NUMLOCK}"
End Sub

Sub NumBlockAusschalten()
  Dim Keys(0 To 255) As Byte

  GetKeyboardState Keys(0)
  If Keys(vbKeyNumlock) Then SendKeys "{NUMLOCK}"
End Sub

Function GetNumBlockStatus() As Boolean
  Dim Keys(0 To 255) As Byte

  GetKeyboardState Keys(0)
  GetNumBlockStatus = Keys(vbKeyNumlock)
End Function

Sub Test()
  MsgBox "Der Nummernblock ist " & IIf(GetNumBlockStatus, "ein", "aus") & "geschaltet!"
End Sub

_________________________
viele Grüße aus Freigericht 😊
Karl-Heinz

Hallo Josef,

zur Erklärung:
Das von snb gezeigte "Togglemacro" toggelt die Numlocktaste, d.h. es wird bei jedem Drücken der Taste der Zustand umgeschaltet, also an-aus-an-aus....

Verwendet wird in dieser Sub die API-Funktion keybd_event, die das Drücken und das Loslassen einer Taste erlaubt und damit genau das simuliert, was ein User machen würde.

Ich bin auch ein Freund von kurzem code und verwende auch nicht immer nur einmal benutzte Konstanten und Variablen, sondern setze den Wert ein.
Ich gebe aber immer einen Hinweis auf die zugrunde liegende Konstante, damit man später noch weiß, was man gemacht hat.

Das ist hier leider nicht gemacht worden.

Das Makro hätte also auch so aussehen können. Natürlich muss man nun die Konstanten auch definieren, also mehr code)


Sub M_snb_NUMlock_aan()
  Const VK_NUMLOCK = &H90
  Const KEYEVENTF_KEYUP = &H2

  If GetKeyState(VK_NUMLOCK) = 0 Then
     keybd_event VK_NUMLOCK, 0, 0, 0
     keybd_event VK_NUMLOCK, 0, KEYEVENTF_KEYUP, 0
  End If
  MsgBox GetKeyState(VK_NUMLOCK)
End Sub

Wozu snb die Werte &H1 und &H45 braucht, weiß ich leider auch nicht. Vielleicht liefert snb ja eine kurze Erklärung dazu.

Die Toggleversion berücksichtigt aber nicht den jetzigen Zustand, sondern schaltet einfach nur um, so dass man, wenn man nur einschalten möchte, vorher den Zustand checken muss.

keybd_event bringt m.E. nicht unbedingt immer einen Vorteil ggü. der Sendkeys-Version, denn auch diese Funktion sendet die Tastenanschläge nur an das Vordergrundfenster.

Gruß KH

Forumthread: Status der Num-Lock-Taste

10
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Infobox / Tutorial