Suchfunktion in bestehender Listfunktion einbinden ...

Hallo Freunde,

habe mir eine Funktion gebastelt, mit der ich eine Listbox befülle. Verwendung fand die Funtkion Rowsource. Nun scheitere ich daran, dass ich mit dieser Funktion keine Suchabfrage generieren kann. zumindest sehe ich den Wald vor lauter Bäumen nicht.^^

Private Sub Suchbegriff_Change()



'richtiges Tabellenblatt auswählen

ThisWorkbook.Worksheets("Lager").Activate



'Listbox leeren

'Me.ListBoxLager.Clear



'Zellbereich einlesen

Dim rng As Range

Set rng = shLager.Range("A1").CurrentRegion

Set rng = rng.Offset(1, 0).Resize(rng.Rows.Count - 1)



'Listbox befüllen

With ListBoxLager



        .RowSource = rng.Address(external:=True)

        .ColumnCount = rng.Columns.Count ' Spaltenanzhal festlegen

        .ColumnWidths = "20;80;80;50;40;40;40;50;50;40;40;80;50;50;40;30;30;30" 'Spaltenbreite festlegen

        .ColumnHeads = True

        .ListIndex = 0



End With



End Sub

Dies ist der derzeitige Code für das Befüllen meiner ListBox. Nun möchte ich aber mit einem Suchfeld (über der Listbox) die Auswahl eingrenzen, da die Daten gefühlt unendlich erscheinen. Hier wollte ich quasi über mehrere Spalten einer Tabelle die Suchfunktion wirken lassen. Ergebnisse sollen dann gefiltert in der Listbox erscheinen.

Weiter wollte ich im Vorfeld die ListBix leeren, damit die Ergebnisse angezeigt werden können. Die Funktion habe ich weiter oben stehen und auskommentiert, da ich dort einen Fehler bekomme.

Danke euch.

Hi
mal so als Idee, wie du das einfach realisieren kannst:

1. suche dir eine freie Zelle.
in diese kommt später der Text aus der Textbox für die Suche.
Die Zelle sei jetzt mal U1 im Tabellenblatt lager

2. füge der Liste "Lager" eine weitere Spalte hin zu (Spalte S)
in diese kommt eine Formel, die eine 1 ausgibt, wenn die Zeile später in der Liste angezeigt werden soll und ein "x" wenn nicht, also sowas wie

=Wenn(Istzahl(Suchen($U$1;B2));1;"x")

3. im Change-Event der Textbox für die Suche machst du jetzt folgendes:
- Textboxwert in die Zelle U1 schreiben
- die Lagerliste nach der neuen Spalte S aufsteigend sortieren, die Zeilen mit 1, die angezeigt werden sollen, stehen jetzt ganz oben.
- den Zellbereich mit 1 ermitteln und diesen als RowSource verwenden
um das zu machen, kannst du den Ausdruck Columns("S:S").SpecialCells(xlcelltypeformulas, 1) verwenden, das referenziert auf alle Zellen, die in Spalte 1 eine Formel haben, die eine Zahl als ergebnis ausspuckt.

konkreter Code dazu sähe so aus:

Private Sub Suchbegriff_Change()



'richtiges Tabellenblatt auswählen

ThisWorkbook.Worksheets("Lager").Activate

Range("U1").Value = Me.Suchbegriff.Value



'Listbox leeren

'Me.ListBoxLager.Clear



'Zellbereich einlesen

Dim rng As Range

Set rng = shLager.Range("A1").CurrentRegion

rng.Sort key1:=rng.Cells(1, rng.Columns.Count), order1:=xlAscending, Header:=xlYes

If WorksheetFunction.Sum(rng.Columns(rng.Columns.Count)) = 0 Then

    Set rng = rng.Offset(rng.Rows.Count + 3).Resize(1)

Else

    Set rng = rng.Columns(rng.Columns.Count).SpecialCells(xlCellTypeFormulas, 1).Offset(0, 1 - rng.Columns.Count).Resize(, rng.Columns.Count)

End If

'Listbox befüllen

With ListBoxLager

        .RowSource = rng.Address(external:=True)

        .ColumnCount = rng.Columns.Count ' Spaltenanzhal festlegen

        .ColumnWidths = "20;80;80;50;40;40;40;50;50;40;40;80;50;50;40;30;30;30;0" 'Spaltenbreite festlegen

        .ColumnHeads = True

        .ListIndex = 0

End With



End Sub

wenn du deine Datumswerte als Datum angezeigt bekommen und auch die Spaltenüberschriften haben willst, dann bekommst du das nur mit einer Befüllung über RowSource.
dann geht das Filtern aber nur mit einer separat Tabelle, oder wenn du wie hier die anzuzeigenden Zeilen nach oben sortierst (damit sie unter der Überschriftenzeile stehen) und diesen Bereich als RowSource verwendest.

Gruß Daniel

Suchfunktion in bestehender Listfunktion einbinden ...

Forumthread: Suchfunktion in bestehender Listfunktion einbinden ...

23
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Beliebteste Forumthreads (12 Monate)

Suchfunktion in bestehender Listfunktion einbinden ...

Forumthread: Suchfunktion in bestehender Listfunktion einbinden ...

23 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

23
Beiträge zum Forumthread

Beiträge zu diesem Forumthread