datenimport von access nach excel

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Benutzer

Hallo Rainer,
vielen Dank für Deine Bemühungen. Das große Problem, dass ich beim Datenimport habe, sind die unterschiedlichen Namen der Access-Tabellen.
Vielleicht sollte ich mein Problem etwas ausführlicher schildern:
1. Ich habe eine Access-Datenbank aus der ich bedarfsweise Daten (Tabellenblätter) in meine Exceldatei überführen möchte.
2. Der Name des benötigten Access-Tabellenblattes wird in Excel über eine Kombo-Box ausgewählt (=und in eine Hilfszelle geschrieben).
3. Gesteuert über eine Schaltfläche (Button) in meiner Excel-Datei möchte ich nun das Access-Tabellenblatt, dessen Namen in der Hilfszelle abgelegt ist, in ein definiertes Tabellenblatt in meiner Exceldatei importieren.
Ich scheitere allerdings auch schon seit Tagen und habe immernoch keine Idee. Deshalb bedanke ich mich in jedem Fall ganz herzlich für Deine Bemühungen. Vielleicht gehe ich die Sache auch komplett falsch an. Alternative Lösungsvorschläge nehme ich dankend an.
Beste Grüße
Thomas

Hallo Thomas,
ich habe ein bestehendes Programm VBA-Programm etwas angepasst und denke, dass es bei deinem Problem weiterhelfen könnte:
Das folgende Programm übernimmst du in einen normalen Modul deiner Arbeitsmappe:
Sub ADO_Recordset_komplett_übernehmen()
' Ein Recordset wird mit sämtlichen Feldern
' in eine Tabelle übernommen
Dim con As ADODB.Connection
Dim datei As String
Dim fld As Field
Dim rs As ADODB.Recordset
Dim spalte As Long
Dim accTab As String
Dim ws As Worksheet
Dim zeile As Long

accTab = "Tbl-" & ThisWorkbook.Worksheets("Auswertung").Range("E3")

' (1) Verbindung zur Datenbank herstellen

datei = ThisWorkbook.Path & "\Datenbank.mdb"

Set con = New ADODB.Connection
con.Open ConnectionString:= _
"Provider=Microsoft.Jet.OLEDB.4.0;" & _
"Data Source=" & datei

' (2) Recordset erstellen

Set rs = New ADODB.Recordset
rs.CursorLocation = adUseServer
rs.Open Source:=accTab, _
ActiveConnection:=con, _
CursorType:=adOpenKeyset, _
LockType:=adLockReadOnly, _
Options:=adCmdTableDirect
' (3) Recordset auflisten

' (3a) Tabellenblatt vorbereiten

Set ws = ThisWorkbook.Worksheets("Daten")
ws.UsedRange.ClearContents

' (3b) Spaltenüberschriften schreiben

spalte = 1
For Each fld In rs.Fields
ws.Cells(1, spalte) = fld.Name
spalte = spalte + 1
Next fld

' (3c) Sätze des Recordsets auflisten

ws.Range("A2").CopyFromRecordset _
Data:=rs, _
MaxRows:=ws.Rows.Count - 1, _
MaxColumns:=ws.Columns.Count

' (3d) Tabellenblatt formatieren

ws.UsedRange.Columns.AutoFit

' (4) Recordset und Verbindung schließen

rs.Close
con.Close
Set rs = Nothing
Set con = Nothing
End Sub
Im VBA-Editor setzt du unter Extras | Verweise... einen Verweis auf Microsoft ActiveX Data Objects 2.x Library.
Deinen CommandButton verbindest du mit der obigen Prozedur. Rechter Mausklick auf das Blattregister von "Auswertung" und dann "Code anzeigen". In den sich öffnenden Klassenmodul der Tabelle schreibst du die folgende Prozedur:


Private Sub CommandButton1_Click()
ADO_Recordset_komplett_übernehmen
End Sub

Du könntest diesem Button noch die Eigenschaft "TakeFocusOnClick" = False spendieren (ist aber nicht lebensnotwendig).
MfG
Dieter

Beliebteste Forumthreads (12 Monate)

datenimport von access nach excel

7
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

datenimport von access nach excel

7 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu verwandten Themen

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

7
Beiträge zum Forumthread

Beiträge zu diesem Forumthread