Live-Forum - Die aktuellen Beiträge
Anzeige
Archiv - Navigation
760to764
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
760to764
760to764
Aktuelles Verzeichnis
Verzeichnis Index
Verzeichnis Index
Übersicht Verzeichnisse
Inhaltsverzeichnis

Daten zusammenführen?

Daten zusammenführen?
02.05.2006 17:06:51
J. Bode
Hallo Freunde,
ich habe 20 Tabellen oder mehr die alle identisch sind. Die Daten in den einzelnen Tabellen werden von den Mitarbeitern aus gefüllt. Nun habe ich eine Mastertabelle in denen alle Daten automatisch zusammengeührt werden sollen.
Wie bekomme ich das hin ohne die Daten zu kopieren (VBA ?). Dabei ist darauf zuachten das die Daten in der Mastertabelle NICHT überschrieben werden sondern immer unten eingefügt werden.
Ich hoffe meine Erklärung ist einigermaßen verständlich ausgefallen.
Kann leider von diesem rechner kein Beispiel hochladen.
Danke schon mal in voraus,
J. Bode

17
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Daten zusammenführen?
02.05.2006 18:33:27
Erich G.
Hallo J.(?),
wenn du von "Tabellen" sprichst, meinst du dann Blätter innerhalb einer Excelmappe, oder sind das viele Excelmappen, also getrennte Dateien?
Wenn es um "20 oder mehr Blätter" geht:
Sind die Daten ALLER Blätter der Mappe (außer der "Mastertabelle" natürlich) in die Mastertabelle zu kopieren? Oder gibt es ein Muster für die Namen der zu verarbeitenden Blätter?
Wenn es um "20 oder mehr Excelmappen" geht:
Stehen alle diese Mappen im selben Verzeichnis?
Gibt es in diesem Verzeichnis auch Mappen, die nicht interessieren? Oder gibt es ein Muster für die Namen der zu verarbeitenden Mappen?
Weitere Frage:
Üblicherweise stehen in der 1. Zeile Spaltenüberschriften. Sollen alle Daten ab der 2. Zeile übertragen werden?
Und noch eine Frage:
Ist sicher, dass die Zellformate pro Spalte bei allen Kollegen gleich sind? Man kann die Zellen (einschließlich der Formate) oder nur die Zellinhalte kopieren.
Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort
Anzeige
AW: Daten zusammenführen?
03.05.2006 06:54:20
J. Bode
Hallo Erich,
habe mich wie immer falsch ausgedrückt.
Ich meine natürlich einzelne von einander getrennte Arbeitsmappen die per Email bei mir eintreffen. Die Zellformate sind in allen Arbeitsmappen identisch, es sei denn der Benutzer ändert das Format.
Der Datenbereich beginnt immer in der 2.Zeile und ist nach unten offen. Die Daten aus der nächsten Arbeitsmappe müßen logischerweis in die nächste freie Zeile der Masterarbeitsmappe, usw.
Grüße von J. aus Dortmund
AW: Daten zusammenführen?
03.05.2006 08:23:19
Erich G.
Hallo J.(?),
einen Teil meiner Fragen muss ich dann wohl noch einmal stellen:
Stehen alle diese Mappen im selben Verzeichnis?
Gibt es in diesem Verzeichnis auch Mappen, die nicht interessieren (z. B. Mappen, die bereits verarbeitet wurden)? Oder gibt es ein Muster für die Namen der zu verarbeitenden Mappen?
Sollen die Zellen (einschließlich der Formate) oder nur die Zellinhalte kopiert werden?
("... es sei denn der Benutzer ändert das Format ...)
Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort
Anzeige
AW: Daten zusammenführen?
03.05.2006 10:01:52
J. Bode
Hallo Erich,
Stehen alle diese Mappen im selben Verzeichnis?
Antwort:
NEIN, werden vom jeweiligen Mitarbeiter ausgefüllt, per Email zugesandt, dann in einem Ordner zusammen geführt.
Gibt es in diesem Verzeichnis auch Mappen, die nicht interessieren (z. B. Mappen, die bereits verarbeitet wurden)? Oder gibt es ein Muster für die Namen der zu verarbeitenden Mappen?
Antwort:
Eingepflegte Arbeitsmappen verbleiben in diesem Ordner, keine Mustermappen oder leere Mappen.
Sollen die Zellen (einschließlich der Formate) oder nur die Zellinhalte kopiert werden?
("... es sei denn der Benutzer ändert das Format ...)
Antwort:
Nur die Zellinhalte einfügen.
Grüße von J. a. D.
Anzeige
AW: Daten zusammenführen?
03.05.2006 23:43:54
Erich G.
Hallo J.(?),
wie schon oft ist die Kommunikation über eine Problem komplizierter als das Problem selbst.
Deiner Antwort ("... in einem Ordner zusammen geführt") entnehme ich, dass die Mappen alle im selben Verzeichnis (Ordner) stehen.
Zwischen bereits erledigten und noch zu verarbeitenden Mappen kann nicht so leicht unterschieden werden - sie stehen im selben Ordner, und ein Namensmuster gibt es nicht.
Bei mehrfachem Aufruf des unten stehenden Programms werden alle Daten mehrfach verarbeitet. Damit das nachher erkennbar ist, schreibt das Programm auf Wunsch hinter jede Zeile den Namen der Quellmappe und die Zeit, zu der die Kopie erfolgte.
Ich habe ein bestehendes kleines Programm ( ursprünglich auf Basis von https://www.herber.de/mailing/237804h.htm )etwas angepasst - damit kannst du es versuchen. Die drei Angaben in den Const-Anweisungen müsstest du noch anpassen:
Option Explicit
Sub Zusammenfassen()
Dim wbkQ As Workbook, arr As Variant, iNr As Integer
Dim datUhr As Date, iRowQ As Long, iRowZ As Long, iCol As Integer
Const strVerz = "c:\daten"       ' Ordner/Verzeichnis mit den Quellmappen
Const boolInf = True             ' False, wenn Dateiname+Datum nicht in die Liste sollen
Const vBlatt = 1 ' "Tabelle1"    ' Blattnummer oder Blattname in den Quellmappen
Application.ScreenUpdating = False
Application.EnableEvents = False
On Error GoTo ERRORHANDLER
arr = FileArray(strVerz, "*.xls")
For iNr = 1 To UBound(arr)
If arr(iNr) <> ThisWorkbook.Name Then
datUhr = Now
Set wbkQ = Workbooks.Open(strVerz & "\" & arr(iNr), 0)
With wbkQ.Worksheets(vBlatt)
iRowQ = .Cells(Rows.Count, 1).End(xlUp).Row
ThisWorkbook.Activate
If iNr = 1 Then
If IsEmpty(Cells(1, 1)) Then
.Rows(1).Copy
Cells(1, 1).PasteSpecial Paste:=xlPasteValues, Operation:=xlNone
Cells(1, 1).Select
ActiveWindow.FreezePanes = True
End If
If boolInf Then
iCol = Cells(1, Columns.Count).End(xlToLeft).Column
If Cells(1, iCol - 1) & Cells(1, iCol) = "Quelldateiam" Then
iCol = iCol - 1
Else
iCol = iCol + 1
Range(Cells(1, iCol), Cells(1, iCol + 1)) = Split("Quelldatei am")
End If
End If
End If
If iRowQ > 1 Then
iRowZ = Cells(Rows.Count, 1).End(xlUp).Row + 1
Range(.Rows(2), .Rows(iRowQ)).Copy
Cells(iRowZ, 1).PasteSpecial Paste:=xlPasteValues, Operation:=xlNone
Application.CutCopyMode = False
If boolInf Then
Range(Cells(iRowZ, iCol), Cells(iRowZ + iRowQ - 2, iCol)) = wbkQ.Name
Range(Cells(iRowZ, iCol + 1), Cells(iRowZ + iRowQ - 2, iCol + 1)) = datUhr
End If
End If
End With
wbkQ.Close savechanges:=False
End If
Next iNr
If UBound(arr) > -1 Then
Rows(1).HorizontalAlignment = xlHAlignCenter
If boolInf Then Columns(iCol + 1).NumberFormat = "dd.mm.yyyy hh:mm:ss"
ActiveSheet.UsedRange.Columns.AutoFit
iRowZ = iRowZ + iRowQ - 1
Application.Goto Cells(IIf(iRowZ > 25, iRowZ - 25, 1), 1), True
Cells(iRowZ, 1).Select
End If
ERRORHANDLER:
Application.EnableEvents = True
Application.ScreenUpdating = True
End Sub
Function FileArray(ByVal strPath As String, sPattern As String)
Dim arr(), iNr As Integer, tmp As String
With Application.FileSearch
.NewSearch
.LookIn = strPath
.SearchSubFolders = False
.Filename = sPattern
.MatchTextExactly = True
.FileType = msoFileTypeAllFiles
If .Execute() > 0 Then
ReDim arr(1 To .FoundFiles.Count)
For iNr = 1 To .FoundFiles.Count
tmp = .FoundFiles(iNr)
arr(iNr) = Right(tmp, Len(tmp) - InStrRev(tmp, "\"))
Next iNr
Else
ReDim arr(-1 To -1)
MsgBox "Es wurden keine Dateien gefunden.", vbInformation
End If
End With
FileArray = arr
End Function
Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort
Anzeige
AW: Daten zusammenführen?
04.05.2006 07:49:10
J. Bode
Hallo Erich,
habe Dein Makro 1 : 1 übernommen. Die Befehle "True" in "False", '"Tabelle1" in "Eingabe" geändert. Im Laufwerk "C" einen Ordner "Daten" angelegt.
Beim entfernen des " ' " bekomme ich die Fehlermeldung:
Fehler beim Kompilieren
Erwarte: Anweisungsende
Const strVerz = "c:\daten"
Const boolInf = False
Const vBlatt = 1 "Eingabe"
Von VBA habe ich sogut wie keine Ahnung;-)
Danke für Deine Bemühungen.
Grüße v. J.
AW: Daten zusammenführen?
04.05.2006 08:02:28
Erich G.
Hallo J.,
in der Zeile für das Blatt musst du noch die 1 rausnehmen, dann sollte sie so aussehen:
Const vBlatt = "Eingabe" ' Blattnummer oder Blattname in den Quellmappen
Grüße von Erich aus Kamp-Lintfort
Anzeige
AW: Daten zusammenführen?
04.05.2006 08:30:49
J. Bode
Hallo Erich,
so weit, so gut.
Wenn ich aber zwei Arbeitsmappen in dem selben Ordner habe werden immer die Daten aus ein und der selben Quellmappe kopiert, nehme ich nun die erste Quellmappe heraus dann werden die Daten aus der zweiten Quellmappe übernommen.
Die Quellmappen werden auch nicht wieder geschlossen.
Ich hätte auch gerne das nur der Zellinhalt kopiert werden ohne Formatierung.
Die MSG - Box gibt keine Meldung aus.
Danke
J.
AW: Daten zusammenführen?
04.05.2006 08:44:34
J. Bode
Hallo Erich,
so weit, so gut.
Wenn ich aber zwei Arbeitsmappen in dem selben Ordner habe werden immer die Daten aus ein und der selben Quellmappe kopiert, nehme ich nun die erste Quellmappe heraus dann werden die Daten aus der zweiten Quellmappe übernommen.
Die Quellmappen werden auch nicht wieder geschlossen.
"Ich hätte auch gerne das nur der Zellinhalt kopiert werden ohne Formatierung."
Erledigt, mein Fehler!!!
Die MSG - Box gibt keine Meldung aus.
Danke
J.
Anzeige
AW: Daten zusammenführen?
04.05.2006 09:07:06
Erich G.
Hallo J.,
wenn die Quelldatei nicht geschlossen wird, muss bei der Verarbeitung ein Fehler aufgetreten sein. Bitte schreib mal an den Anfang der Zeile
On Error GoTo ERRORHANDLER
ein einzelnes Hochkomma:
'On Error GoTo ERRORHANDLER
Die Zeile wird dadurch zu einem Kommentar, also nicht mehr ausgeführt.
Wenn du dann das Makro startest, wird VBA mit einer Fehlermeldung stoppen und die fehlerhafte Makrozeile markieren.
Bitte schreib hier den Wortlaut der Fehlermeldung und in welcher Zeile das Makro abbricht.
Damit du sehen kannst, was wann der Sammeltabelle hinzugefügt wurde, empfehle ich dir, jetzt für den Test
Const boolInf = True
zu setzen.
Bei mir läuft das Makro einwandfrei.
Grüße von Erich aus Kamp-Lintfort
Anzeige
AW: Daten zusammenführen?
04.05.2006 09:36:59
J. Bode
Hallo Erich,
jetzt habe ich das Makro in meine Originaldatei eingeplegt und das klappt auch soweit gut.
Nur ein kleines Problem ist dazu kekommen:
In meiner Datei sind einige Zellen mit Gültigkeiten belegt, sodas diese als Zellen (auch wenn sie leer sind) mit kopiert werden, obwohl dort kein Eintrag ist.
Kann man das Kopieren in der Quelldatei auch Spalten begrenzen?
Das heißt Spalte " A:H ".
Gruß
J.
AW: Daten zusammenführen?
04.05.2006 10:29:19
Erich G.
Hallo J.,
mit der Spaltenauswahl geht das so:
Option Explicit
Sub ZusammenfassenSp()
Dim wbkQ As Workbook, arr As Variant, iNr As Integer
Dim datUhr As Date, iRowQ As Long, iRowZ As Long, iCol As Integer
Const strVerz = "c:\daten"       ' Ordner/Verzeichnis mit den Quellmappen
Const boolInf = True             ' False, wenn Dateiname+Datum nicht in die Liste sollen
Const vBlatt = "Eingabe"         ' Blattnummer oder Blattname in den Quellmappen
Const iColV = 1                  ' 1. zu kopierende Spalte
Const iColB = 8                  ' letzte zu kopierende Spalte
Application.ScreenUpdating = False
Application.EnableEvents = False
'   On Error GoTo ERRORHANDLER
arr = FileArray(strVerz, "*.xls")
For iNr = 1 To UBound(arr)
If arr(iNr) <> ThisWorkbook.Name Then
datUhr = Now
Set wbkQ = Workbooks.Open(strVerz & "\" & arr(iNr), 0)
With wbkQ.Worksheets(vBlatt)
iRowQ = .Cells(Rows.Count, iColV).End(xlUp).Row
ThisWorkbook.Activate
If iNr = 1 Then
If IsEmpty(Cells(1, 1)) Then
Range(.Cells(1, iColV), .Cells(1, iColB)).Copy
Cells(1, 1).PasteSpecial Paste:=xlPasteValues, Operation:=xlNone
Cells(1, 1).Select
ActiveWindow.FreezePanes = True
End If
If boolInf Then
iCol = iColV + iColB
Range(Cells(1, iCol), Cells(1, iCol + 1)) = Split("Quelldatei am")
End If
End If
If iRowQ > 1 Then
iRowZ = Cells(Rows.Count, 1).End(xlUp).Row + 1
Range(.Cells(2, iColV), .Cells(iRowQ, iColB)).Copy
Cells(iRowZ, 1).PasteSpecial Paste:=xlPasteValues, Operation:=xlNone
Application.CutCopyMode = False
If boolInf Then
Range(Cells(iRowZ, iCol), Cells(iRowZ + iRowQ - 2, iCol)) = wbkQ.Name
Range(Cells(iRowZ, iCol + 1), Cells(iRowZ + iRowQ - 2, iCol + 1)) = datUhr
End If
End If
End With
wbkQ.Close savechanges:=False
End If
Next iNr
If UBound(arr) > -1 Then
Rows(1).HorizontalAlignment = xlHAlignCenter
If boolInf Then Columns(iCol + 1).NumberFormat = "dd.mm.yyyy hh:mm:ss"
ActiveSheet.UsedRange.Columns.AutoFit
iRowZ = iRowZ + iRowQ - 1
Application.Goto Cells(IIf(iRowZ > 25, iRowZ - 25, 1), 1), True
Cells(iRowZ, 1).Select
End If
ERRORHANDLER:
Application.EnableEvents = True
Application.ScreenUpdating = True
End Sub
Das mit den Gültigkeiten kann ich nicht nachvollziehen. Kopiert wird aus den Zeilen 2 bis zur letzten Zeile, die in der ersten zu kopierenden Spalte einen Wert enthält - unabhängig von Gültigkeitsprüfungen.
Vielleicht kannst du mal eine kleine Beispiel-Quelltabelle hochladen, bei der es nicht richtig funzt?
Grüße von Erich aus Kamp-Lintfort
Anzeige
AW: Daten zusammenführen?
04.05.2006 12:26:59
J. Bode
Hallo Erich,
es ist nicht die Gültigkeit sondern in den Spalten A u. B sind Formel hinterlegt die das Problem machen. Habe die Formeln gelöscht und siehe da, es klappt.
Habe Dein Makro reinkopiert, nun bekomme ich die nächste Fehlermeldung und zwar bei dem Befehl:
arr = FileArray(strVerz, "*.xls").
Eine Probedatei kann ich leider von diesem nicht Rechner hochladen, da dies ein Firmenrechner ist. Wenn das alles nichts wird muß ich es morgen von zu Hause machen.
An Deine e-mail - Adresse könnte ich die Datei senden!!!
Gruß
J.
AW: Daten zusammenführen?
04.05.2006 13:41:00
Erich G.
Hallo J.,
vermutlich fehlt bei dir jetzt die Funktion FileArray(...). Da sie sich nicht geändert hat, habe ich sie nicht noch mal ins Forum gestellt.
Wenn du möchtest: Meine Mailadresse findest du (wegen Spam etwas verklausuliert) unter
Forums-Seiten - Profile - Profilliste
Grüße von Erich aus Kamp-Lintfort
Anzeige
AW: Daten zusammenführen?
04.05.2006 15:20:46
J. Bode
Hallo Erich,
ich versuch mal eine Testdatei hoch zuladen.
https://www.herber.de/bbs/user/33320.xls

Die Datei https://www.herber.de/bbs/user/33321.xls wurde aus Datenschutzgründen gelöscht

Die Datei https://www.herber.de/bbs/user/33322.xls wurde aus Datenschutzgründen gelöscht

Die Datei https://www.herber.de/bbs/user/33323.xls wurde aus Datenschutzgründen gelöscht

Gruß
J.
AW: Daten zusammenführen?
04.05.2006 18:38:14
Erich G.
Hallo Jochen(!),
deine Files haben mich doch etwas überrascht:
Das erste enthält überhaupt keine Daten, die Überschriften der Spalten A bis D fehlen.
Im zweiten File steht in A2 schon mal "Abteilung".
Aus welchem Grund auch immer ist Zeile 1 leer, in Zeile 2 kommen Überschriften, der Datenbereich beginnt in Zeile 3.
Ich habe das Makro jetzt so geändert, dass man die Überschriftzeile vorgeben kann. Außerdem wird nur bis zur letzten Zeile kopiert, die in der ersten zu kopierenden Spalte einen nichtleeren Wert enthält:
Option Explicit
Sub ZusammenfassenSp()
Dim wbkQ As Workbook, arr As Variant, iNrQ As Integer, iAnz As Integer
Dim datUhr As Date, iRowQ As Long, iRowZ As Long, iCol As Integer
Const strVerz = "c:\daten"       ' Ordner/Verzeichnis mit den Quellmappen
Const boolInf = False 'True      ' False, wenn Dateiname+Datum nicht in die Liste sollen
Const vBlatt = "Eingabe"         ' Blattnummer oder Blattname in den Quellmappen
Const iColV = 1                  ' 1. zu kopierende Spalte
Const iColB = 8                  ' letzte zu kopierende Spalte
Const iRowU = 2                  ' Zeile mit der Überschrift
Application.ScreenUpdating = False
Application.EnableEvents = False
'   On Error GoTo ERRORHANDLER
arr = FileArray(strVerz, "*.xls")
For iNrQ = 1 To UBound(arr)
If arr(iNrQ) <> ThisWorkbook.Name Then
datUhr = Now
Application.StatusBar = "Öffne " & arr(iNrQ)
Set wbkQ = Workbooks.Open(strVerz & "\" & arr(iNrQ), 0, True)
With wbkQ.Worksheets(vBlatt)
iRowQ = Row_LastNotEmpty(.Columns(iColV))
If iRowQ > 1 Then
iAnz = iAnz + 1
ThisWorkbook.Activate
If iAnz = 1 Then
If IsEmpty(Cells(1, 1)) Then
Range(.Cells(iRowU, iColV), .Cells(iRowU, iColB)).Copy
Cells(1, 1).PasteSpecial Paste:=xlPasteValues, Operation:=xlNone
Cells(1, 1).Select
ActiveWindow.FreezePanes = True
End If
If boolInf Then
iCol = iColV + iColB
Range(Cells(1, iCol), Cells(1, iCol + 1)) = Split("Quelldatei am")
End If
End If
If iRowQ > iRowU Then
iRowZ = Cells(Rows.Count, 1).End(xlUp).Row + 1
Range(.Cells(iRowU + 1, iColV), .Cells(iRowQ, iColB)).Copy
Cells(iRowZ, 1).PasteSpecial Paste:=xlPasteValues, Operation:=xlNone
Application.CutCopyMode = False
If boolInf Then
Range(Cells(iRowZ, iCol), Cells(iRowZ + iRowQ - iRowU - 1, iCol)) = wbkQ.Name
Range(Cells(iRowZ, iCol + 1), Cells(iRowZ + iRowQ - iRowU - 1, iCol + 1)) = datUhr
End If
End If
End If
End With
wbkQ.Close savechanges:=False
End If
Next iNrQ
If UBound(arr) > -1 Then
ActiveWindow.FreezePanes = False
Cells(2, 1).Select
ActiveWindow.FreezePanes = True
Rows(1).HorizontalAlignment = xlHAlignCenter
If boolInf Then Columns(iCol + 1).NumberFormat = "dd.mm.yyyy hh:mm:ss"
ActiveSheet.UsedRange.Columns.AutoFit
iRowZ = iRowZ + iRowQ - iRowU
Application.Goto Cells(IIf(iRowZ > 25, iRowZ - 25, 1), 1), True
Cells(iRowZ, 1).Select
End If
ERRORHANDLER:
Application.StatusBar = False
Application.EnableEvents = True
Application.ScreenUpdating = True
End Sub
Function FileArray(ByVal strPath As String, sPattern As String)
Dim arr(), iNr As Integer, tmp As String
With Application.FileSearch
.NewSearch
.LookIn = strPath
.SearchSubFolders = False
.Filename = sPattern
.MatchTextExactly = True
.FileType = msoFileTypeAllFiles
If .Execute() > 0 Then
ReDim arr(1 To .FoundFiles.Count)
For iNr = 1 To .FoundFiles.Count
tmp = .FoundFiles(iNr)
arr(iNr) = Right(tmp, Len(tmp) - InStrRev(tmp, "\"))
Next iNr
Else
ReDim arr(-1 To -1)
MsgBox "Es wurden keine Dateien gefunden.", vbInformation
End If
End With
FileArray = arr
End Function
Public Function Row_LastNotEmpty&(ByVal wo As Range)
Row_LastNotEmpty = Row_LastFound(wo, "*")
End Function
Public Function Row_LastFound&(ByVal wo As Range, ByVal was$)
On Error Resume Next
Row_LastFound = wo.Find(was, wo.Cells(1), xlValues, xlWhole, , xlPrevious).Row
End Function

Ich hoffe, das funzt jetzt auch bei dir. Denn auch ich habe nicht unendlich viel Zeit, für deine Firma "ehrenamtlich und damit kostengünstig" Programme zu schreiben - und bis nach dem Wochenende werde ich weg sein.
Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort
AW: Daten zusammenführen?
05.05.2006 07:41:01
J. Bode
Hallo Erich,
das waren nicht die Originalen Dateien die sehen noch etwas anders aus.
Jetzt klappt es sehr gut nur mir wird immer die Fixierung verschoben ( um eine Zeile nach oben).
Nun wünsche ich Dir ein schönes Wochenende.
Anmerkung: Ich wollte Dich nicht NERVEN;-)
Danke für Deine Bemühungen.
Gruß
J. aus Dortmund

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige