Live-Forum - Die aktuellen Beiträge
Anzeige
Archiv - Navigation
820to824
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
820to824
820to824
Aktuelles Verzeichnis
Verzeichnis Index
Verzeichnis Index
Übersicht Verzeichnisse
Inhaltsverzeichnis

Export_Speichern ins andere Ecel_Arbeitsblatt

Export_Speichern ins andere Ecel_Arbeitsblatt
24.11.2006 18:10:59
WilliamM
https://www.herber.de/bbs/user/38480.xls
Hallo Experten
bräuchte (einfaches?) Makro mit dem ich Daten aus EINGABE Arbeitblatt ins
SICHERUNGS Arbeitblatt Exportiere/Speichere.Die Daten aus Arbeitblatt
sollen danach gelöscht werden.
Sicherungs Arbeitblatt soll fortlaufend sein....
Es sollen nur die Zeilen A2:AN4 exportiert werden
Danke in voraus

7
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Export_Speichern ins andere Ecel_Arbeitsblatt
25.11.2006 13:23:21
fcs
Hallo William,
Zusatzfragen:
1. meinst du mit EINGABE Arbeitsblatt bzw. SICHERUNGS Arbeitsblatt jeweil eine eigene Arbeitsmappe(Exceldatei) oder 2 Tabellenblätter innerhalb der gleichen Arbeitsmappe?
2. Sicherungs Arbeitsblatt soll fortlaufend sein?
Sollen die 3 Zeilen aus dem Eingabeblatt immer jeweils in dem Sicherungs-Tabellenblatt unter den bereits vorhandenen Daten eingefügt werden?
3. Gibt in der Eingabemaske in den zu sichernden/exportierenden Zellen auch Zellen mit Formeln?
Wenn ja, sollen die Formeln oder die Werte in die Sicherungsdtei übertragen werden?
4. Sollen die Zellen-Formate im Eingabebereich auch mit in die Sicherungstabelle kopiert werden?
Gruss
Franz
Anzeige
AW: Export_Speichern ins andere Ecel_Arbeitsblatt
25.11.2006 17:15:29
fcs
Hallo William,
hier 2 Makro-Varianten für die Speicherung der Eingabedaten in einer Datei.
Die 1. Variante überträgt nur die Werte
Die 2. Variante kopiert jeewils die Zellen des Eingabebereichs in die Sicherunsdatei.
Ich bin bei meinem Makro davon ausgegenagen, dass die Spalte "C" (Masch) bei allen Eingaben ausgefüllt wird.
Die Spalte C wird benutzt, um die nächste frei Zeile in der Export-Tabelle zu bestimmen. ggf. hier eine andere Spalte festlegen.
Gruss
Franz

Sub Eingabe_Exportieren1()
'Überträgt die Werte im Eingabebereich in die Sicherungsdatei
'Alle Formate müssen in der Sicherungsdatei festgelegt werden
Dim wbThis As Workbook, wbExport As Workbook, rngEingabe As Range
Dim wksEingabe As Worksheet, wksExport As Worksheet, ZeileExport As Long
Set wbThis = ThisWorkbook
Set wksEingabe = wbThis.Worksheets("Tabelle1") 'Tabelle mit den Eingabedaten
Set rngEingabe = wksEingabe.Range("A2:AN4") 'Bereich mit den Eingabedaten
Application.ScreenUpdating = False
'Sicherungs-Datei öffnen
Set wbExport = Workbooks.Open("C:\Test\TestExport.xls") 'Datei in die exportiert/gesichert werden soll
Set wksExport = wbExport.Worksheets("Tabelle1") 'Tabelle in die Daten exportiert/gesichert werden sollen
'Daten übertragen
With wksExport
'Nächste freie Zeile bestimmen (Annahme: In Spalte C werden immer Eingaben gemacht)
ZeileExport = .Cells(.Rows.Count, "C").End(xlUp).Row + 1
'Daten übertragen
.Cells(ZeileExport, "A").Range("A1:AN3").Value = rngEingabe.Value
End With
'Sicherungsdatei speichern und schliessen
wbExport.Close savechanges:=True
Application.ScreenUpdating = True
'Inhalte im Eingabebereich löschen
rngEingabe.ClearContents
End Sub
Sub Eingabe_Exportieren2()
'Kopiert die Zellen im Eingabebereich in die Sicherungsdatei
Dim wbThis As Workbook, wbExport As Workbook, rngEingabe As Range
Dim wksEingabe As Worksheet, wksExport As Worksheet, ZeileExport As Long
Set wbThis = ThisWorkbook
Set wksEingabe = wbThis.Worksheets("Tabelle1") 'Tabelle mit den Eingabedaten
Set rngEingabe = wksEingabe.Range("A2:AN4") 'Bereich mit den Eingabedaten
Application.ScreenUpdating = False
'Sicherungs-Datei öffnen
Set wbExport = Workbooks.Open("C:\Test\TestExport.xls") 'Datei in die exportiert/gesichert werden soll
Set wksExport = wbExport.Worksheets("Tabelle1") 'Tabelle in die Daten exportiert/gesichert werden sollen
'Daten übertragen
With wksExport
'Nächste freie Zeile bestimmen (Annahme: In Spalte C werden immer Eingaben gemacht)
ZeileExport = .Cells(.Rows.Count, "C").End(xlUp).Row + 1
'Daten kopieren
rngEingabe.Copy .Cells(ZeileExport, "A")
Application.CutCopyMode = False
End With
'Sicherungsdatei speichern und schliessen
wbExport.Close savechanges:=True
'Inhalte im Eingabebereich löschen
Application.ScreenUpdating = False
rngEingabe.ClearContents
End Sub

Anzeige
AW: Export_Speichern ins andere Ecel_Arbeitsblatt
25.11.2006 19:55:54
WilliamM
Hallo Franz
Zusatzfragen:
1. meinst du mit EINGABE Arbeitsblatt bzw. SICHERUNGS Arbeitsblatt jeweil eine eigene Arbeitsmappe(Exceldatei) oder 2 Tabellenblätter innerhalb der gleichen Arbeitsmappe?
JA...Jeweil eine eigene Arbeitsmappe(Exceldatei)
--------------------------------------------------------------------------------------
2. Sicherungs Arbeitsblatt soll fortlaufend sein?
Sollen die 3 Zeilen aus dem Eingabeblatt immer jeweils in dem Sicherungs-Tabellenblatt unter den bereits vorhandenen Daten eingefügt werden?
JA..........
----------------------------------------------------------------------------------------
3. Gibt in der Eingabemaske in den zu sichernden/exportierenden Zellen auch Zellen mit Formeln?
Wenn ja, sollen die Formeln oder die Werte in die Sicherungsdtei übertragen werden?
NEIN ....es gibt keine Formeln die übertragen werden sollen
---------------------------------------------------------------------------------------
4. Sollen die Zellen-Formate im Eingabebereich auch mit in die Sicherungstabelle kopiert werden?
JA...............
Grüß und nochmals daknke das du dich damit beschäftigst
Wi.
Anzeige
AW: Export_Speichern ins andere Ecel_Arbeitsblatt
26.11.2006 00:00:43
fcs
Hallo William,
dann kannst die 2. Variante aus meienr vorherigen Antwort benutzen.
Kopiere den Code im VBA-Editor in ein allgemeines Modul.
Anschliessend muss du das Makro dann der Schaltfläche zuweisen.
Gruss
Franz
AW: Export_Speichern ins andere Ecel_Arbeitsblatt
26.11.2006 13:56:44
WilliamM
Hallo Franz
Erstmal Danke es klappt alles wunderbar...trotzdem habe ich noch eine bitte/frage wegen der Vereinfachung in der Eingabemaske
Spalte A und B sollen nur Werte exportiert werden (Formeln sollen bleiben)
In spalte C verändern sich die eingaben nicht, also nur Exportieren nicht löschen
Grüß
WM
AW: Export_Speichern ins andere Ecel_Arbeitsblatt
26.11.2006 19:09:19
fcs
Hallo William,
ich hab die Prozedur geringfügig angepasst.
Formate und Werte das Eingabebereichs werden jetzt in der Sicherungsdatei eingefügt.
Im Eingabebereich werden nur noch im Bereich D2:AN4 die Inhalte gelöscht.
Gruss
Franz

Sub Eingabe_Exportieren2()
'Kopiert die Zellen im Eingabebereich in die Sicherungsdatei
Dim wbThis As Workbook, wbExport As Workbook, rngEingabe As Range
Dim wksEingabe As Worksheet, wksExport As Worksheet, ZeileExport As Long
Set wbThis = ThisWorkbook
Set wksEingabe = wbThis.Worksheets("Tabelle1") 'Tabelle mit den Eingabedaten
Set rngEingabe = wksEingabe.Range("A2:AN4") 'Bereich mit den Eingabedaten
Application.ScreenUpdating = False
'Sicherungs-Datei öffnen
Set wbExport = Workbooks.Open("C:\Test\TestExport.xls") 'Datei in die exportiert/gesichert werden soll
Set wksExport = wbExport.Worksheets("Tabelle1") 'Tabelle in die Daten exportiert/gesichert werden sollen
'Daten übertragen
With wksExport
'Nächste freie Zeile bestimmen (Annahme: In Spalte C werden immer Eingaben gemacht)
ZeileExport = .Cells(.Rows.Count, "C").End(xlUp).Row + 1
'Daten kopieren
rngEingabe.Copy
.Cells(ZeileExport, "A").PasteSpecial Paste:=xlFormats 'Formate kopieren
.Cells(ZeileExport, "A").PasteSpecial Paste:=xlValues 'Werte kopieren
Application.CutCopyMode = False
End With
'Sicherungsdatei speichern und schliessen
wbExport.Close savechanges:=True
'Inhalte im Eingabebereich löschen
Application.ScreenUpdating = False
wksEingabe.Range("D2:AN4").ClearContents
End Sub

Anzeige
AW: Export_Speichern ins andere Ecel_Arbeitsblatt
26.11.2006 19:57:05
WilliamM
Bin glücklich ...
Danke Franz
Grüß
WM

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige