Tabellenblatt in UF

Forumthread: Tabellenblatt in UF

Tabellenblatt in UF

Pia

Hi Ihr alle!
Ich möchte ein Tabellenblatt in einer UF darstellen, ist dies möglich?
Bei einem Diagramm habe ich es hinbekommen - vorher als jpg abspeichern.
Aber bei dem Tabellenblatt?
Danke Euch! Pia

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Benutzer

AW: Tabellenblatt in UF

11.02.2006 19:38:40

chris

Dazue musst du Spreadsheet verwenden.
Bei den Steuerelementen.
Genauer kann ich es dir leider nicht beschreiben.
gruß Christian

AW: Tabellenblatt in UF

11.02.2006 20:01:26

Nepumuk

Hallo Pia,
den Rest musst du dir anpassen:

' **********************************************************************
' Modul: Modul1 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Public Sub prcExportTablecopy()
    Dim objChart As Chart
    Dim objChartObject As ChartObject
    Dim objShape As Shape
    Application.ScreenUpdating = False
    With Tabelle1
        .Select
        .Cells(1, 1).Select
        .Range(.Cells(1, 1), .Cells(10, 5)).Copy
        .Pictures.Paste Link:=True
        Set objShape = .Shapes(.Shapes.Count)
    End With
    Application.CutCopyMode = False
    objShape.CopyPicture Appearance:=2, Format:=-4147
    Set objChart = Charts.Add
    Set objChartObject = objChart.ChartObjects.Add(0, 0, _
        objShape.Width * 0.85, objShape.Height * 0.85)
    With objChartObject.Chart
        .Paste
        .Export Filename:=ThisWorkbook.Path & "\Bild.jpg", _
            FilterName:="JPG", Interactive:=False
    End With
    Application.DisplayAlerts = False
    objChart.Delete
    objShape.Delete
    Application.DisplayAlerts = True
    Set objChart = Nothing
    Set objChartObject = Nothing
    Set objShape = Nothing
    With UserForm1
        .Image1.Picture = LoadPicture(ThisWorkbook.Path & _
            "\Bild.jpg")
        .Show
    End With
End Sub

Gruß
Nepumuk

AW: Tabellenblatt in UF

11.02.2006 23:42:36

Pia

Danke Euch!
Habt mir sehr geholfen!
Auf ein neues Problem! ;-)

AW: Tabellenblatt in UF

12.02.2006 22:40:09

daniel

Hallo,
wenn es nur auf die Daten und nicht auf die Optik ankommt und der darzustellende Bereich nicht allzugroß ist, könnte man auch eine mehrspaltige List-Box verwenden, deren Inhalt über die Eigenschaft Rowsoucre mit dem darzustellenden Tabellenbereich verknüpft ist (am besten über Namen)
dann erfolgt die Aktualisierung der Darstellung automatisch und und nicht über den komplizierten Weg mit Exporieren und wieder reinladen.
Gruß, Daniel Eisert

Beliebteste Forumthreads (12 Monate)

Forumthread: Tabellenblatt in UF

4 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread