Kassenbuch - Abfragen/Unterabfragen ???

Bild

Betrifft: Kassenbuch - Abfragen/Unterabfragen ???
von: Niko
Geschrieben am: 14.10.2003 21:03:12

Hallo.

Ich habe eine Frage zu den Abfragen.

Ich versuche ein Kassenbuch zu erweitern/ändern, leider fehlen mir die Excelkenntnisse.

Kann mir bitte jemand weiter helfen.

Das Beispiel des falschen Kassenbuches finden Sie hier:
http://www.hong.de/kassenbuch_falsch.xls

Das Beispiel des gewünschten Kassenbuches finden Sie hier (ohne Formel):
http://www.hong.de/kassenbuch_richtig.xls

So wie sie sehen, wird die Berechnung richtig durchgeführt, aber im Bestandbereich nicht richtig dargestellt. Der Bestand wird immer von oben nach unten berechnet, was auch falsch ist. Der Bestand soll nur beim Anfang des Tages berechnet werden.

Ich brauche das der aktuelle Bestand, nur angezeigt wird, wenn der neue Tag kommt (die Ausgaben oder Einnahmen diesen Tages werden bei dem nächsten Tag natürlich berechnet).

Das Formel der alten Berechnungen:
=WENN(A5>0;C4+A5;WENN(B5>0;C4-B5;""))
Da wird eigentliche Berechnung des Bestandes durchgeführt.

Ich habe dafür ein logischen Weg überlegt:

1) Wenn der Umsatz vorhanden ist, überprüfen ob auf der nächste Zeile noch ein Bestand vorhanden ist:
a) wenn keins, dann Bestand nicht berechnen
b) wenn es doch eins gibt, dann der letzte Bestand + diesen Umsatz – letzte Ausgaben
2) Wenn es kein Umsatz gibt, dann der letzte Einnahmen – letzte Ausgaben + letzte Bestand

Bin mir nicht sicher ob es auch ein richtiger logischer Weg ist.

Wie wird das ganze mit Excel realisiert?

Danke.
Cu.

Bild


Betrifft: AW: Kassenbuch - Abfragen/Unterabfragen ???
von: th.heinrich
Geschrieben am: 14.10.2003 21:33:03

hallo Niko,

warum so kompliziert ?

in C4: =A4-B4
in C5: =A5-B5+C4

diese formel runterkopieren.

gruss thomas


Bild


Betrifft: AW: Kassenbuch - Abfragen/Unterabfragen ???
von: PeterW
Geschrieben am: 14.10.2003 21:43:10

Hallo Niko,

etwas unverständlich ist die Tatsache, dass nach Eingaben für 2002 noch Eingaben für 2001 erfolgen. Versuch es mal in C5 mit dieser Formel:
=WENN(F5>F4;SUMME(A$4:A4)-SUMME(B$4:B4);"")
und dann runterziehen.

Gruß
Peter


Bild


Betrifft: AW: Kassenbuch - Abfragen/Unterabfragen ???
von: Arnim
Geschrieben am: 14.10.2003 23:23:16

Hallo
das geht mit folgender Array-Formel in C4:

=WENN(F4<>F5;SUMME(A$4:A4-B$4:B4);"")
Eingabe der Formel mit Tastenkombination Strg/Shift(Umschalt)/Enter

Diese Formel runterkopieren.

Gruß Arnim


Bild


Betrifft: Frage....
von: Niko
Geschrieben am: 15.10.2003 14:18:43

Hallo.

Ich habe alles da was ihr gepostet habt, ausprobiert, am nähersten war der PeterW.

Ich habe da noch ein paar Fragen.

Diese Formel:
=WENN(F5>F4;SUMME(A$4:A4)-SUMME(B$4:B4);"")

Funktioniert fast gut, nur ein kleiner Fehler in dieser Testdatei: http://www.hong.de/kassenbuch_update.xls

In dem Feld „C10“-> sollte auch 800 stehen, aber ist leer, da stimmt irgend was nicht mit der Berechnung von Ausnahmen?

Und wie kann man die Zahl 0 in der Anfangsbestand anzuzeigen in dem Feld C4 und nicht in C5, so dass es nicht manuell ändern muss? Oder soll da lieber manuell ändern für der Bestand auf das nächste Monat.

Danke.
Cu.


Bild


Betrifft: AW: Frage....
von: Arnim
Geschrieben am: 15.10.2003 14:43:15

Hallo,
da in C4 der Anfangsbestand/Übertrag stehen muss, wird diese Formel in C5 eingegeben:
=WENN(F5<>F6;C$4+SUMMENPRODUKT(A$5:A5-B$5:B5);"")
und runterkopiert.
Die Eingabe dieser Formel normal mit "Enter".

PS: Etwas ungewöhnlich ist die Datum-Spalte "F" - anstatt "A".


Bild


Betrifft: PS an Arnim
von: Niko
Geschrieben am: 15.10.2003 15:05:22

Arnim ich habe dein Formel ausprobiert, es zeigt mir die Daten falsch an.

Wenn ich dein Formel in dieser Datei http://www.hong.de/kassenbuch_update.xls einfüge, habe ich in dem Feld c8-> 1000 und in c9->200 was aber falsch ist.
Es sollte im Feld c8 nichts stehen, weil es noch der 01.01.2001 ist und in dem Feld c9 -> 1200, weil es ein neuer Tag ist, und der Bestand für Anfang diesen Tagen soll berechnet werden.

Danke.


Bild


Betrifft: Tagessaldo am Schluss!
von: Arnim
Geschrieben am: 15.10.2003 20:24:38

Hallo,
offensichtlich ist das eine Neuerfindung für den Kassensaldo!
Hier noch eine Formel für C5:
=WENN((C4=0)+(F5="")+(F4=F5);"";C$4+SUMMENPRODUKT(A$5:A5-B$5:B5))
Natürlich wird jetzt der erste Kasseneintrag für Einnahmen oder Ausgaben beim sog. Tages-Anfangssaldo berücksichtigt. Sonst wäre der ausgewiesene Saldo eine Lüge!
Du könntest natürlich die Einträge für Ausgaben oder Einnahmen in der jeweiligen Saldo-Zeile auslassen. Das würde jedoch gegen die Vorschriften verstoßen.
Und warum wird das Datum in F4 nicht ausgewiesen, sondern mit weißer Schrift ausgeblendet?
Also ich rate Dir zur ersten Formel - alles andere ist m.E. Unsinn.
Gruß Arnim


Bild


Betrifft: Super
von: Niko
Geschrieben am: 16.10.2003 22:23:32

Hallo.

Danke mehrmals, deine Formel funktioniert wunderbar, nur ein Korrektur sollte ich vornehem:
da wo steht SUMMENPRODUKT(A$5:A5-B$5:B5))
müsste ich das da verwenden SUMMENPRODUKT(A$5:A4-B$5:B4))
Ein Feld weniger ;=)

PS: Arnim
Eine allgemeine Frage:
da wo in dem Formel ein Pluszeichen im "Wenn" Bereich steht, ist gleichbedeutend einer UND-Verknüpfung?
Wenn ja, dann wie schreibt man darein eine Oder-Verknüpfung.

Danke.
Cu.


Bild


Betrifft: Bedeutet ODER
von: Arnim
Geschrieben am: 16.10.2003 23:12:58

Hallo Niko,
so hatte ich die Formel auch geschrieben, jedoch abgeändert, da ich diese Darstellung des Saldos im Kassenbuch nicht für richtig halte. Aber das ist Deine Sache!
Zur UND/ODER-Funktion:
Die Formel könnte auch so lauten:
=WENN(ODER(C4=0;ODER(H5="";ODER(H4=H5)));"";C$4+SUMMENPRODUKT(A4:A$5-B4:B$5))
Das "+" bedeutet also "ODER".
"UND" wäre:
=WENN((C4=0)*(H5="")*(H4=H5);"";C$4+SUMMENPRODUKT(A4:A$5-B4:B$5))
Das klappt dann allerdings nicht!

Gruß Arnim


Bild


Betrifft: letzte Frage ;=)
von: Niko
Geschrieben am: 17.10.2003 09:29:33

Moin.

Excel ist echt geil, kann man damit die Zeit sparen.
Ich dachte erst das geht nicht mit den normalen Formel, dachte soll macros einfügen.

Noch eine letzte Frage und dann das war's.
Z. B ich will in dem Feld G21 ein unsichtabares Zeichen einfügen:
@ (ich setze da eine weisse Schriftfarbe)
und in den Formel auf der Stelle ->
=WENN((C4=0)+(F5="")+(F4=F5);"";
erweitern, so dass, wenn dieses unsichtbares Zeichen in dem Feld NICHT steht, dann auch leer? Wie macht man so was?

WENN((C4=0)+(F5="")+(F4=F5)+(G21<>"@ mit der weissen Schriftfarbe");

Danke.
Cu.


Bild


Betrifft: Same procedure
von: Arnim
Geschrieben am: 17.10.2003 10:00:41

Hallo,
dann müsste wohl die Formel in C5 so lauten:
=WENN((C4=0)+(F5="")+(F4=F5)+(G5="@");"";C$4+SUMMENPRODUKT(A4:A$5-B4:B$5))
und runterkopieren.

Gruß Arnim

PS: Probiere die Array-Formel so, dann wird sie kürzer:
=WENN((C4=0)+(F5="")+(F4=F5)+(G5="@");"";C$4+SUMME(A4:A$5-B4:B$5))
Eingabe mit Tastenkombination Strg/Shift/Enter
(Cursor muss sich in der Bearbeitungszeile befinden!)
Die Formel wird dann von geschweiften Klammern eingerahmt.


Bild


Betrifft: AW: Same procedure - fast!
von: Arnim
Geschrieben am: 17.10.2003 12:40:19

Hallo,
Du hattest das "NICHT" so klein geschrieben :-), dass ich es nicht beachtet habe. Vermutlich sollte der Teil der Formel also so aussehen: +(G5<>"@")
(Jetzt macht das Ganze für mich auch Sinn!)

Gruß Arnim


 Bild

Beiträge aus den Excel-Beispielen zum Thema " Kassenbuch - Abfragen/Unterabfragen ???"