Live-Forum - Die aktuellen Beiträge
Datum
Titel
28.03.2024 21:12:36
28.03.2024 18:31:49
Anzeige
Archiv - Navigation
1092to1096
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Runden

Runden
Christian
Hallo,
ich möchte mit Excel eine Notenberechnung durchführen:
Die Endenote setzt sich aus 3 Teilen zusammen:
A: 25%
B: 25%
C: 50%
Und die Endnote kann nur die Ausprägungen x,0; x,3; oder x,7 annehmen.
Mit dieser Formel berechne ich die Note: Zelle1*0,25+Zelle2*0,25+Zelle*0,5
Jetzt soll aber das Ergebnis auf ,0 ,3 oder ,7 abgerundet werden.
Bsp: Die o.g. Formel ergibt 1,6. Dann sollte auf 1,3 abgerundet werden. Bei 1,8 sollte auf 1,7 abgerundet werden.
Hat jemand einen Vorschlag?
Vielen Dank und viele Grüße,
Christian
Notenrundung (ungewöhnlich)
03.08.2009 21:30:01
Erich
Hi Christian,
vielleicht so? (entweder mit Hilfsspalte D und kurzer Formel in Sp. E
oder mit einer einzigen langen Formel wie in Sp. F)
 ABCDEF
125%25%50%   
23364,54,34,3
34364,754,74,7

Formeln der Tabelle
ZelleFormel
D2=SUMMENPRODUKT(A$1:C$1;A2:C2)
E2=GANZZAHL(D2) +0,3*(REST(D2;1)>=0,3) +0,4*(REST(D2;1)>=0,7)
F2=GANZZAHL(SUMMENPRODUKT(A$1:C$1;A2:C2)) +0,3*(REST(SUMMENPRODUKT(A$1:C$1;A2:C2); 1)>=0,3) +0,4*(REST(SUMMENPRODUKT(A$1:C$1;A2:C2); 1)>=0,7)


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort
Anzeige
AW: Notenrundung (ungewöhnlich)
03.08.2009 21:32:14
BoskoBiati
Hallo zusammen,
oder so:
Tabelle1

 AB
1422,0

Formeln der Tabelle
ZelleFormel
B14=WENN((A14-GANZZAHL(A14))>=0,7;GANZZAHL(A14)+0,7;WENN((A14-GANZZAHL(A14))>=0,3;GANZZAHL(A14)+0,3;GANZZAHL(A14)))


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruß
Bosko
Anzeige
AW: Notenrundung (ungewöhnlich)
03.08.2009 21:58:28
Christian
Hi,
vielen Dank. Ihr habt mir sehr geholfen. Es funktioniert. Ich weiß zwar noch nicht genau wie, aber das finde ich schon noch raus ;)
Viele Grüße,
Christian
AW: Notenrundung (ungewöhnlich)
03.08.2009 22:14:29
Christian
Hi Bosko,
vielen Dank! Auch bei dieser Variante wird bei einem ,7 Wert auf ,3 abgerundent. Werde noch ein bisschen probieren.
VG,
Christian
AW: Notenrundung (ungewöhnlich)
03.08.2009 22:28:04
Christian
es gibt scheinbar Probleme mit der zweiten Wenn Bedingung. Obwohl die erste Wenn Bedingung erfüllt ist, springt die Funktion in den "sonst-Wert" und aktiviert somit die zweite Wenn Funktion ...
AW: Notenrundung (ungewöhnlich)
03.08.2009 22:11:30
Christian
Hi Erich,
wenn als Ergebnis des Summenprodukts ein Wert mit ,7 rauskommt wird auf ,3 gerundet.
Es sollte dann aber ,7 bleiben.
VG,
Christian
Anzeige
Fehlerfall?
03.08.2009 22:23:09
Erich
Hi Christian,
hast du mal ein Beispiel dafür, dass es nicht klappt?
 ABCDEFG
125%25%50%    
53,8111,71,71,71,7

Formeln der Tabelle
ZelleFormel
D5=SUMMENPRODUKT(A$1:C$1;A5:C5)
E5=GANZZAHL(D5) +0,3*(REST(D5;1)>=0,3) +0,4*(REST(D5;1)>=0,7)
F5=GANZZAHL(SUMMENPRODUKT(A$1:C$1;A5:C5)) +0,3*(REST(SUMMENPRODUKT(A$1:C$1;A5:C5); 1)>=0,3) +0,4*(REST(SUMMENPRODUKT(A$1:C$1;A5:C5); 1)>=0,7)
G5=WENN((D5-GANZZAHL(D5))>=0,7;GANZZAHL(D5)+0,7;WENN((D5-GANZZAHL(D5))>=0,3;GANZZAHL(D5)+0,3;GANZZAHL(D5)))


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort
Anzeige
AW: Fehlerfall?
03.08.2009 22:29:23
BoskoBiati
Hallo Erich,
hier mal eine mögliche Ursache für den vermeintlichen Fehlerfall:
Tabelle1

 ABCD
125%25%50% 
24554,7
3   4,3

Formeln der Tabelle
ZelleFormel
D2=SUMMENPRODUKT(A1:C1*A2:C2)
D3=GANZZAHL(SUMMENPRODUKT(A$1:C$1;A2:C2)) +0,3*(REST(SUMMENPRODUKT(A$1:C$1;A2:C2); 1)>=0,3) +0,4*(REST(SUMMENPRODUKT(A$1:C$1;A2:C2); 1)>=0,7)


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Tabelle1

 ABCD
125%25%50% 
24,04,85,04,69
3   4,3

Formeln der Tabelle
ZelleFormel
D2=SUMMENPRODUKT(A1:C1*A2:C2)
D3=GANZZAHL(SUMMENPRODUKT(A$1:C$1;A2:C2)) +0,3*(REST(SUMMENPRODUKT(A$1:C$1;A2:C2); 1)>=0,3) +0,4*(REST(SUMMENPRODUKT(A$1:C$1;A2:C2); 1)>=0,7)


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Identische Tabellen, nur Anzeige der Dezimalstellen verändert.
Gruß
Bosko
Anzeige
AW: Runden
03.08.2009 21:34:17
Daniel
Hi
wenn du mit der ungenauigkeit leben kannst, daß die Rundungsgrenzen nicht 0 ,3 und ,7 sind sondern
0 ,333333333333 und ,66666666 (also 0 1/3 und 2/3), dann so:
das Ergebnis mit 3 multiplizieren, dann abrunden und wieder durch 3 teilen, als Formel:
=Abrunden(A1*3;0)/3
Gruß, Daniel
AW: Runden
03.08.2009 21:43:05
BoskoBiati
Hallo Daniel,
bei 1,3 rundet Deine Formel auf 1,0!
AW: Runden
03.08.2009 22:12:28
Daniel
Hi
ja klar, Rundungsgrenze ist ,3333333 und es wird immer abgerundet.
und da 1,3 kleiner als 1,33333333 ist, wird aus 1,3 eben 1,0.
das hatte ich aber so dazugeschrieben.
Gruß, Daniel
AW: Runden mit Sverweis
03.08.2009 22:26:04
Daniel
Hi
hier noch ne möglichkeit:
=GANZZAHL(A1)+SVERWEIS(A1-GANZZAHL(A1);{0;0,3;0,7;1};1;1)
Gruß, Daniel
Anzeige
AW: Runden mit Sverweis optimiert
03.08.2009 22:28:17
Daniel
Hi
ich hab noch Erichts Idee mit dem Rest eingebaut, dann wirds noch etwas einfacher:
=GANZZAHL(A1)+SVERWEIS(REST(A1;1);{0;0,3;0,7;1};1;1)
Gruß, Daniel
AW: Runden mit Sverweis optimiert
03.08.2009 22:28:17
Daniel
Hi
ich hab noch Erichts Idee mit dem Rest eingebaut, dann wirds noch etwas einfacher:
=GANZZAHL(A1)+SVERWEIS(REST(A1;1);{0;0,3;0,7;1};1;1)
Gruß, Daniel
AW: Runden mit Sverweis optimiert - Fehler
Beate
Hallo Daniel,
schau mal, in Zelle B14 kommt das Ergebnis falsch, habe mich aber nicht weiter damit auseinandergesetzt, weil ich jetzt Offline gehen muss:
 AB
111
21,11
31,21
41,31,3
51,41,3
61,51,3
71,61,3
81,71,7
91,81,7
101,91,7
1122
122,12
132,22
142,32
152,42,3
162,52,3

Formeln der Tabelle
ZelleFormel
B1=GANZZAHL(A1)+SVERWEIS(REST(A1;1); {0;0,3;0,7;1};1;1)

Die Formel aus B1 kann dazu runterkopieren.
Gruß,
Beate
Anzeige
Runden mit SVERWEIS - korrigiert
03.08.2009 22:46:09
Erich
Hi zusammen,
Beates Beispiel zeigt den Einfluss der notwendigerweise ungenauen Speicherung von Fließkommazahlen.
So sollte die Formel (fast) immer richtig rechnen:
 AB
12,32,3

Formeln der Tabelle
ZelleFormel
B1=KÜRZEN(A1)+SVERWEIS(REST(A1;1)+0,00000000000001;{0;0,3;0,7};1;1)

Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort
Anzeige
noch ein wenig kürzer
03.08.2009 22:33:37
Erich
Hi zusammen,
Daniels Schöne Lösung noch etwas verkürzt:
=KÜRZEN(A1)+SVERWEIS(REST(A1;1);{0;0,3;0,7};1;1)
Was spricht eigentlich gegen REST(A1;1) und für A1-GANZZAHL(A1) ?
Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort
AW: noch ein wenig kürzer
03.08.2009 22:35:53
Christian
Vielen Dank.
Leider wird auch hier bei einem Ergebnis von bspw. 1,7 auf 1,3 abgerundet.
VG
AW: noch ein wenig kürzer
03.08.2009 22:37:33
Christian
ah ... ich denke es hat mit den Kommastellen zu tun. Ich hatte nur eine Kommastelle sichtbar. es sind nicht 1,7 sondern 1,65.
Dann passt alles wunderbar!
Vielen Dank euch allen.
VG,
Christian
AW: Rest<>-Ganzzahl
04.08.2009 13:40:39
Daniel
Hi
nix, ich hatte bisher die Funktion REST nur als Anwendung für Ganzzahlen auf dem Schirm, nicht für Nachkommawerte, aber ich habs ja übernommen ;-)
Gruß, Daniel
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige