Microsoft Excel

Herbers Excel/VBA-Archiv

Formelsuche | Herbers Excel-Forum


Betrifft: Formelsuche von: Frank H.
Geschrieben am: 18.01.2010 08:13:11

Einen wunderschönen Guten Morgen euch Allen!!!

Mein Problem: Ich nutze folgende Formel:

=INDEX(A:A;3+VERGLEICH(H4;$C$4:$C$2024;0))

Diese funzt soweit ganz gut, aber wenn ein Wert in Spalte C doppelt vorkommt, dann wird aber trotzdem nur der erste dazugehörige Wert aus Spalte A angezeigt. Ich möchte beim Finden des ersten Suchbegriffes das der erste dazugehörige Wert erscheint und wenn der Begriff zum zweiten Mal auftaucht, auch der zweite dazugehörige Begriff auftaucht! Wie muss ich meine Formel erweitern oder umstellen???

Danke schon Mal!!!

Gruß Frank H.

  

Betrifft: SVERWEIS bei mehrfach vorkommendem Suchkriterium von: Erich G.
Geschrieben am: 18.01.2010 08:21:57

Hi Frank,
hast du dir das schon mal angesehen? http://www.excelformeln.de/formeln.html?welcher=28

Aus deiner Frage wird nicht klar, WO "auch der zweite dazugehörige Begriff auftauch"en soll:
In der selben Zelle? oder der Zelloe darunter oder daneben?

Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort


  

Betrifft: AW: SVERWEIS bei mehrfach vorkommendem Suchkriterium von: Frank H.
Geschrieben am: 18.01.2010 08:33:31

Hallo Erich!!!

Danke für die schnelle Nachfrage!!!

Meine Formel steht in Spalte M. Wird nun eine Übereinstimmung des Wertes aus H mit einem Wert aus C gefunden wird der dazugehörige Wert in die Zelle der Spalte M eingetragen. Ist der Wert in H nun ein zweites mal in C vorhanden, soll nun der jetzt in Spalte A dazugehörige Wert auftauchen!!! So besser zu verstehen???

Den Link habe ich mir angesehen, stehe aber auf dem Schlauch es umzusetzen!

Danke! Frank H.!


  

Betrifft: noch unklar von: Erich G.
Geschrieben am: 18.01.2010 08:49:41

Hi Frank,
nein - leider ist das noch nicht besser zu verstehen.

Nehmen wir mal an, deine Formel steht z. B. in Zelle (nicht Spalte!) M4,
angezeigt wird das Ergebnis 123,45 (=A17) zum ersten Treffer (H4 wurde gefunden in C17).

Wenn H4 nun auch in C23 gefunden wird, wo soll dann der Wert 777,88 aus A23 stehen?
Auch in Zelle M4? Wenn ja - wie soll das aussehen? Z. B. könnte das so sein: 1233,45 / 777,88

Oder sollen die weiteren Treffer in anderen Zellen als M4 stehen?

Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort


  

Betrifft: AW: noch unklar von: Frank H.
Geschrieben am: 18.01.2010 09:10:51

Hall Erich!

Danke f. deine Mühe!! Ist nicht selbstverständlich!!!

Meine Formel aus M4 wird runterkopiert. Der Wert aus H18 bspw. stimmt mi dem wert aus C18 überein, dann wert aus A18. Nun kommt der Wert von H18 aber noch einmal vor, z.B. in H345 und steht auch noch in C 243, dann bitte den Wert aus A243 in M243. Nun besser???

Gruß und Danke Frank!

PS.: Bis gegen 11:30 Uhr. Muss kurz weg.


  

Betrifft: jetzt wohl klar von: Erich G.
Geschrieben am: 18.01.2010 10:07:45

Hi Frank,
jetzt kam Licht ins Dunkel.

Ein Wert tritt in Spalte H evtl. mehrfach auf, evtl. dann auch in Spalte C.
Dann soll paarweise zugeordnet werden.

Probiers mal damit:

 ABCHM
4a x1yy2bb
5bb yy2w#ZAHL!
6ccc zzzz3yy2dddd
7dddd yy2x1a

Formeln der Tabelle
ZelleFormel
M4{=INDEX(A:A;KKLEINSTE(WENN($C$4:$C$2024=H4;ZEILE($4:$2024)); ZÄHLENWENN(H$4:H4;H4)))}
M5{=INDEX(A:A;KKLEINSTE(WENN($C$4:$C$2024=H5;ZEILE($4:$2024)); ZÄHLENWENN(H$4:H5;H5)))}
M6{=INDEX(A:A;KKLEINSTE(WENN($C$4:$C$2024=H6;ZEILE($4:$2024)); ZÄHLENWENN(H$4:H6;H6)))}
M7{=INDEX(A:A;KKLEINSTE(WENN($C$4:$C$2024=H7;ZEILE($4:$2024)); ZÄHLENWENN(H$4:H7;H7)))}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen

Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort


  

Betrifft: AW: jetzt wohl klar von: Frank H.
Geschrieben am: 18.01.2010 12:50:58

Hallo noch einmal!!!

Danke dir für dein tolles Bemühen. Funzt Super!!!

Bis zum nächsten Mal!!!

Gruß Frank H.