Verknüpfungen

Forumthread: Verknüpfungen

Verknüpfungen

25.02.2009 23:16:43

Franz

Hallo Spezialists
In einer Datei sind viele Verknüpfungen zu einer anderen Datei bzw. Tabellen.
Um mir das Leben zu erleichert wollte ich per Makro die Verknüpfungen ändern.
Die Zellverknüpfung zeigt zur Datei xxx.xls und danach zum Blatt LM403_07 dieses LM403_07 sollte zu LM403_08 umgewandelt werden.
Problem: es sind taussende solcher Verknüpfungen.
Kann mir jemand helfen?
Gruß
Franz

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Verknüpfungen

25.02.2009 23:27:48

Josef
AW: Verknüpfungen

25.02.2009 23:45:42

Franz
AW: Verknüpfungen

26.02.2009 11:25:57

Franz

AW: Verknüpfungen

25.02.2009 23:27:48

Josef

Hallo Franz,
ungetestet, deshalb an einer Kopie ausprobieren.

' **********************************************************************
' Modul: Modul1 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Sub changeSource()
  Dim rng As Range, rngF As Range
  Dim objWs As Worksheet
  Dim strOld As String, strNew As String

  strOld = "LM403_07!"
  strNew = "LM403_08!"

  On Error GoTo ErrExit
  GMS

  For Each objWs In ThisWorkbook.Worksheets
    On Error GoTo 0
    Set rngF = objWs.UsedRange.SpecialCells(xlCellTypeFormulas)
    On Error GoTo ErrExit
    If Not rngF Is Nothing Then
      For Each rng In rngF
        rng.Formula = Replace(rng.Formula, strOld, strNew)
      Next
    End If
  Next


  ErrExit:
  GMS True
  Set rng = Nothing
End Sub

Public Sub GMS(Optional ByVal Modus As Boolean = False)
  Static lngCalc As Long

  With Application
    .ScreenUpdating = Modus
    .EnableEvents = Modus
    .DisplayAlerts = Modus
    .EnableCancelKey = IIf(Modus, 1, 0)
    If Not Modus Then lngCalc = .Calculation
    If Modus And lngCalc = 0 Then lngCalc = -4105
    .Calculation = IIf(Modus, lngCalc, -4135)
    .Cursor = IIf(Modus, -4143, 2)
  End With

End Sub

Gruß Sepp

AW: Verknüpfungen

25.02.2009 23:45:42

Franz

Hallo Sepp
Versuche es morgen bei der Arbeit.
Hoffentlich klappt es. Chef ist schon sauer, daß ich noch nicht angefangen habe.
Aber bei über 1000 Aederungen ist es ja wohl verständlich, daß nicht umbedingt die grosse Freude herscht.
gib morgen bescheid.
Gruß
Franz

AW: Verknüpfungen

26.02.2009 11:25:57

Franz

Hallo Sepp
Man o Man habe einen Rosenkranz im Geschäft bekommen. Auf Ewig in Stein gemeisselt.
Cheffe war überrascht, daß ich schon fertig bin.
Also Sepp nochmals vielen vielen Dank
Gruß
Franz

Beliebteste Forumthreads (12 Monate)

Forumthread: Verknüpfungen

3 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Beliebteste Forumthreads (12 Monate)

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread