doppelte marmieren

Forumthread: doppelte marmieren

doppelte marmieren

15.12.2005 16:54:45

huelgueuer

hallo
bezogen auf den beitrag
https://www.herber.de/forum/archiv/460to464/t460872.htm
etwas abgeändert passt die formel genau zu meinem problem.


Sub Doppelete_farbig()
x = 6
For aRow = 7 To Range("E66").End(xlUp).Row
auf_dopplung_zu_überprüfende_nummer = Cells(aRow, 1).Value
For bRow = 7 To Range("E66").End(xlUp).Row 'hier die Aenderung
nummer = Cells(bRow, 1).Value
If aRow <> bRow Then
If auf_dopplung_zu_überprüfende_nummer = nummer Then
Cells(aRow, 1).Interior.ColorIndex = x
Cells(bRow, 1).Interior.ColorIndex = x
End If
End If
Next
x = x + 1
Next
End Sub

das einzige ist, die leeren zellen sollen nicht farbig geändert werden. es sollen nur die zellen mit werten einbezogen werden.
zusätzlich sollen dann noch die spalten F G H I J K genau so durchsucht werden.
vielleicht weiss ja einer was.
vielen dank
holger

2
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: doppelte marmieren

15.12.2005 19:25:51

Erich
AW: Doppelte markieren

15.12.2005 19:35:40

Erich

AW: doppelte marmieren

15.12.2005 19:25:51

Erich

Hallo Holger,
in deinem Code wird nur Spalte A auf doppelte überprüft und eingefärbt. Wenn du die Überprüfung in den Spalten E bis K haben möchtest, sollte das so funzen (ungetestet):


Option Explicit
Sub Doppelete_farbig()
Dim intCol As Integer, intFarbe As Integer
Dim aRow As Long, bRow As Long, lngLast As Long
For intCol = 5 To 11
intFarbe = 6
lngLast = Cells(Rows.Count, intCol).End(xlUp).Row
For aRow = 7 To lngLast - 1
If Cells(aRow, intCol) > "" Then
For bRow = aRow + 1 To lngLast 'hier die Aenderung
If Cells(aRow, intCol) = Cells(bRow, intCol) Then
Cells(aRow, intCol).Interior.ColorIndex = intFarbe
Cells(bRow, intCol).Interior.ColorIndex = intFarbe
End If
Next
intFarbe = intFarbe + 1
End If
Next
Next
End Sub

"Option Explicit" ist immer zu empfehlen!
Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort

AW: Doppelte markieren

15.12.2005 19:35:40

Erich

Hallo Holger,
Zellen, die bereits als Dubletten erkannt und damit farbig sind, müssen nicht noch mal bearbeitet werden. Deshalb hier eine neue Version:


Option Explicit
Sub Doppelte_farbig()
Dim intCol As Integer, intFarbe As Integer
Dim aRow As Long, bRow As Long, lngLast As Long
For intCol = 5 To 11
intFarbe = 6
lngLast = Cells(Rows.Count, intCol).End(xlUp).Row
For aRow = 7 To lngLast - 1
With Cells(aRow, intCol)
If .Value > "" And .Interior.ColorIndex = xlColorIndexNone Then
For bRow = aRow + 1 To lngLast
If .Value = Cells(bRow, intCol) Then
.Interior.ColorIndex = intFarbe
Cells(bRow, intCol).Interior.ColorIndex = intFarbe
End If
Next
intFarbe = intFarbe + 1
End If
End With
Next
Next
End Sub

Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort

Beliebteste Forumthreads (12 Monate)

Forumthread: doppelte marmieren

2 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

2
Beiträge zum Forumthread

Beiträge zu diesem Forumthread