Datum Farbig

Bild

Betrifft: Datum Farbig
von: Peter
Geschrieben am: 18.02.2005 11:06:01
Hallo zusammen,
gibt es eine Möglichkeit, da eingetragene Datum in einer Zelle entsprechend dem Wochentag einzufärben.
Montag=weiß
Dienstag=grün
Mittwoch=blau
Donnerstag=gelb
Freitag=rot
Danke
Peter

Bild

Betrifft: AW: Datum Farbig
von: c0bRa
Geschrieben am: 18.02.2005 11:08:29
hallo...
also ohne VBA oder 3rd party-programmen wirds nicht gehen, da bedingt formatierung nur 3 bedingungen akzeptiert...
Frage ist noch offen, via VBA sollts möglich sein...

Das Forum lebt auch von Rückmeldungen...
c0bRa
Bild

Betrifft: AW: Datum Farbig
von: Russi
Geschrieben am: 18.02.2005 11:28:43
Hi Peter,
hi c0bRa!
Es geht zum Teil, und zwar über die bedingte Formatierung:
"FORMEL IST" "=WOCHENTAG(A1;1)=1"
und dann gewünschtes Format einstellen. Die bed. Formatierung kann jedoch maximal 3 verschiedene Bedingungen bzw. Formate aufnehmen. 7 verschiedene Formate für 7 Wochentage geht leider nicht.
Viele Grüße
Russi
www.Russi.de.tt
Bild

Betrifft: AW: Datum Farbig
von: =Peter=
Geschrieben am: 18.02.2005 11:28:14
Hallo Peter, :-)
Du solltest dir mal das Addin CFPlus ansehen. Es bildet die Excel-Funktionalität der bedingten Formatierung nach. Es ist darauf ausgelegt mehr als 3 Bedingungen zur Verfügung zu stellen sowie alle Formatmöglichkeiten von Excel zu unterstützen.
www.xldynamic.com/source/xld.CFPlus.Download.html
Gruss
Peter
Bild

Betrifft: AW: Datum Farbig
von: WernerB.
Geschrieben am: 18.02.2005 12:12:18
Hallo Peter,
Dieses Makro gehört in das Modul des betreffenden Tabellenblattes.
Es reagiert auf Veränderungen in der Zelle "A1".

Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Address <> "$A$1" Then Exit Sub
    If Target.Cells.Count <> 1 Then Exit Sub
    If Target.Value = "" Then Exit Sub
    If Not IsDate(Target) Then Exit Sub
    Select Case Weekday(Target)
      Case 1: Target.Interior.ColorIndex = xlNone  'Sonntag
      Case 2: Target.Interior.ColorIndex = 2       'Montag
      Case 3: Target.Interior.ColorIndex = 10      'Dienstag
      Case 4: Target.Interior.ColorIndex = 5       'Mittwoch
      Case 5: Target.Interior.ColorIndex = 6       'Donnerstag
      Case 6: Target.Interior.ColorIndex = 3       'Freitag
      Case 7: Target.Interior.ColorIndex = xlNone  'Samstag
    End Select
End Sub

Viel Erfolg wünscht
WernerB.
P.S.: Dieses Forum lebt auch von den Rückmeldungen der Fragesteller an die Antworter !
Bild

Betrifft: AW: Datum Farbig
von: peter
Geschrieben am: 18.02.2005 13:21:09
Danke an Alle,
vielleicht habe ich mich falsch ausgedrückt, ich habe in der Spalte E4:E5000 jeweils ein Datum stehen, ich möchte das alle Zellen, wo zB. 4.4., 11.4.,18.4 usw. steht weiss werden
alle Zellen mit 5.4.,12.4 grün.
Peter
Bild

Betrifft: AW: Datum Farbig
von: WernerB.
Geschrieben am: 18.02.2005 13:36:41
Hallo Peter,
dieses Makro gehört in ein normales Standard-Modul:

Sub Peter()
Dim c As Range
    Application.ScreenUpdating = False
    For Each c In Range("E4:E5000")
      c.Interior.ColorIndex = xlNone
      If IsDate(c) Then
        Select Case Weekday(c)
          Case 1: c.Interior.ColorIndex = xlNone  'Sonntag
          Case 2: c.Interior.ColorIndex = 2       'Montag
          Case 3: c.Interior.ColorIndex = 10      'Dienstag
          Case 4: c.Interior.ColorIndex = 5       'Mittwoch
          Case 5: c.Interior.ColorIndex = 6       'Donnerstag
          Case 6: c.Interior.ColorIndex = 3       'Freitag
          Case 7: c.Interior.ColorIndex = xlNone  'Samstag
        End Select
      End If
    Next c
    Application.ScreenUpdating = True
End Sub

Gruß
WernerB.
Bild

Betrifft: Danke, funktioniert oT
von: peter
Geschrieben am: 18.02.2005 14:04:17

 Bild

Beiträge aus den Excel-Beispielen zum Thema "Datum Farbig"