variable Anzahl Daten übertragen

Forumthread: variable Anzahl Daten übertragen

10.08.2007 14:40:41

Peter

Guten Tag
Ich habe in Tabelle "Daten" ab Zeile 8 in Spalte A + B Einträge, die ich in die Tabelle "Auswertung" (beide Tabellen sind in der gleichen Datei) übertragen möchte, und zwar ebenfalls in Spalte A + B, allerdings der erste Eintrag in Zeile 13 (A13; B13) (nur Werte, Formate in Tabelle "Auswertung" sollen unverändert bleiben). Die letzte Zeile mit Einträgen in Spalte A + B ist nicht immer die selbe (variable Anzahl). Wie packe ich das am besten an?
Danke für eine Rückmeldung.
Peter

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: variable Anzahl Daten übertragen

10.08.2007 14:50:00

Ramses
AW: variable Anzahl Daten übertragen

10.08.2007 15:01:36

Peter
AW: variable Anzahl Daten übertragen

10.08.2007 15:05:46

Ramses
AW: variable Anzahl Daten übertragen

10.08.2007 15:18:44

Peter
Entschuldigung...

10.08.2007 15:29:35

Ramses

AW: variable Anzahl Daten übertragen

10.08.2007 14:50:00

Ramses

Hallo
am einfachsten so:

Option Explicit

Sub CopyData()
    Dim lastRow As Long, startRow As Long
    Dim qWks As Worksheet, tarWks As Worksheet
    Set qWks = Worksheets("Daten")
    Set tarWks = Worksheets("Auswertung")
    startRow = 8
    lastRow = qWks.Cells(Rows.Count, 1).End(xlUp).Row
    With tarWks
        qWks.Range(Cells(startRow, 1), Cells(lastRow, 2)).Copy
        .Cells(13, 1).PasteSpecial Paste:=xlPasteValues
    End With
    Set qWks = Nothing
    Set tarWks = Nothing
End Sub

Gruss Rainer

AW: variable Anzahl Daten übertragen

10.08.2007 15:01:36

Peter

Hallo Rainer
Vielen Dank!
Anschlussfragen: Was muss ich anpassen, damit ich das Makro auch ausführen kann, wenn die Tabelle "Daten" nicht aktiv ist; wie kann ich den Kopiermodus (Kopierter Bereich ist noch ersichtlich) abbrechen?
Freundlicher Gruss, Peter

AW: variable Anzahl Daten übertragen

10.08.2007 15:05:46

Ramses

Hallo
"...wenn die Tabelle "Daten" nicht aktiv ist; ..."
OK, du hast "VBA-bescheiden",....aber dann frag nicht, sondern teste erst mal.
Das ist nämlich bereits so vorgesehen !!!
"...Kopierter Bereich ist noch ersichtlich)..."
Wo ist das Problem ?
Drück die Taste "ESC" dann ist er weg, oder schreib als letzte Zeile
Application.CutCopyMode = False
Gruss Rainer

AW: variable Anzahl Daten übertragen

10.08.2007 15:18:44

Peter

Hallo Rainer
Vielen Dank. Die Zeile Application.CutCopyMode = False habe ich eingefügt und es funktioniert.
Ich habe tatsächlich getestet, bevor ich den letzten Thread geschrieben habe. Dabei kam bei der Zeile
qWks.Range(Cells(startRow, 1), Cells(lastRow, 2)).Copy
die Fehlermeldung
"Die Methode 'Range' für das Objekt '_Worksheet' ist fehlgeschlagen"
wenn ich den Makro aufgerufen habe, wenn die Tabelle "Auswertung" aktiv ist.
Weshalb ist mir jedoch leider nicht klar.
Gruss, Peter

Entschuldigung...

10.08.2007 15:29:35

Ramses

Hallo
Dachte EXCEL wäre intelligent genug das zu realisieren :-)

Option Explicit

Sub CopyData()
    Dim lastRow As Long, startRow As Long
    Dim qWks As Worksheet, tarWks As Worksheet
    Set qWks = Worksheets("Daten")
    Set tarWks = Worksheets("Auswertung")
    startRow = 8
    lastRow = qWks.Cells(Rows.Count, 1).End(xlUp).Row
    With tarWks
        With qWks
            .Range(.Cells(startRow, 1), .Cells(lastRow, 2)).Copy
        End With
        .Cells(13, 1).PasteSpecial Paste:=xlPasteValues
    End With
    Set qWks = Nothing
    Set tarWks = Nothing
End Sub

Gruss Rainer

Beliebteste Forumthreads (12 Monate)

variable Anzahl Daten übertragen

Forumthread: variable Anzahl Daten übertragen

5 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread