Variablen in anderer Prozedur aufrufen

Hallo Zusammen,
ich habe eine Frage, die für jeden VBA-Kundigen wahrscheinlich lächerlich ist. Was ich versuche:
Makro1: liest Variablenwerte ein, blendet ein Blatt ein
Makro2: erhält die Variablen inklusive Werten, die mit Makro1 zugewiesen wurden, (macht noch ein paar andere Dinge) und blendet das Blatt wieder aus
Habe das wie unten versucht, umzusetzen, die Zeile
Sheets("test").Range("C2") = customer
im letzten Makro sollte die funktionierende Übergabe "beweisen", aber irgendwie funzt das nicht, und ich stehe auf'm Schlauch :-(
Danke für Hilfe!!
Doro


Sub VariablenDefinition(ByVal customer As String)
customer = Sheets("test").Range("C1").Value
End Sub


Sub BlattEinblenden()
Sheets("WirdEin-undAusgeblendet").Visible = True
End Sub


Sub Confirm()
VariablenDefinition customer
Sheets("test").Range("C2") = customer
Sheets("WirdEin-undAusgeblendet").Visible = False
End Sub

Hallo Doro,
ich darf mal aus Lucs erster Antwort zitieren:
[ZITAT]
2. Statt Subroutine VariablenDefinition (benutzerdefinierte) Function verwenden!
[/ZITAT]
und aus deiner Antwort darauf:
[ZITAT]
Und ne Funktion ist es nicht.
[/ZITAT]
In diesem Punkt habt ihr beide recht. Luc hat recht, wenn er sagt, dass das ein klassischer Fall für eine Funktion ist. Und du hast recht damit, dass das auch als Sub geht. Für beide Möglichkeiten je ein Beispiel. Aufgabe ist jeweils folgendes:
1. Es steht ein Wert in Tabellenblatt "test", Zelle C1.
2. Dieser Wert soll von einer Prozedur eingelesen und an eine zweite Prozedur übergeben werden.
3. Die zweite Prozedur soll den Wert verdoppeln und wieder der ersten Prozedur zur Verfügung stellen.
4. Die erste Prozedur soll den verdoppelten Wert schließlich in die Zelle C2 schreiben.
Möglichkeit 1 per Funktion:

Function verdoppeln(ByVal Eingangswert As Integer) As Integer
  verdoppeln = Eingangswert * 2
End Function
Sub test()
  With Sheets("test")
    .Range("C2") = verdoppeln(.Range("C1"))
  End With
End Sub

Diese Variante ist etwas unübersichtlich, da im Prinzip alles in einer Zeile geschieht. Der Ausgangswert wird von der Prozedur test eingelesen und an die Funktion verdoppeln übergeben. Die Funktion verdoppeln verdoppelt den Wert und gibt ihn wieder an die Prozedur test zurück. Achte darauf, dass innerhalb der Funktion der Name der Funktion wie eine Variable behandelt wird. Dies ist eine ganz spezielle Variable, die nichts anderes ist, als der Rückgabewert, den die Funktion an die aufrufende Prozedur zurückgibt. In der aufrufenden Prozedur wird dieser Rückgabewert in derselben Zeile, die auch die Funktion aufruft, in die Zelle C2 geschrieben.
Möglichkeit 2 per Sub:

Private Sub verdoppeln2(ByRef Wert As Integer)
  Wert = Wert * 2
End Sub
Sub test2()
  Dim Eingangswert As Integer
  With Sheets("test")
    Eingangswert = .Range("C1")
    Call verdoppeln2(Eingangswert)
    .Range("C2") = Eingangswert
  End With
End Sub

In dieser zweiten Variante wird der Ausgangswert aus der Zelle C1 zunächst in die Variable Eingangswert eingelesen. Diese Variable wird dann an die Prozedur verdoppeln2 übergeben. Der Begriff Call ist hier wichtig. Im Prinzip kann ich eine andere Prozedur auch ohne Call aufrufen. Hier geht's aber nur mit Call. Die Prozedur verdoppeln2 greift nun ebenfalls auf die Variable Eingangswert zu, spricht diese Variable aber mit einem anderen Namen, nämlich Wert an (das muss nicht sein, kann aber). Wichtig ist hier in der Kopfzeile der aufgerufenen Prozedur verdoppeln2 der Begriff ByRef. Durch den Begriff ByRef an Stelle von ByVal wird die Prozedur verdoppeln2 veranlasst, direkt auf dieselbe Variable zuzugreifen, die die Prozedur test2 unter dem Namen Eingangswert kennt. Daher muss die Variable auch nicht mehr an die aufrufende Prozedur test2 zurück übergeben werden. Die aufrufende Prozedur kann nun vielmehr einfach die Variable, die sie ja unter dem Namen Eingangswert kennt in die Zelle C2 schreiben.
Gruß Ingolf

Variablen in anderer Prozedur aufrufen

Forumthread: Variablen in anderer Prozedur aufrufen

19
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Infobox / Tutorial