Microsoft Excel

Herbers Excel/VBA-Archiv

finden-funktion

Betrifft: finden-funktion von: Jochen
Geschrieben am: 27.08.2004 17:48:58

Hallo Leute,

habe bei einer Musikdatenbank folgendes Problem:

Titel und Interpret können in der Vorlage durch ein "/" oder ein "-" voneinander getrennt sein. Bisher habe ich nur hingekriegt, dass Excel mit der Funtion FINDEN eines der beiden Zeichen, allerdings nicht alternativ auch das andere findet (FINDEN("/";Q4;2). Wie kann ich es einrichten, dass es mit beiden Zeichen funktioniert? Vielen Dank im voraus... :-)

  


Betrifft: AW: finden-funktion von: Jutta N.
Geschrieben am: 27.08.2004 18:05:43

Hallo,

eine Möglichkeit wäre: den Filter setzen, dann gehen "Benutzerdefiniert" zwei Wahlmöglichkeiten.

Gruß

Jutta


  


Betrifft: AW: finden-funktion von: mealone
Geschrieben am: 27.08.2004 18:26:55

hallo jochen,

=UND(ISTFEHL(FINDEN("/";Q4;2));ISTFEHL(FINDEN("-";Q4;2)))
liefert FALSCH wenn eines vorhanden und WAHR wenn keines vorhanden

wie du an og bsp erkennst hängt die antwort auf deine frage sehr stark davon ab
was du denn mit den infos dann machen willst?

gruss mealone


  


Betrifft: AW: finden-funktion von: Jochen
Geschrieben am: 27.08.2004 18:40:28

Danke für die Antworten. Motiv der Sache ist, Titel und Interpret in zwei verschiedenen Spalten wiederzugeben.


  


Betrifft: AW: finden-funktion von: Jörg Gradert
Geschrieben am: 27.08.2004 20:52:41

Hallo Jochen,

=WENN(ISTFEHLER(FINDEN("/";Q4;2));FINDEN("-";Q4;2);FINDEN("/";Q4;2))

Gruss Jörg


  


Betrifft: Sicher? von: Boris
Geschrieben am: 27.08.2004 22:06:56

Hi Jörg,

ich würde sagen: Das war nix...
Wenn "/" nicht gefunden wird, dann soll "-" gefunden werden, ansonsten wieder "/" (was ja bereits nicht gefunden wurde...)?!?

Das kann - sofern weder "/" noch "-" vorkommt, nur zu #WERT! führen.

Grüße Boris


  


Betrifft: Ja, sicher ! von: Jörg Gradert
Geschrieben am: 28.08.2004 02:01:53

Hallo Boris,

>Das kann - sofern weder "/" noch "-" vorkommt, nur zu #WERT! führen.

wenn keins der beiden Zeichen enthalten ist, führt es natürlich zu #WERT.
Was bei der einfachen Formel =FINDEN("/";Q4;2) ja auch der Fall ist, wenn das Zeichen nicht enthalten ist.
Gesucht war aber eine Formel für die Position des einen "/" oder anderen "-" Trennzeichens, da geh ich dann doch davon aus, dass das Zeichen, dessen Position ich ermitteln soll, auch im Suchstring enthalten ist.

>Wenn "/" nicht gefunden wird, dann soll "-" gefunden werden, ansonsten wieder "/" >(was ja bereits nicht gefunden wurde...)?!?

Dein Satz in der Klammer stimmt nicht, da der Sonst-Teil der WENN() nur abgehandelt wird, wenn die Bedingung nicht zutrifft, also wurde "/" doch gefunden!

=WENN(ISTFEHLER(FINDEN("/";Q4;2));FINDEN("-";Q4;2);FINDEN("/";Q4;2))

findet die Position des einen "/", oder anderen "-" Zeichens.

Gruss Jörg


  


Betrifft: AW: Ja, sicher ! von: Boris
Geschrieben am: 30.08.2004 09:50:24

Hi Jörg,

hast Recht - hab das etwas zu schnell gelesen.

Um auch bei keinem Vorkommen der Zeichen nicht #WERT! zu erhalten, könnte man das im übrigen so schreiben (KEINE Array-Formel):

=MIN(WENN(ISTZAHL(FINDEN({"/"."-"};Q4));FINDEN({"/"."-"};Q4)))

Grüße Boris


  


Betrifft: AW: finden-funktion von: mealone
Geschrieben am: 27.08.2004 23:01:47

hallo jochen,

alles vor den zeichen
=TEIL(Q4;1;WENN(ISTFEHL(FINDEN("-";Q4));FINDEN("/";Q4);FINDEN("-";Q4))-1)

und alles danach
=TEIL(Q4;WENN(ISTFEHL(FINDEN("-";Q4));FINDEN("/";Q4);FINDEN("-";Q4))+1;LÄNGE(Q4))

gruss
mealone


  


Betrifft: AW: finden-funktion von: Jochen
Geschrieben am: 28.08.2004 12:41:24

Ja, so funktioniert´s. Ein herzliches Dankeschön an alle die mitgeholfen haben.