Erste freie Zelle

Forumthread: Erste freie Zelle

Erste freie Zelle

Peter

Hallo Freunde,
ich habe folgendes Problem:
nachstehendes Makro funktioniert in einem anderen Projekt, aber hier blockiert es immer in der Befehlszeile
Cells(Range("A1").End(xlDown).Row + 1, 1).Select
Aufgabe des Makros ist es Daten aus der Tabelle "Jul" in die erste leere Zeile ab Spalte A der Tabelle "Mahnungen" zu übertragen.
Ich habe es auch mit anderen gleichartigen Befehlen versucht, aber immer der gleiche Misserfolg.

Sub Mahnungen()
ActiveSheet.Unprotect
ActiveCell.FormulaR1C1 = "1.Mahnung"
ActiveCell.Offset(0, -14).Range("A1:J1").Select
Selection.Copy
Sheets("Mahnungen").Select
Cells(Range("A1").End(xlDown).Row + 1, 1).Select
Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
:=False, Transpose:=False
Sheets("Jul").Select
Application.CutCopyMode = False
ActiveCell.Select
ActiveCell.Offset(0, 14).Select
Selection.Locked = True
Selection.FormulaHidden = False
ActiveSheet.Protect DrawingObjects:=True, Contents:=True, Scenarios:=True
End Sub

Wer kann mir bitte helfen den Fehler zu finden.
Vielen Dank im voraus
Peter

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Benutzer

AW: Erste freie Zelle

08.08.2009 15:57:19

Herbert

Hi,
was heißt "blockiert"? Welcher Fehler wird gemeldet?
Besser Beispiel hochladen.
mfg Herbert

AW: Erste freie Zelle

08.08.2009 16:12:46

Peter

https://www.herber.de/bbs/user/63708.xls
Hallo Herbert,
das nenne ich schnelle Reaktion!!! Danke!!
Anbei der Link zur Datei.
Liebe Grüße
Peter

AW: Erste freie Zelle

08.08.2009 17:08:03

Herbert

Hi,
Das Blatt Mahnungen sollte unbedingt Überschriften enthalten.
Ändere die Codezeile wie folgt:
Cells(Range("A1").End(xlUp).Row + 1, 1).Select
mfg Herbert

Kopie in erste freie Zeile

08.08.2009 17:35:57

Erich

Hi Peter,
mit der falschen Zeile
Cells(Range("A1").End(xlDown).Row + 1, 1).Select
würdest du unterhalb der letztmöglichen Zeile (z. B. 65537) landen, wenn Spalte A leer oder nur A1 gefüllt ist.
Besser verwende die Zeile, doe Herbert geschrieben hat.
Oder du versuchst es damit (ganz ohne "Select"):


Option Explicit
Sub Mahnungen()
Dim lngQ As Long, lngZ As Long
lngQ = ActiveCell.Row
If Not IsEmpty(Cells(lngQ, 15)) Then
MsgBox "Zelle O" & lngQ & " ist nicht leer!"
Exit Sub
End If
With Sheets("Mahnungen")
lngZ = .Cells(.Rows.Count, 1).End(xlUp).Row + 1
If lngZ >= .Rows.Count Then
MsgBox "Blatt '" & .Name & "' ist voll."
Exit Sub
End If
.Cells(lngZ, 1).Resize(, 10) = Cells(lngQ, 1).Resize(, 10).Value
End With
With ActiveSheet
.Unprotect
With Cells(lngQ, 15)
.Value = "1.Mahnung"
.Locked = True
.FormulaHidden = False
End With
.Protect DrawingObjects:=True, Contents:=True, Scenarios:=True
End With
End Sub

Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort

AW: Kopie in erste freie Zeile

09.08.2009 10:09:39

Peter

Hallo Herbert und Erich,
es ist ja toll wie schnell ihr so professionelle Lösungen anbietet.
Vielen herzlichen Dank, ihr habt mir sehr geholfen.
Das komplette Makro von Erich (mit der MsgBox) funktioniert fantastisch!!!!
Beste Grüße aus Tirol
Peter

Beliebteste Forumthreads (12 Monate)

Forumthread: Erste freie Zelle

5 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Beliebteste Forumthreads (12 Monate)

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread