formatieren

Forumthread: formatieren

formatieren

20.07.2004 19:52:30

Herbert

Hallo!
Ich habe in Zelle A1 ein älteres Datum
und in A2 das aktuelle Datum.
In A3 steht die Formel Bruchteiljahre.
Das Ergebnis lautet z.B. 3,75 Jahre.
Meine Frage: kann ich die Zelle so formatieren damit ich z.B. 3Jahre 8Monate und die einzelnen Tage bekomme?

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: formatieren

20.07.2004 20:06:51

Hermann

Hallo Herbert,
das ergebniss aus der Formel BRTEILJAHRE läst sich nicht in das von dir gewünschte Format ändern.
Nimm statt dessen die Funktion DATEDIF mit der kannst du das gewünschte machen.
Erläuterung der DATEDIF-Funktion:

Syntax: DATEDIF(Datum1;Datum2;"Parameter")
Datum2 muß größer als Datum1 sein.
Parameter (Muß immer in "" stehen):

y = Jahre DATEDIF("01.01.04";"15.02.05";"y") = 1
m = Monate DATEDIF("01.01.04";"15.02.05";"m") = 13
d = Tage DATEDIF("01.01.04";"15.02.05";"d") = 410
ym = Monate minus Jahre
DATEDIF("01.01.04";"15.02.05";"ym") = 1 (13 Monate -1 Jahr (12 Monate))
yd = Tage minus Jahre
DATEDIF("01.01.04";"15.02.05";"yd") = 45 (410 Tage - 1 Jahr (365 Tage !!))
md = Tage minus Monate minus Jahre
DATEDIF("01.01.04";"15.02.05";"md") = 14 (Differenz vom 01.02. & 15.02
Gruß Hermann

AW: Zeitraum in Jahren, Monaten und Tagen angeben

Hallo Herbert,
Per Format geht das nicht :-(
Aber per Formel :-)

Tabelle3

	A
1	05.04.1914
2	20.07.2004
3	90 Jahr(e), 3 Monat(e), 106 Tag(e)

Formeln der Tabelle

A2 : =HEUTE()
A3 : =DATEDIF(A1;A2;"y")&" Jahr(e), "&DATEDIF(A1;A2;"ym")&" Monat(e), "&DATEDIF(A1;A2;"yd")&" Tag(e)"

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download
Servus aus dem Salzkammergut
Franz

AW: Zeitraum in Jahren, Monaten und Tagen angeben

Herbert

Danke werde die beiden Tip´s probieren
mfG
Herbert

AW: Zeitraum in Jahren, Monaten und Tagen angeben

20.07.2004 20:13:36

Annett

Hallo Franz

Tabelle1

	A
1	31.10.2002
2	30.10.2003
3	0 Jahr(e), 11 Monat(e), 364 Tag(e)

Formeln der Tabelle

A3 : =DATEDIF(A1;A2;"y")&" Jahr(e), "&DATEDIF(A1;A2;"ym")&" Monat(e), "&DATEDIF(A1;A2;"yd")&" Tag(e)"

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download
Gruß Annett

AW: Danke für den Hinweis ;-)

Hallo Annett,
Du bist "a Nette"
muss latürnich so heissen:

Tabelle3

	A
1	05.04.1914
2	20.07.2004
3	90 Jahr(e), 3 Monat(e), 15 Tag(e)

Formeln der Tabelle

A2 : =HEUTE()
A3 : =DATEDIF(A1;A2;"y")&" Jahr(e), "&DATEDIF(A1;A2;"ym")&" Monat(e), "&DATEDIF(A1;A2;"md")&" Tag(e)"

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download
Servus aus dem Salzkammergut
Franz

AW: Danke für den Hinweis ;-)

20.07.2004 20:19:25

Annett

Hallo Franz
ich würde sagen sa fehlt noch ein Tag. Ich benutze mal wieder mein Beispiel.

Tabelle1

	A
1	31.10.2002
2	30.10.2003
3	0 Jahr(e), 11 Monat(e), 29 Tag(e)

Formeln der Tabelle

A3 : =DATEDIF(A1;A2;"y")&" Jahr(e), "&DATEDIF(A1;A2;"ym")&" Monat(e), "&DATEDIF(A1;A2;"md")&" Tag(e)"

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download
Gruß Annett

AW: Na ja, dann eben so ...

Hallo Annett,
bist Du jetzt zufrieden ;-)

Tabelle3

	A	B
1	05.04.1914	90
2	20.07.2004	3
3	90 Jahr(e), 3 Monat(e), 15 Tag(e)	15
4
5	31.10.1914	89
6	30.10.2004	11
7	89 Jahr(e), 11 Monat(e), 30 Tag(e)	30
8
9	01.11.1914	89
10	30.10.2004	11
11	89 Jahr(e), 11 Monat(e), 29 Tag(e)	29
12
13	02.11.1914	89
14	30.10.2004	11
15	89 Jahr(e), 11 Monat(e), 28 Tag(e)	28

Formeln der Tabelle

B1 : =DATEDIF(A1;A2;"y")
A2 : =HEUTE()
B2 : =DATEDIF(A1;A2;"ym")
A3 : =DATEDIF(A1;A2;"y")&" Jahr(e), "&DATEDIF(A1;A2;"ym")&" Monat(e), "&REST(TAG(A2)-TAG(A1);TAG(DATUM(JAHR(A2);MONAT(A1)+1;0)))&" Tag(e)"
B3 : =REST(TAG(A2)-TAG(A1);TAG(DATUM(JAHR(A2);MONAT(A1)+1;0)))
B5 : =DATEDIF(A5;A6;"y")
B6 : =DATEDIF(A5;A6;"ym")
A7 : =DATEDIF(A5;A6;"y")&" Jahr(e), "&DATEDIF(A5;A6;"ym")&" Monat(e), "&REST(TAG(A6)-TAG(A5);TAG(DATUM(JAHR(A6);MONAT(A5)+1;0)))&" Tag(e)"
B7 : =REST(TAG(A6)-TAG(A5);TAG(DATUM(JAHR(A6);MONAT(A5)+1;0)))
B9 : =DATEDIF(A9;A10;"y")
B10 : =DATEDIF(A9;A10;"ym")
A11 : =DATEDIF(A9;A10;"y")&" Jahr(e), "&DATEDIF(A9;A10;"ym")&" Monat(e), "&REST(TAG(A10)-TAG(A9);TAG(DATUM(JAHR(A10);MONAT(A9)+1;0)))&" Tag(e)"
B11 : =REST(TAG(A10)-TAG(A9);TAG(DATUM(JAHR(A10);MONAT(A9)+1;0)))
B13 : =DATEDIF(A13;A14;"y")
B14 : =DATEDIF(A13;A14;"ym")
A15 : =DATEDIF(A13;A14;"y")&" Jahr(e), "&DATEDIF(A13;A14;"ym")&" Monat(e), "&REST(TAG(A14)-TAG(A13);TAG(DATUM(JAHR(A14);MONAT(A13)+1;0)))&" Tag(e)"
B15 : =REST(TAG(A14)-TAG(A13);TAG(DATUM(JAHR(A14);MONAT(A13)+1;0)))

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download
Servus aus dem Salzkammergut
Franz

AW: Na ja, dann eben so ...

20.07.2004 20:59:57

Annett

Hallo Franz
das war nun kein Angriff gegen Deine Person. Mir war nur aufgefallen das die Formel nicht ganz korrekt war.
Gruß Annett

AW: Richtig oder nicht richtig...

Hallo Annett,
... das ist so 'ne Sache, sieh selbst:
Spalte
B - meine neue Formel, immer richtig - aber leider sehr lang
C - Formel von www.excelformeln.de
D - DATEDIF
E - meine vorher gepostete Formel - aber logisch korrigiert
F - meine vorher gepostete Formel
rot - falsches Ergebnis
grün - alles ok

Tabelle3

	A	B	C	D	E	F
1	29.02.1916	87
2	28.04.2003	1
3	87 Jahr(e), 1 Monat(e), 27 Tag(e)	30	28	30	30	27
4
5	31.10.1914	89
6	30.10.2004	11
7	89 Jahr(e), 11 Monat(e), 30 Tag(e)	30	30	29	29	30
8
9	29.01.1916	88
10	28.04.2004	2
11	88 Jahr(e), 2 Monat(e), 30 Tag(e)	30	30	30	30	30
12
13	29.01.1916	88
14	28.05.2004	3
15	88 Jahr(e), 3 Monat(e), 30 Tag(e)	29	30	29	29	30

Formeln der Tabelle

B1 : =DATEDIF(A1;A2;"y")
B2 : =DATEDIF(A1;A2;"ym")
A3 : =DATEDIF(A1;A2;"y")&" Jahr(e), "&DATEDIF(A1;A2;"ym")&" Monat(e), "&REST(TAG(A2)-TAG(A1);TAG(DATUM(JAHR(A2);MONAT(A1)+1;0)))&" Tag(e)"
B3 : =REST(TAG(A2)-TAG(A1);TAG(DATUM(JAHR(A2);MONAT(A2);0)))+(TAG(A1)>TAG(DATUM(JAHR(A2);MONAT(A2);0)))
C3 : =TAG(A2)-TAG(A1)+(TAG(A1)>TAG(A2))*TAG(DATUM(JAHR(A1);MONAT(A1)+1;))
D3 : =DATEDIF(A1;A2;"md")
E3 : =REST(TAG(A2)-TAG(A1);TAG(DATUM(JAHR(A2);MONAT(A2);0)))
F3 : =REST(TAG(A2)-TAG(A1);TAG(DATUM(JAHR(A2);MONAT(A1)+1;0)))
B5 : =DATEDIF(A5;A6;"y")
B6 : =DATEDIF(A5;A6;"ym")
A7 : =DATEDIF(A5;A6;"y")&" Jahr(e), "&DATEDIF(A5;A6;"ym")&" Monat(e), "&REST(TAG(A6)-TAG(A5);TAG(DATUM(JAHR(A6);MONAT(A5)+1;0)))&" Tag(e)"
B7 : =REST(TAG(A6)-TAG(A5);TAG(DATUM(JAHR(A6);MONAT(A6);0)))+(TAG(A5)>TAG(DATUM(JAHR(A6);MONAT(A6);0)))
C7 : =TAG(A6)-TAG(A5)+(TAG(A5)>TAG(A6))*TAG(DATUM(JAHR(A5);MONAT(A5)+1;))
D7 : =DATEDIF(A5;A6;"md")
E7 : =REST(TAG(A6)-TAG(A5);TAG(DATUM(JAHR(A6);MONAT(A6);0)))
F7 : =REST(TAG(A6)-TAG(A5);TAG(DATUM(JAHR(A6);MONAT(A5)+1;0)))
B9 : =DATEDIF(A9;A10;"y")
B10 : =DATEDIF(A9;A10;"ym")
A11 : =DATEDIF(A9;A10;"y")&" Jahr(e), "&DATEDIF(A9;A10;"ym")&" Monat(e), "&REST(TAG(A10)-TAG(A9);TAG(DATUM(JAHR(A10);MONAT(A9)+1;0)))&" Tag(e)"
B11 : =REST(TAG(A10)-TAG(A9);TAG(DATUM(JAHR(A10);MONAT(A10);0)))+(TAG(A9)>TAG(DATUM(JAHR(A10);MONAT(A10);0)))
C11 : =TAG(A10)-TAG(A9)+(TAG(A9)>TAG(A10))*TAG(DATUM(JAHR(A9);MONAT(A9)+1;))
D11 : =DATEDIF(A9;A10;"md")
E11 : =REST(TAG(A10)-TAG(A9);TAG(DATUM(JAHR(A10);MONAT(A10);0)))
F11 : =REST(TAG(A10)-TAG(A9);TAG(DATUM(JAHR(A10);MONAT(A9)+1;0)))
B13 : =DATEDIF(A13;A14;"y")
B14 : =DATEDIF(A13;A14;"ym")
A15 : =DATEDIF(A13;A14;"y")&" Jahr(e), "&DATEDIF(A13;A14;"ym")&" Monat(e), "&REST(TAG(A14)-TAG(A13);TAG(DATUM(JAHR(A14);MONAT(A13)+1;0)))&" Tag(e)"
B15 : =REST(TAG(A14)-TAG(A13);TAG(DATUM(JAHR(A14);MONAT(A14);0)))+(TAG(A13)>TAG(DATUM(JAHR(A14);MONAT(A14);0)))
C15 : =TAG(A14)-TAG(A13)+(TAG(A13)>TAG(A14))*TAG(DATUM(JAHR(A13);MONAT(A13)+1;))
D15 : =DATEDIF(A13;A14;"md")
E15 : =REST(TAG(A14)-TAG(A13);TAG(DATUM(JAHR(A14);MONAT(A14);0)))
F15 : =REST(TAG(A14)-TAG(A13);TAG(DATUM(JAHR(A14);MONAT(A13)+1;0)))

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download
Servus aus dem Salzkammergut
Franz

AW: formatieren

andreas

hallo herbert,
wie wäre es statt der Bruchteilformel mit datedif ?
die kannst dann ja die 3 von mir aufgezeigten in einer Formel zusammen fassen

	A	B	C	D
1	11.01.2002	10.01.2004	1	Differenz in Jahren
2	11.01.2002	10.01.2003	11	Differenz in Monaten
3	11.01.2002	10.01.2003	30	Differenz in Tagen
4				Differenz beträgt 1 Jahre und 11 Monate 30 Tage

Formeln der Tabelle

C1 : =DATEDIF(A1;B1;"y")
C2 : =DATEDIF(A2;B2;"m")
C3 : =DATEDIF(A3;B3;"md")
D4 : ="Differenz beträgt "&C1&" Jahre und "&C2&" Monate "&C3&" Tage"

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download
gruß
andreas e

http://www.fachforen.de
eine Linksammlung zu diversen fachforen

AW: formatieren

Konni

Hallo Andreas e,
ich möchte mich an dieser Stelle einklinken.
Wie stellt man es an, wenn ich die Differenz von einem Datum mit Uhrzeit (hh:mm:ss) aus der Vergangenheit mit dem Datum von heute mit Uhrzeit (hh:mm:ss) ermitteln will. Weiterhin soll auf die gleiche Weise die Differenz von einem Datum mit Uhrzeit (hh:mm:ss) in der Zukunft mit dem Datum von heute mit Uhrzeit (hh:mm:ss) ermittelt werden.
Ich habe schon Vieles probiert, scheiterte aber immer daran, wenn die Zukunftszeit kleiner als die Heute-Zeit ist.
Die aktuelle Uhrzeit mit Datum habe ich als VBA-Code. - Das Ganze soll ein Geburtstagsgeschenk für einen Kollegen sein, der damit seine Arbeitszeit in der Firma ermitteln kann (Tag der Einstellung bis heute und Tag der Rente von heute bis Stichtag).
Auf eine Antwort bin ich gespannt! Auch wenn es keine gibt, vielen Dank: Konni

Zeitdifferenzen

20.07.2004 21:16:40

Konni

Hallo Freaks,
ich muss mich an die Spezialisten wenden.
Wie stellt man es an, wenn ich die Differenz von einem Datum mit Uhrzeit (hh:mm:ss) aus der Vergangenheit mit dem Datum von heute mit Uhrzeit (hh:mm:ss) ermitteln will. Weiterhin soll auf die gleiche Weise die Differenz von einem Datum mit Uhrzeit (hh:mm:ss) in der Zukunft mit dem Datum von heute mit Uhrzeit (hh:mm:ss) ermittelt werden.
Ich habe schon Vieles probiert, scheiterte aber immer daran, wenn die Zukunftszeit kleiner als die Heute-Zeit ist. Gleiches gilt, wenn die Vergangenheitszeit größer als die Heute-Zeit ist.
Die aktuelle Uhrzeit mit Datum habe ich als VBA-Code. - Das Ganze soll ein Geburtstagsgeschenk für einen Kollegen sein, der damit seine Arbeitszeit in der Firma ermitteln kann (Tag der Einstellung bis heute und Tag der Rente von heute bis Stichtag).
Auf eine Antwort bin ich gespannt! Auch wenn es keine gibt, vielen Dank: Konni

AW: so lange noch ;-)

Hallo Konni,

Tabelle3

	A	B
1	20.07.2004 21:53
2	30.09.2023 00:00
3
4	7010,088194	Du mußt noch 19 Jahr(e), 2 Monat(e), 10 Tag(e) und 2 Stunde(n) 7 Minute(n) arbeiten!

Formeln der Tabelle

A4 : =A2-A1
B4 : ="Du mußt noch "&DATEDIF(A1;A2;"y")&" Jahr(e), "&DATEDIF(A1;A2;"ym")&" Monat(e), "&REST(TAG(A2)-TAG(A1);TAG(DATUM(JAHR(A2);MONAT(A2);0)))+(TAG(A1)>TAG(DATUM(JAHR(A2);MONAT(A2);0)))&" Tag(e) und "&KÜRZEN(REST(A4;1)*24)&" Stunde(n) "&RUNDEN(REST(REST(A4;1)*24;1)*60;0)&" Minute(n) arbeiten!"

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download
Servus aus dem Salzkammergut
Franz

Beliebteste Forumthreads (12 Monate)

Forumthread: formatieren

14 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

14
Beiträge zum Forumthread

Beiträge zu diesem Forumthread