Nochmal: Nullen weg

Bild

Betrifft: Nochmal: Nullen weg
von: Demian
Geschrieben am: 08.04.2005 09:57:45
Muss nochmal mit meinen Nullen kommen. In der angehängten Datei funktioniert die Prozedur zwar, die Zeilen mit den Nullen werden gelöscht. Dennoch bekomme ich eine Fehlermeldung in der letzten Zeile "if cells..." - Laufzeitfehler '13': Typen unverträglich.


Sub Auswertung3()
    Dim l As Long
    Dim Letzte As Long
    Letzte = Range("a500").End(xlUp).Row
        For l = Letzte To 1 Step -1
            If Not IsEmpty(Cells(l, 1)) Then
            If Cells(l, 1).Value = 0 Then Rows(l).Delete
            End If
        Next
End Sub

https://www.herber.de/bbs/user/20858.xls
Jemand eine Ahnung, was ich falsch mache?
Gruß, Demian
Bild

Betrifft: AW: Nochmal: Nullen weg
von: Tobias Marx
Geschrieben am: 08.04.2005 10:05:26
Servus!
Ich konnte jetzt keinen Fehler bei mir feststellen, alles lief so durch, wie es sollte, ich kann mir aber nur vorstellen, dass er wegen den Datentypen nen Haenger hat, deswegen hab ich jetzt noch ne Ueberpruefung auf "nummer" gemacht:

Sub Auswertung3()
    Dim l As Long
    Dim Letzte As Long
    Letzte = Range("a500").End(xlUp).Row
        For l = Letzte To 1 Step -1
            If Not IsEmpty(Cells(l, 1)) Then
            If Cells(l, 1).Value = 0 And IsNumeric(Cells(l, 1).Value) Then Rows(l).Delete
            End If
        Next
End Sub

Gruss

Tobias
Bild

Betrifft: AW: Nochmal: Nullen weg
von: Demian
Geschrieben am: 08.04.2005 10:13:16
Wie so häufig treten die Fehler nur bei mir auf. Auch mit dieser Formel funktioniert die Prozedur - aber nur mit der gleichen Fehlermeldung...
Bild

Betrifft: AW: Nochmal: Nullen weg
von: Lars
Geschrieben am: 08.04.2005 10:07:43
Hi,
Option Explicit
Sub Auswertung3()
Dim z As Long, Letzte As Long
Letzte = Range("a500").End(xlUp).Row
For z = Letzte To 1 Step -1
    If IsNumeric(Cells(z, 1)) And Not IsEmpty(Cells(z, 1)) Then
       If Cells(z, 1).Value = 0 Then Rows(z).Delete
    End If
Next
End Sub
Mit freundlichen Grüßen Lars

Bild

Betrifft: AW: Nochmal: Nullen weg
von: Demian
Geschrieben am: 08.04.2005 10:14:32
That works! Cheers.
Bild

Betrifft: AW: Weg mit den Nullen
von: FP
Geschrieben am: 08.04.2005 19:56:34
Hallo Demian,
falls Du viele Zeilen mit einer Null in Spalte A löschen mußt: damit schaffst Du 2000 gelöschte Zeilen in < 1 Sekunde :-)


Sub DelZeroRows()
  Dim bytCRC  As Byte
  Dim strWSN  As String
  Dim appl    As Application
  Dim rngCR   As Range
  Dim aws     As Worksheet
  Dim nws     As Worksheet
  Set appl = Application
  Set rngCR = Cells(1, 1).CurrentRegion
  bytCRC = rngCR.Columns.Count
  If bytCRC < 256 Then
    appl.ScreenUpdating = False
    appl.Calculation = xlCalculationManual
    Set aws = ActiveSheet
    Set nws = ActiveWorkbook.Sheets.Add
    aws.Activate
    strWSN = aws.Name
    Cells(1, bytCRC + 1) = Cells(1, 1)
    Cells(2, bytCRC + 1) = "<>0"
    rngCR.AdvancedFilter Action:=xlFilterCopy, _
      CriteriaRange:=Range(Cells(1, bytCRC + 1), Cells(2, bytCRC + 1)), _
      CopyToRange:=nws.Cells(1, 1), Unique:=False
    appl.DisplayAlerts = False
    aws.Delete
    appl.DisplayAlerts = True
    nws.Name = strWSN
    appl.ScreenUpdating = True
    appl.Calculation = xlCalculationAutomatic
  End If
End Sub

Servus aus dem Salzkammergut
Franz
 Bild

Beiträge aus den Excel-Beispielen zum Thema "Nochmal: Nullen weg"