Makro unterbrechen??

Informationen und Beispiele zu den hier genannten Dialog-Elementen:
Bild

Betrifft: Makro unterbrechen??
von: Nadine
Geschrieben am: 15.02.2005 16:26:47
Hallo zusammen..
...ich habe einen VBA-Code der auch wunderbar läuft, allerdings kann man ihn mit der Controll und Pause-Taste unterbrechen... und genau das möchte ich eben nicht!
Kann man das irgendwie deaktivieren im Code?
Könnte man weiter beispielsweise den Menübefehl "Speichern unter" deaktivieren?
Vielen lieben Dank!
Lieben Gruss
Nadine

Bild

Betrifft: AW: Makro unterbrechen??
von: EtoPHG
Geschrieben am: 15.02.2005 16:40:36
Hallo Nadine,
Füge am Anfang deines Makros
Application.EnableCancelKey = xlDisabled
ein, dann wird die Unterbrechung verhindert.
Gruss Hansueli
Bild

Betrifft: AW: Makro unterbrechen??
von: Nepumuk
Geschrieben am: 15.02.2005 16:54:45
Hallo Nadine,
und an das Ende deines Makros: Application.EnableCancelKey=xlInterrupt
"Speichern unter" deaktivieren geht so:


Private Sub procControlEnableDisable(intId As Integer, bolStatus As Boolean)
    Dim myCommandBar As CommandBar, myCommandBarControl As CommandBarControl
    For Each myCommandBar In Application.CommandBars
        Set myCommandBarControl = myCommandBar.FindControl(ID:=intId, Recursive:=True)
        If Not myCommandBarControl Is Nothing Then myCommandBarControl.Enabled = bolStatus
    Next
End Sub
Public Sub sperren()
    Call procControlEnableDisable(748, False)
End Sub
Public Sub freigeben()
    Call procControlEnableDisable(748, True)
End Sub


Am besten machst du das im Workbook_Activate - bzw. im Workbook_Deactivate - Ereignis. Dann ist das ganze auf diese eine Mappe begrenzt.
Gruß
Nepumuk
Bild

Betrifft: Nepumuk Special ;-))
von: Franz W.
Geschrieben am: 15.02.2005 17:11:05
Hallo Nepumuk,
schön, Dich hier zu lesen!!
Toller Tipp, werd ich mir auch aufheben. Aber: wo kann man die anderen Code-Zahlen finden? Gibt's die in der Hilfe? Oder in spezieller Literatur?
Grüße
Franz
Bild

Betrifft: AW: Nepumuk Special ;-))
von: Nepumuk
Geschrieben am: 15.02.2005 17:25:44
Hallo Franz,
da gibt's was selbstgestricktes. Ist nicht sehr schön, alle Untermenüpunkte werden auch nicht aufgelistet und ab XP wird sogar die Tabelle zu klein.


Public Sub create_Id_list()
    Dim myCommandBarControl As CommandBarControl, myCommandBar As CommandBar
    Dim intColumn As Integer, intCount As Integer, lngRow As Long, intCbCount As Integer
    Application.ScreenUpdating = False
    lngRow = 1
    Cells.ClearContents
    For Each myCommandBar In Application.CommandBars
        intCbCount = intCbCount + 1
        Cells(lngRow, 1) = myCommandBar.Name
        Cells(lngRow, 2) = myCommandBar.NameLocal
        With Cells(lngRow, 3)
            .Value = intCbCount
            .Font.Bold = True
        End With
        For intCount = 1 To myCommandBar.Controls.Count
            With myCommandBar.Controls(intCount)
                 Cells(lngRow + intCount, 1) = .ID
                 Cells(lngRow + intCount, 2) = .Caption
            End With
        Next intCount
        lngRow = lngRow + intCount + 1
    Next
    On Error Resume Next
    For lngRow = 2 To Cells(65536, 1).End(xlUp).Row
        If IsNumeric(Cells(lngRow, 1)) And Trim(Cells(lngRow, 1)) <> "" Then
            intColumn = 3
            For Each myCommandBarControl In Application.CommandBars(Cells(Cells(lngRow, 1).End(xlUp).Row, 1).Value).Controls(Cells(lngRow, 2).Value).Controls
                If Err.Number <> 0 Then GoTo nextone
                With myCommandBarControl
                    Cells(lngRow, intColumn) = .ID
                    Cells(lngRow, intColumn + 1) = .Caption
                End With
                intColumn = intColumn + 2
            Next
        End If
nextone:
    Err.Clear
    Next
    Columns.AutoFit
    Application.ScreenUpdating = True
End Sub


Und noch was für's perönliche Archiv:
Webbrowser in der Tabelle größenoptimiert:
https://www.herber.de/forum/index.htm?https://www.herber.de/forum/messages/567537.html
Mit VBA ins Internet:
https://www.herber.de/forum/index.htm?https://www.herber.de/forum/messages/568605.html
Gruß
Nepumuk
Bild

Betrifft: Vielen Dank und...
von: Franz W.
Geschrieben am: 15.02.2005 18:29:31
... du hast Post.
Grüße
Franz
Bild

Betrifft: Dankeschön :-)
von: Nadine
Geschrieben am: 15.02.2005 18:30:34
Hui, jetzt bin ich echt perplex! Ausprobieren kann ich es erst morgen, aber ich sage schonmal DANKESCHÖN !! Kapieren werde ich es zwar nicht, weil das ist dann schon total Profi-like! Da kann ich nimmer folgen... Tjanu, kommt Zeit kommt Rat...
Aber ich find es echt cool und total lieb, dass ihr mir so helft! :)
 Bild

Beiträge aus den Excel-Beispielen zum Thema "Makro unterbrechen??"