AW: Danke Franz aber
27.01.2007 21:42:44
fcs
Hallo Walter,
die Selbstzerstörung einer Excel-Datei in VBA zu realiseren ist etwas tricky und läßt sich ohne eine zweite Steuerungsdatei nicht realiseren.
Als Steuerdatei kann man entweder die Persönliche Arbeitsmappe (macht nur Sinn bei einer Einzelplatzanwendung) verwenden oder eine separate Excel-Datei.
Diese Steuerdatei muss von der sich selbst-zerstörenden Datei per Makro geöffnet werden und das Makro in der Steuerdatei zum Schliessen und Löschen der Datei gestartet werden.
Der entsprechende Code in der Selbstmörder-Datei sieht dann etwa so aus:
Sub Test()
Dim aktWb As Workbook
'Aufruf der Selbstzerstörung
Set aktWb = ActiveWorkbook
Workbooks.Open "C:\Test\DateiKiller.XLS"
aktWb.Activate
Application.Run "DateiKiller.XLS!CloseAndKillme"
End Sub
In der Steuerdatei sind zwei Makros erforderlich.
Im ersten Makro wird per OnTime-Methode das 2. Makro zum Löschen der Datei aktiviert und die zu löschende Datei geschlossen.
Das 2. Makro wird dann zeitverzögert ausgeführt.
Diese Vorgehensweise ist notwendig, da mit dem Schließen der zu löschenden Datei auch alle von der Datei gestarteten Prozeduren beendet werden. Es muss also sichergestellt werden, dass das Löschen der Datei von einer unabhängigen Prozedur ausgeführt wird.
Der Code in der Steuerdatei schaut etwa so aus, wobei ich auch eine Sicherheitsabfrage eingebaut hab. Die Steuerdatei schließt sich nach dem Löschvorgang automatisch wieder.
Sub CloseAndKillme()
'Schließt und löscht die aktive Exceldatei
If ActiveWorkbook.Name = ThisWorkbook.Name Then
MsgBox "Dieses Makro darf nur von einer anderen aktiven Datei aus gestartet werden!"
Else
'Dateiname in Zelle der Tabelle der Arbeitsmappe speichern
ThisWorkbook.Worksheets(1).Range("C8").Value = ActiveWorkbook.FullName
If MsgBox("Aktive Excel-Datei " & vbLf & vbLf & ActiveWorkbook.FullName & vbLf & vbLf _
& "wirklich löschen?" & vbLf & vbLf & "Löschung erfolgt ca. 5 Sekunden nach Klick auf Ja", _
vbCritical + vbYesNo + vbDefaultButton2, "Datei killen") = vbNo Then
Else
'Datei killen mit 5 Sekunden Verzögerung
Application.OnTime Earliesttime:=Now + 5 / 3600 / 24, Procedure:="DateiSchliessen"
End If
End If
ActiveWorkbook.Close savechanges = False
End Sub
Sub DateiSchliessen()
If Not IsEmpty(ThisWorkbook.Worksheets(1).Range("C8")) Then
Kill ThisWorkbook.Worksheets(1).Range("C8").Value
ThisWorkbook.Worksheets(1).Range("C8").Clear
ThisWorkbook.Save
End If
ThisWorkbook.Close savechanges:=False
End Sub
Hier ein Beispiel für die Steuerungsdatei, in die ich noch einen Not-Stopp-Button eingebaut hab, mit dem man in der Verzögerungszeit den Löschvorgang noch abbrechen kann.
https://www.herber.de/bbs/user/39972.zip
Vorsicht beim Testen dieser verbundenen Prozeduren!!!
Vor dem Start der Kill-Makros immer die Datei unter einem anderen Namen/in einem anderen Verzeichnis sichern!!!! Oder immer die Sicherheitsabfrage mit Nein beantworten.
Möglicherweise kann man auch eine Batchdatei erstellen, die mit der Shell-Methode gestartet wird und mit Zeitverzögerung (zum Schliessen der Datei in Excel) die Datei löscht. Wichtig ist dabei immer die vollständige Entkopplung der Löschprozedur von der zu löschenden Excel-Datei. Leider bin ich auf Betriebssystem-Ebene (DOS, Windows) nicht fit genug, um dir hier weiter helfen zu können.
Gruß
Franz