doppeltes Summewenn + zeilenproblem

Forumthread: doppeltes Summewenn + zeilenproblem

26.07.2004 00:12:24

Camper

Hi,
ich habe zwei Probleme!
1.
ich wollte jetzt zählen, wenn in der ersten spalten a oder b zutrifft UND in der 2. Spalte a,b,c zutrifft!
mein versuch war: =SUMME(ZÄHLENWENN(C3:E204;{"SD"."PR"});SUMME(ZÄHLENWENN(E3:E204;{"A1"}))) hierbei addiert er aber die treffer in spalte 1, wo a oder b auftritt, und die treffer der spalte 2,wo a auftritt (hab kein b,c reingenommen)
HILFE :-)
2.
bitte bild anschauen!
Userbild

wenn ich hier summewenn mache, dann nimmt er halt nur die ersten Werte der zugehörigen zeilen: C1 und C10 und daraus den durchschnitt!
ich will aber dass er jeweils alle 5 werte die zu"SD" gehören nimmt und den durchschnitt daraus ermittelt!!
Danke !!
Andreas
Danke!

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: doppeltes Summewenn + zeilenproblem

26.07.2004 08:08:31

M@x

Hi Andreas,
Ich hab mir jetzt nicht deine Formeln genau angeschaut, aber es dürfte an den zusammengezogenen Zellen liegen, schreib als Test wieder 5 mal "SD" hinein, und schau was dann passiert
Gruss
M@x

AW: doppeltes Summewenn + zeilenproblem

26.07.2004 12:51:38

Camper

Hi,
das will ich ja eben nicht, weil sich dann bei mir andere Ergebnisse verändern!!
deshalb muss ich das "5mal reinschreiben" umgehen!
Hilfe zur ersten Frage?
Mfg Camper

AW: doppeltes Summewenn + zeilenproblem

26.07.2004 13:40:02

M@x

Hi,
das geht leider nicht.
Notlösung: eine verdeckte Hilfsspalte, in der es keine Zusammengezogene Zellen gibt,
was gscheiteres fällt mir nicht ein, außer du bist in VBA so gut drauf
Gruss
M@x

AW: doppeltes Summewenn + zeilenproblem

26.07.2004 14:49:53

Camper

Hi,
ok danke M@x- ich glaub dir mal!
muss ich wohl noch ne extra spalte anlegen :/

AW: mit oder ohne Hilfsspalte...

Hallo "Camper" Andreas,
Dein Problem läßt sich natürlich auch ohne Hilfsspalte lösen - ABER um welchen Preis ?
Lösung
rot = ohne Hilfsspalte
blau = mit Hilfsspalte

Tabelle1

	A	B	C	D	E
1	SD	SD	47	Summen
2		SD	41	SD	163
3		SD	15	PD	258
4		SD	43	SD	306
5		SD	17	Mittelwert
6	PD	PD	70	SD	32,60
7		PD	76	PD	64,50
8		PD	70	SD	61,20
9		PD	42	Summen
10	SD	SD	85	SD	469
11		SD	51	PD	258
12		SD	64	Mittelwert
13		SD	57	SD	46,90
14		SD	49	PD	64,50

Formeln der Tabelle

B1 : =A1
B2 : =WENN(A2="";B1;A2)
D2 : =A1
E2 : {=SUMME(WENN(ZEILE($1:$14)<KKLEINSTE(WENN(A$1:A$14<>"";ZEILE($1:$14));ZEILE(A2));C$1:C$14))}
B3 : =WENN(A3="";B2;A3)
D3 : {=INDEX(A:A;KKLEINSTE(WENN(A$1:A$14<>"";ZEILE($1:$14));ZEILE(A2)))}
E3 : {=SUMME(WENN(ZEILE($1:$14)<WENN(ANZAHL2(A$1:A$14)>=ZEILE(A3);KGRÖSSTE((A$1:A$14<>"")*ZEILE($1:$14);ANZAHL2(A$1:A$14)+1-ZEILE(A3));99);C$1:C$14))-SUMME(E$2:E2)}
B4 : =WENN(A4="";B3;A4)
D4 : {=INDEX(A:A;KKLEINSTE(WENN(A$1:A$14<>"";ZEILE($1:$14));ZEILE(A3)))}
E4 : {=SUMME(WENN(ZEILE($1:$14)<WENN(ANZAHL2(A$1:A$14)>=ZEILE(A4);KGRÖSSTE((A$1:A$14<>"")*ZEILE($1:$14);ANZAHL2(A$1:A$14)+1-ZEILE(A4));99);C$1:C$14))-SUMME(E$2:E3)}
B5 : =WENN(A5="";B4;A5)
B6 : =WENN(A6="";B5;A6)
D6 : =D2
E6 : {=SUMME(WENN(ZEILE($1:$14)<KKLEINSTE(WENN(A$1:A$14<>"";ZEILE($1:$14));ZEILE(A2));C$1:C$14))/SUMME(KKLEINSTE(WENN((A$1:A$15<>"")+(ZEILE($1:$15)=ANZAHL(C$1:C$14)+1);ZEILE($1:$15));ZEILE(1:2))*{-1;1})}
B7 : =WENN(A7="";B6;A7)
D7 : =D3
E7 : {=(SUMME(WENN(ZEILE($1:$14)<WENN(ANZAHL2(A$1:A$14)>=ZEILE(A3);KKLEINSTE(WENN(A$1:A$14<>"";ZEILE($1:$14));ZEILE(A3));99);C$1:C$14))-SUMME(E$2:E2))/SUMME(KKLEINSTE(WENN((A$1:A$15<>"")+(ZEILE($1:$15)=ANZAHL(C$1:C$14)+1);ZEILE($1:$15));ZEILE(2:3))*{-1;1})}
B8 : =WENN(A8="";B7;A8)
D8 : =D4
E8 : {=(SUMME(WENN(ZEILE($1:$14)<WENN(ANZAHL2(A$1:A$14)>=ZEILE(A4);KKLEINSTE(WENN(A$1:A$14<>"";ZEILE($1:$14));ZEILE(A4));99);C$1:C$14))-SUMME(E$2:E3))/SUMME(KKLEINSTE(WENN((A$1:A$15<>"")+(ZEILE($1:$15)=ANZAHL(C$1:C$14)+1);ZEILE($1:$15));ZEILE(3:4))*{-1;1})}
B9 : =WENN(A9="";B8;A9)
B10 : =WENN(A10="";B9;A10)
E10 : =SUMMEWENN(B:B;D10;C:C)
B11 : =WENN(A11="";B10;A11)
E11 : =SUMMEWENN(B:B;D11;C:C)
B12 : =WENN(A12="";B11;A12)
B13 : =WENN(A13="";B12;A13)
E13 : {=MITTELWERT(WENN(B$1:B$14=D13;C$1:C$14))}
B14 : =WENN(A14="";B13;A14)
E14 : {=MITTELWERT(WENN(B$1:B$14=D14;C$1:C$14))}
Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download
Und jetzt bau die hilfsspaltenfreie Lösung mal für 3000 Zeilen nach ;-)
Servus aus dem Salzkammergut
Franz

Beliebteste Forumthreads (12 Monate)

doppeltes Summewenn + zeilenproblem

Forumthread: doppeltes Summewenn + zeilenproblem

5 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread