Live-Forum - Die aktuellen Beiträge
Anzeige
Archiv - Navigation
832to836
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
832to836
832to836
Aktuelles Verzeichnis
Verzeichnis Index
Verzeichnis Index
Übersicht Verzeichnisse
Inhaltsverzeichnis

Beispiel Verwendung WINAPI...

Beispiel Verwendung WINAPI...
10.01.2007 12:04:53
windalf
Wie bekommt man es hin die WINAPI aus VBA zu verwenden...
Wenn ich einfach nur Funktionen verwenden will bekomme ich das bei sowas wie Sleep noch hin aber was muss man machen, wenn die Parameter komplexe datentypen sind (structs)...
Kann mir jemand z.B. für dieses C-Programm (ja das ist nur ein Beispiel in einem echten Programm würde ich TerminateProcess nicht verwenden) den Code in VBA liefern bzw. ein wenig Unterstüzung geben wie ich die C-Datentypen in VBA verwenden kann?
#include
#include
typedef BOOL(__stdcall *THFUNC)(HANDLE,LPPROCESSENTRY32);
void stop(){
DWORD dw;
HANDLE hSysSnapshot = NULL;
HANDLE h_pro;
PROCESSENTRY32 proc;
THFUNC pProcess32First=(THFUNC)GetProcAddress(GetModuleHandle("kernel32.dll"),"Process32First");
THFUNC pProcess32Next=(THFUNC)GetProcAddress(GetModuleHandle("kernel32.dll"),"Process32Next");
if(pProcess32First&&pProcess32Next)
{
proc.dwSize = sizeof(proc);
hSysSnapshot = CreateToolhelp32Snapshot ( TH32CS_SNAPPROCESS, 0 );
pProcess32First(hSysSnapshot,&proc);
proc.dwSize = sizeof(proc);
do{
if(!strcmp(proc.szExeFile,"EXCEL.EXE")){//oder halt th32ProcessID verwenden
h_pro=OpenProcess(PROCESS_ALL_ACCESS, TRUE, proc.th32ProcessID);
GetExitCodeProcess(h_pro,&dw);
TerminateProcess(h_pro,dw);
}
}while(pProcess32Next(hSysSnapshot,&proc));
}
}
//---------------------------------------------------------------------------------
int main()
{
stop();
return 0;
}
Danke Gruß Windi

5
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Beispiel Verwendung WINAPI...
10.01.2007 14:50:36
Herbert
Hi,
macht keinen Sinn ins Blaue hinein, welche API willst du konkret verwenden
und wozu?
mfg Herbert
...oder versuch's im VB-Forum von Spotlight! orT
10.01.2007 15:03:20
Spotlight!
Gruß Luc :-?
AW: Beispiel Verwendung WINAPI...
10.01.2007 15:54:53
windalf
Konkret verwenden will ich die WINAPI. Hatte ich doch geschrieben
Wenn ich sowas wie Sleep verwenden will oder ne Bildschirmauflösung herrausfinden will, kann ich mittels Declare ja diese WINAPI-Funktionen in VBA bekannt machen. Wie man aber zum Beispiel das den obigen Quellcode in VBA umsetzen könnte das ist mir dann aktuell noch zu hoch...
AW: Beispiel Verwendung WINAPI...
10.01.2007 16:04:45
Nepumuk
Hi,
wortwörtlich kannst du das Programm nicht übersetzen, aber sinngemäß.
' **********************************************************************
' Modul: Modul3 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Private Declare Function CreateToolhelp32Snapshot Lib "kernel32.dll" ( _
    ByVal dwFlags As Long, _
    ByVal th32ProcessID As Long) As Long
Private Declare Function Process32First Lib "kernel32.dll" ( _
    ByVal hSnapshot As Long, _
    ByRef lppe As PROCESSENTRY32) As Long
Private Declare Function Process32Next Lib "kernel32.dll" ( _
    ByVal hSnapshot As Long, _
    ByRef lppe As PROCESSENTRY32) As Long
Private Declare Function CloseHandle Lib "kernel32.dll" ( _
    ByVal hObject As Long) As Long
Private Declare Function TerminateProcess Lib "kernel32.dll" ( _
    ByVal hProcess As Long, _
    ByVal uExitCode As Long) As Long
Private Declare Function OpenProcess Lib "kernel32.dll" ( _
    ByVal dwDesiredAccess As Long, _
    ByVal bInheritHandle As Long, _
    ByVal dwProcessId As Long) As Long

Private Const TH32CS_SNAPPROCESS = &H2
Private Const MAX_PATH = 260
Public Const PROCESS_VM_READ = &H10

Private Type PROCESSENTRY32
    dwSize As Long
    cntUsage As Long
    th32ProcessID As Long
    th32DefaultHeapID As Long
    th32ModuleID As Long
    cntThreads As Long
    th32ParentProcessID As Long
    pcPriClassBase As Long
    dwFlags As Long
    szExeFile As String * MAX_PATH
End Type

Public Sub Alle_Prozesse()
    Dim Snap As Long, Process As PROCESSENTRY32, Result As Long
    Snap = CreateToolhelp32Snapshot(TH32CS_SNAPPROCESS, 0)
    If Snap <> -1 Then
        Process.dwSize = Len(Process)
        Result = Process32First(Snap, Process)
        Do Until Result = 0
            If InStr(1, LCase$(Process.szExeFile), "excel.exe") Then
                Result = OpenProcess(17, 0, Process.th32ProcessID)
                TerminateProcess Result, 0
                Exit Do
            End If
            Result = Process32Next(Snap, Process)
        Loop
    End If
    CloseHandle Snap
End Sub

Gruß
Nepumuk
Anzeige
AW: Beispiel Verwendung WINAPI...
11.01.2007 16:55:39
windalf
@Nepumuk
Hallo Nepumuk. Vielen Vielen Dank. Das war ja deutlich mehr als ich gefragt habe.
Besten Dank für deine Mühen. Funktioniert alles wunderbar und mir ist jetzt so einiges klarer geworden....
Gruß Windi

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige