Microsoft Excel

Herbers Excel/VBA-Archiv

Zwischensumme

    Betrifft: Zwischensumme von: martin
    Geschrieben am: 02.10.2003 14:12:45

    hallo experten,

    mit folgender formel: =WENN(ISTFEHLER(SUMME(KGRÖSSTE(A8:H8;{1;2;3;4;5;6})));"";SUMME(KGRÖSSTE(A8:H8;{1;2;3;4;5;6}))), addiert er mir die sechs höchsten zahlen zusammen. das klappt.

    jetzt mein problem:
    das ergebnis erscheint erst, wenn die sechste zahl eingeben worden ist.
    gibt es eine möglichkeit: z.b. wenn ich vier zahlen eingeben habe, diese als zwischensumme anzeigen zu lassen?

    für eure hilfe wäre ich dankbar.

    gruss martin

      


    Betrifft: Die x-grössten Werte addieren - #ZAHL! vermeiden von: Boris
    Geschrieben am: 02.10.2003 14:30:18

    Hi Martin,

    aufgrund der maximalen Verschachtelungstiefe von 8 Funktionen fällt mir nur ne Lösung mit Hilfszelle ein.
    Hilfszelle D1 (Array-Formel):
    {=MIN(6;MAX(ISTZAHL(KGRÖSSTE(A8:H8;ZEILE(1:6)))*ZEILE(1:6)))}

    Und dann in irgendeine Zelle:
    =SUMMENPRODUKT(KGRÖSSTE(A8:H8;ZEILE(INDIREKT("1:"&D1))))

    Grüße Boris


      


    Betrifft: AW: Zwischensumme von: MartinBEE
    Geschrieben am: 02.10.2003 14:42:58

    schnell was gestrickt, geht viell noch einfacher:
    =SUMME(KGRÖSSTE(A8:H8;SPALTE(BEREICH.VERSCHIEBEN(A8;;;;WENN(ANZAHL2(A8:H8)>6;6;ANZAHL2(A8:H8))))))
    als Matrixformel eingeben (Strg+hoch+enter)
    Gruss Martin


      


    Betrifft: ohne Array und Hilfsspalte von: Panicman
    Geschrieben am: 02.10.2003 14:51:45

    Hallo Martin

    es geht auch so:
    =SUMMENPRODUKT(KGRÖSSTE(A8:H8;ZEILE(INDIREKT("1:"&6+((ANZAHL(A8:H8)<6)*(ANZAHL(A8:H8)-6))))))

    Gruß
    Holger


      


    Betrifft: Sehr schön! oT von: Boris
    Geschrieben am: 02.10.2003 14:56:50




      


    Betrifft: AW: ohne Array und Hilfsspalte von: martin
    Geschrieben am: 02.10.2003 14:59:14

    hallo holger,

    danke für die schnelle hilfe.
    es klappt aber wenn alle zellen leer sind, kommt der hinweis #bezug!
    kann man den unterdrücken.

    gruss martin


      


    Betrifft: Mit ISTFEHLER oder Bedingter Formatierung oT von: Boris
    Geschrieben am: 02.10.2003 15:00:44




      


    Betrifft: AW: Mit ISTFEHLER oder Bedingter Formatierung oT von: martin
    Geschrieben am: 02.10.2003 15:08:33

    danke an allen.

    so klappt es: =WENN(ISTFEHLER(SUMMENPRODUKT(KGRÖSSTE(A8:H8;ZEILE(INDIREKT("1:"&6+((ANZAHL(A8:H8)<6)*(ANZAHL(A8:H8)-6)))))));"";SUMMENPRODUKT(KGRÖSSTE(A8:H8;ZEILE(INDIREKT("1:"&6+((ANZAHL(A8:H8)<6)*(ANZAHL(A8:H8)-6)))))))

    bis bald!

    gruss martin


      


    Betrifft: AW: Mit ISTFEHLER oder Bedingter Formatierung oT von: Panicman
    Geschrieben am: 02.10.2003 15:19:12

    Hallo Martin,

    nun übertreib mal nicht ;-))
    den eigentlichen Fehler verursacht Kgrösste() es reicht nur den abzufangen
    =WENN(ISTFEHLER(KGRÖSSTE(A8:H8;6));"";SUMMENPRODUKT(KGRÖSSTE(A8:H8;ZEILE(INDIREKT("1:"&6+((ANZAHL(A8:H8)<6)*(ANZAHL(A8:H8)-6)))))))

    Gruß
    Holger


      


    Betrifft: AW: Mit ISTFEHLER oder Bedingter Formatierung oT von: martin
    Geschrieben am: 02.10.2003 15:44:54

    hallo holger,
    sorry, ich wollte mich auch nicht mit fremden lorbeeren schmücken. sondern nur eine rückmeldung geben.

    gruss martin


      


    Betrifft: Danke für die Rückmeldung, so .... von: Panicman
    Geschrieben am: 02.10.2003 15:49:52

    Hallo Martin,

    so hab ich das auch nicht aufgefasst. (deshalb der Smilie)
    Ich wollte dir nur Tipparbeit ersparen fürs nächste mal.

    Gruß
    Holger

    P.S. Du hast aber in sofern recht, das ich wirklich stolz darauf bin von BORIS geschmückt zu werden.


     

    Beiträge aus den Excel-Beispielen zum Thema " Zwischensumme"