Herbers Excel/VBA-Archiv

Tabellenblätter anlegen und mit Daten befüllen | Herbers Excel-Forum

• Tabellenblätter anlegen und mit Daten befüllen von Mat vom 22.01.2010 19:10:50
• AW: Tabellenblätter anlegen und mit Daten befüllen - von Christian am 22.01.2010 22:27:16
  • AW: Tabellenblätter anlegen und mit Daten befüllen - von Mat am 23.01.2010 22:46:03

Betrifft: Tabellenblätter anlegen und mit Daten befüllen von: Mat
Geschrieben am: 22.01.2010 19:10:50

Hallo liebes Excelforum,

wer kann mir bei der folgenden Aufgabe mit einem Makro helfen.

Ich haben ein Datenblatt mit ca. 50 Namen, welche die dazugehörigen Werte in einer Liste beinhalten. Nun müsste für jeden Namen ein eigenes Tabellenblatt mit den jeweiligen Daten erstellt werden. Die Datenüberschriften sollten dabei in Spalte A transponiert und das Tabellenblatt nach dem Namen benannt werden.

Hier mein Beispiel: https://www.herber.de/bbs/user/67428.xls

Viele Grüße

Mat

Betrifft: AW: Tabellenblätter anlegen und mit Daten befüllen von: Christian
Geschrieben am: 22.01.2010 22:27:16

Hallo,
ein Ansatz
Gruß
Christian

Option Explicit

Sub VerteilDat()
    Dim wks As Worksheet, i&, vntCapt, vntDat
    
    Application.ScreenUpdating = False
    Application.DisplayAlerts = False
    For Each wks In Worksheets
        If wks.Name <> "Data" Then wks.Delete
    Next
    Application.DisplayAlerts = True
    With Sheets("Data")
        vntCapt = .Cells(1, 2).Resize(, 20).Value
        For i = 2 To .Cells(.Rows.Count, 1).End(xlUp).Row
            Set wks = Sheets.Add(, Sheets(Sheets.Count))
            vntDat = .Cells(i, 2).Resize(, 20).Value
            wks.Cells(1, 2) = .Cells(i, 1)
            wks.Name = .Cells(i, 1)
            wks.Cells(2, 1).Resize(20) = Application.Transpose(vntCapt)
            wks.Cells(2, 2).Resize(20) = Application.Transpose(vntDat)
        Next
    End With
    Application.ScreenUpdating = True
    Set wks = Nothing
End Sub

Betrifft: AW: Tabellenblätter anlegen und mit Daten befüllen von: Mat
Geschrieben am: 23.01.2010 22:46:03

Hallo Christian,

vielen Dank für Deine Hilfe. Damit müsste ich gut zurecht kommen.

Bis zum nächsten mal.

Viele Grüße

Mat

Beiträge aus den Excel-Beispielen zum Thema "Tabellenblätter anlegen und mit Daten befüllen"