ListView Steuerelement

• ListView Steuerelement von J.L. vom 02.04.2005 13:24:55
• AW: ListView Steuerelement - von K.Rola am 02.04.2005 14:47:27
  • AW: ListView Steuerelement - von J.L. am 02.04.2005 15:57:30
    • AW: ListView Steuerelement - von K.Rola am 02.04.2005 16:18:12
      • Danke o.T. - von J.L. am 02.04.2005 18:43:17
      • ListView vs. Listbox - von Rolf Beißner am 03.04.2005 08:55:46
        • AW: ListView vs. Listbox - von K.Rola am 03.04.2005 14:37:40
          • AW: ListView vs. Listbox - von Rolf Beißner am 03.04.2005 19:14:24

Betrifft: ListView Steuerelement
von: J.L.
Geschrieben am: 02.04.2005 13:24:55
Hallo Forum, wer hat Erfahrungen mit dem ListView-Element unter VBA.
Leider hat mich die Recherche, auch in anderen Foren, nicht wirklich weitergebracht. Hat jemand Hinweise ?
Wie müßte z.B. der folgende Code aussehen, wenn statt der Listboxen ein zweispaltiges Listview gefüllt werden soll?

Sub fillverlauf()
Dim VName$
VName = Dir(Pfad & "\Verlauf\*.xls")
    While VName <> ""
        ListBox3.AddItem (Left(VName, Len(VName) - 20))
        ListBox4.AddItem (Mid(VName, Len(VName) - 19))
        VName = Dir()
    Wend
End Sub

Vielen Dank
Jörg

Betrifft: AW: ListView Steuerelement
von: K.Rola
Geschrieben am: 02.04.2005 14:47:27

Hallo,
mal ein Beispiel, wie es prinzipiell geht.
In Spalte A stehen Namen, in Spalte B Vornamen:
Private Sub UserForm_Initialize()
Dim x As Long
Dim ix As ListItem
With ListView1
  .ColumnHeaders.Add , , "Name", 80
  .ColumnHeaders.Add , , "Vorname", 80
  .View = 3
  For x = 1 To 10
    .ListItems.Add , , Cells(x + 1, 1)
    .ListItems(x).SubItems(1) = Cells(x + 1, 2)
  Next
End With
End Sub

Gruß K.Rola

Der Fleiß ist die Wurzel aller Häßlichkeit.

Oscar Wilde

Betrifft: AW: ListView Steuerelement
von: J.L.
Geschrieben am: 02.04.2005 15:57:30
OK, das sieht schon mal sehr geschmeidig aus. Hab den Code wie folgt übernommen

Private Sub UserForm_Initialize()
Dim x As Long, pfad$ , VName$
Dim ix As ListItem
pfad = CreateObject("Scripting.FileSystemObject").GetFile(ActiveWorkbook.Path & "\" & ActiveWorkbook.Name).parentfolder.parentfolder
With ListView1
  .Width = 240
  .ColumnHeaders.Add , , "Name", 80
  .ColumnHeaders.Add , , "erstellt am", 80
  .ColumnHeaders.Add , , "zuletzt bearbeitet", 80
  .ColumnHeaders.Add , , "Name komplett", 80
  .View = 3
VName = Dir(pfad & "\Verlauf\*.xls")
    While VName <> ""
    x = x + 1
    .ListItems.Add , , Left(VName, Len(VName) - 20)
    .ListItems(x).SubItems(1) = Mid(VName, Len(VName) - 18, 8)
    .ListItems(x).SubItems(2) = FileDateTime(pfad & "\Verlauf\" & VName)
    .ListItems(x).SubItems(3) = pfad & "\Verlauf\" & VName
  VName = Dir()
    Wend
End With
End Sub

Jetzt möchte ich nur noch den in der verborgenen 4. Spalte abgelegten kompletten Ddateinamen auf Doppelklick zurückgegeben haben um die Datei zu öffnen. Mit SelectedItem bin ich noch nicht zum Ziel gekommen.
ListView ist geil.
Danke
Jörg

Betrifft: AW: ListView Steuerelement
von: K.Rola
Geschrieben am: 02.04.2005 16:18:12

Hallo,
Private Sub ListView1_DblClick()
Dim Pfad As String
Pfad = ListView1.SelectedItem.ListSubItems(3).Text
MsgBox Pfad
End Sub

Gruß K.Rola

Der Fleiß ist die Wurzel aller Häßlichkeit.

Oscar Wilde

Betrifft: Danke o.T.
von: J.L.
Geschrieben am: 02.04.2005 18:43:17
.

Betrifft: ListView vs. Listbox
von: Rolf Beißner
Geschrieben am: 03.04.2005 08:55:46
Hallo K.Rola,
nach welchen Kriterien arbeitest du
mit dieser oder jener???
Herzliche Grüße
Rolf

Betrifft: AW: ListView vs. Listbox
von: K.Rola
Geschrieben am: 03.04.2005 14:37:40

Hallo,
wenn die Anwendung privat ist, mit Listview, wenn es ein Auftrag ist, wird mit
Auftraggeber geklärt, wie er es haben will. Mir ist dann allerdings dann die Listbox
lieber, weil weniger Aufwand.

Gruß K.Rola

Es gibt keine Sünde außer der Dummheit.

Oscar Wilde

Betrifft: AW: ListView vs. Listbox
von: Rolf Beißner
Geschrieben am: 03.04.2005 19:14:24
Hallo K.Rola,
danke für die Info
+ den neuen Wilde(n) Spruch.
Herzliche Grüße
Rolf

Beiträge aus den Excel-Beispielen zum Thema "ListView Steuerelement"