Microsoft Excel

Herbers Excel/VBA-Archiv

Otto? Komme leider doch nicht klar!

Betrifft: Otto? Komme leider doch nicht klar! von: Melanie
Geschrieben am: 15.09.2004 11:12:53

Hallo Otto und alle anderen!

Vielen Dank noch mal für Deine Antwort aus meiner vorigen Frage. Ich wende mich mal direkt an Dich (weil der Code ja auch von Dir ist) und hoffe, das Du meinen Thread siehst. Falls jemand anders einen Tipp geben kann, bin ich natürlich auch nicht böse.
Also, der Code läuft bis s.u. und dann bricht er ab. WAS mache ich falsch? Wenn ich die letzte Zeile davor wegnehme läuft alles, aber die Materialnummern werden summiert, statt addiert.

Sub PivotBereich()
   Dim intZeilen As Integer
   Dim strSource As String
   Dim wksPivotGrund As Worksheet
   Dim wksPivotTabellen As Worksheet
   
   Set wksPivotGrund = _
    Workbooks("materialstamm.xls").Worksheets("matstammw7")
   Set wksPivotTabellen = _
    Workbooks("materialstamm.xls").Worksheets("Tabelle3")
   With wksPivotGrund
      intZeilen = .Cells(.Rows.Count, 1).End(xlUp).Row
      strSource = .Range(.Cells(1, 1), .Cells(intZeilen, 21)). _
       Address(RowAbsolute:=True, ColumnAbsolute:=True, _
       ReferenceStyle:=xlR1C1, External:=True)
   End With
   wksPivotTabellen.PivotTableWizard SourceType:=xlDatabase, _
    SourceData:=strSource, _
    TableDestination:=wksPivotTabellen.Range("A1"), _
    TableName:="Pivot1"
With ActiveSheet.PivotTables("Pivot1")
.PivotFields("Dpro").Orientation = xlRowField
.PivotFields("Ppro").Orientation = xlColumnField
.PivotFields("Material").Orientation = xlDataField
.PivotFields("Material").Function = xlCount

                ----- hier bekomme ich die Meldung, dass die Function-Eigenschaft des PivotField-Objektes nicht festgelegt werden kann....

End With

End Sub


Ich hoffe Du/Ihr könnt helfen.

Danke und Gruß,
Melanie
  


Betrifft: PivotTabelle .Function von: Otto
Geschrieben am: 15.09.2004 11:40:29

Hallo Melanie,

Meine Testumgebung: Excel 9.0 SR-1, Multilingual unter Windows 2000 SP-4

es wäre schon sinnlvoll gewesen, Deine Frage im alten Thread nur ein kleine Frage! (Pivot) (484242#484593) als Zusatzfrage zu stellen. Bei dieser Zusatzfrage kannst Du angeben, dass die Frage noch offen ist. Dann fühlt sich jeder angesprochen und der Zusammenhang bleibt gewahrt.
Ersetze doch mal die Felddefinitionen durch
   With ActiveSheet.PivotTables("Pivot1")
      .PivotFields("Dpro").Orientation = xlRowField
      .PivotFields("Ppro").Orientation = xlColumnField
      With .PivotFields("Material")
         .Orientation = xlDataField
         .Name = "Anzahl - Material"
         .Function = xlCount
      End With  
   End With  

Sollte das nicht funktionieren, melde Dich nochmal

Gruß Otto


  


Betrifft: AW: PivotTabelle .Function von: Melanie
Geschrieben am: 15.09.2004 16:43:59

Hallo Otto!

Ja, jetzt läuft es reibungslos. Sorry, dass ich einen neuen Beitrag geschrieben habe, wußte nicht, was besser ist. Jetzt weiß ist es - und nochmals DANKE!

Gruß,
Melanie