Zahlen mit 3 relvanten Stellen anzeigen

Forumthread: Zahlen mit 3 relvanten Stellen anzeigen

Hallo zusammen,
Ich möchte in einem Geschützem Registerblatt, Zahlen immer mit 3 relevanten stellen darstellen und dafür folgende Wenn abfrage eingefügt.
=WENN(UND((ANZAHL(C12)=1);(C12>0);(ANZAHL($D$11)=1);($D$11>0)); WENN(C12*$D$11>=100;RUNDEN(C12*$D$11; 0);WENN(UND((100>C12*$D$11); C12*$D$11>=10));RUNDEN(C12*$D$11;1);WENN(UND((10>C12*$D$11); C12*$D$11>=1));RUNDEN(C12*$D$11;2);WENN(UND((1>=C12*$D$11);(C12*$D$11>0)); RUNDEN(C12*$D$11;3); C12*$D$11))));"-") Leider kann es jetzt vorkommen das eine Zahl z.B. genau den "2.00" hat. Diese wird jetzt aber leider gemäß der obrigen Rundungsregel als "2" dargestellt. Leider ist jetzt die zwingende Vorgabe das diese Zahl als "2.00" dargestellt wird. Das Zellenformat ist Standard.
Gibt es eine Möglichkeit Excel zu sagen er soll Trotzdem zwei nachkomma stellen anzeigen, ohne VBA Code zu verwenden?
Vielen im Vorraus für eure Hilfe.
Gruß
Markus

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Benutzer

AW: Zahlen mit 3 relvanten Stellen anzeigen

02.03.2010 13:54:40

Josef

Hallo Markus,

EXcel gut" ? Formatiere die Zelle als Zahl mit 2 Dezimalstellen.

Gruß Sepp

Sorr^y,.. hab deine Antwort nicht gesehen o.w.T.

02.03.2010 13:57:48

Ramses

...

AW: Zahlen mit 3 relvanten Stellen anzeigen

02.03.2010 14:02:40

Hallo Josef,
Das hilft mir leider nicht. Wenn es so einfach wäre, bräuchte ich die Rundungsregeln nicht.
Nochmal zur Verdeutlichung.
Die Zelle kann Werte zwischen 0.123 - 112345.678 haben.
Alle Werte sollen mit 3 "relevante" Stellen angezeigt werden. Also:
0,1234 =0,123
1,234 =1,23
12,34 =12,3
123,4 =123
1234 =1234
Mit der oben beschriebenen Rundungsregel funktioniert das ganz gut. Ist in der Zelle aber eine Zahl wie z.b: 12.0 wird nur 12 angezeigt, bei 2,00 nur 2.
Es ist aber zwingend Vorgeschrieben das auch bei diesen Zahlen 3 stellen angezeit werden. Also 12.,0 und 2,00.
Ich hoffe jetzt ist mein Problem besser erklärt.
gru0
Markus

AW: Zahlen mit 3 relvanten Stellen anzeigen

02.03.2010 14:51:27

Josef

Hallo Markus,

was besseres fällt mir dazu nicht ein.

	A	B	C	D
1	0,1234		0,123
2	1,234		1,23
3	12,34		12,3
4	123,4		123
5	1234		1234
6	2		2,00
7
8
9

Formeln der Tabelle

Zelle	Formel
C1	=WENN(A1="";"";FEST(A1;MAX(WENN(REST(A1;1)=0;MAX(0;3-LÄNGE(GANZZAHL(A1))); LÄNGE(A1)-FINDEN(",";A1)-1)); 1))

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4

Gruß Sepp

Dann wdn die Zahlen zu Text! Wenn du das...

02.03.2010 15:33:56

Luc:-?

…nicht willst, Markus,
führt kein Weg an flexibler Formatfestlegung mittels VBA-(Ereignis-)Prozedur vorbei. Je nach Anspruch kann das relativ einfach oder ziemlich kompliziert wdn…
Gruß Luc :-?

AW: Dann wdn die Zahlen zu Text! Wenn du das...

02.03.2010 17:07:23

Hallo Josef,
Dein Tipp mit Fest war der Durchbruch.
Somit kann ich die Zahlen so formatieren wie ich sie brauche.

=WENN(ANZAHL(C15)=1;WENN(C15>=100;RUNDEN(C15;0);WENN(UND(C15=10);FEST(RUNDEN(C15;1);1;WAHR); WENN(UND(C15=1);FEST(RUNDEN(C15;2);2;WAHR);WENN(UND(C15=0);FEST(RUNDEN(C15;3);3;WAHR)) )));"-")

Das die Zahlen dadurch zu Text werden, damit kann ich Leben. Da dies ein reines Ausgabesheet wird. An dem nichts mehr geändert wird.
Vielen Dank.
Gruß
Markus

Format - Zellen - Zahl - Dezimalstellen = 2 o.w.T.

02.03.2010 13:56:36

Ramses

...

Runden und 3 signifikante Stellen anzeigen

03.03.2010 10:26:08

Erich

Hi Markus,
mit deinen und Sepps Formeln habe ich noch ein wenig weiter gebastelt:

	C	D	E	F	G	H	I	J	K	L	M	N
11		1,1	Rundung	oder	oder	Formel 179		nur pos.	auch neg.	Sepps Formel	Markus geä.	Markus
12	0,0007	0,00077	0,001	0,00077	0,001	0,00077		0,00077	0,00077	0,00077	0,001	0,001
13	0,007	0,0077	0,008	0,0077	0,008	0,0077		0,008	0,008	0,008	0,008	0,008
14	0,07	0,077	0,077	0,077	0,077	0,077		0,077	0,077	0,077	0,077	0,077
15	0,7	0,77	0,77	0,77	0,77	0,77		0,77	0,77	0,77	0,770	0,770
16	7	7,7	7,7	7,7	7,7	7,7		7,70	7,70	7,7	7,70	7,70
17	70	77	77	77	77	77		77,0	77,0	77,0	77,0	77,0
18	700	770	770	770	770	770		770	770	770	770	770
19	7000	7700	7700	7700	7700	7700		7700	7700	7700	7700	7700
20	-0,7	-0,77	-	-0,77	-0,77	-0,77		-0,77	-0,77	-0,77	negativ	FALSCH
21	-7	-7,7	-	-7,7	-7,7	-7,7		-7,7	-7,70	-7,7	negativ	FALSCH
22	-70	-77	-	-77	-77	-77		-77	-77,0	-77	negativ	FALSCH
23	-700	-770	-	-770	-770	-770		-770	-770	-770	negativ	FALSCH

Formeln der Tabelle

Zelle	Formel
D12	=C12*$D$11
E12	=WENN(UND((ANZAHL(C12)=1); (C12>0); (ANZAHL($D$11)=1); ($D$11>0)); WENN(C12$D$11>=100;RUNDEN(C12$D$11; 0); WENN(UND((100>C12$D$11); C12$D$11>=10); RUNDEN(C12$D$11;1); WENN(UND((10>C12$D$11); C12$D$11>=1); RUNDEN(C12$D$11;2); WENN(UND((1>=C12$D$11); (C12$D$11>0)); RUNDEN(C12$D$11;3); C12$D$11)))); "-")
F12	=WENN(ISTZAHL(D12); RUNDEN(D12;MAX(;2-GANZZAHL(LOG(ABS(D12))))); "-")
G12	=WENN(ISTZAHL(D12); RUNDEN(D12;MIN(3;MAX(;2-GANZZAHL(LOG(ABS(D12)))))); "-")
H12	=RUNDEN(D12;2-GANZZAHL(LOG(ABS(D12))))
J12	=WENN(ISTZAHL(F12); LINKS(F12&WENN(REST(F12;1)>0;"";",")&"000"; MAX(LÄNGE(F12); 4-(LÄNGE(F12)=3)*(REST(F12;1)=0))); "-")
K12	=WENN(ISTZAHL(F12); LINKS("-";F12<0)&LINKS(ABS(F12)&WENN(REST(F12;1)>0;"";",")&"000"; MAX(LÄNGE(ABS(F12)); 4-(LÄNGE(ABS(F12))=3)*(REST(F12;1)=0))); "-")
L12	=WENN(F12="";"";FEST(F12;MAX(WENN(REST(F12;1)=0; MAX(0;3-LÄNGE(GANZZAHL(F12))); 1+LÄNGE(F12)-FINDEN(",";F12)-1)); 1))
M12	=WENN(ANZAHL(F12)=1;WENN(F12>=100;""&RUNDEN(F12;0); WENN(F12>=10;FEST(RUNDEN(F12;1); 1;1); WENN(F12>=1;FEST(RUNDEN(F12;2); 2;1); WENN(F12>=0;FEST(RUNDEN(F12;3); 3;1); "negativ")))); "-")
N12	=WENN(ANZAHL(F12)=1;WENN(F12>=100;RUNDEN(F12;0); WENN(UND(F12<100;F12>=10); FEST(RUNDEN(F12;1); 1;WAHR); WENN(UND(F12<10;F12>=1); FEST(RUNDEN(F12;2); 2;WAHR); WENN(UND(F12<1;F12>=0); FEST(RUNDEN(F12;3); 3;WAHR))))); "-")

Ausgangspunkt für die Rundung sind die Zahlen in D12:D23.
In E12 steht deine Formel, in H12 die Formel aus http://www.excelformeln.de/formeln.html?welcher=179
(Achtung: Die Excelformeln-Formel würde 7777 zu 7780 runden - also immer auf 3 signifikante Stellen.)
In F12, G12 stehen meine Vorschläge für die Rundung.
In den Spalten ab J stehen dann die Darstellungen.
J12 ist mein Vorschlag, der aber nicht bei negativen Zahlen passt (J21:J22 sind falsch).
K12 klappt auch bei negativen.
Sepps Formel in Spalte L klappt nicht richtig in Zelle L16.
In N12 steht deine alte Formel. In M18:M19 kommen Zahlen (rechtsbündig) raus, sonst Text,
außer bei negativen, da fehlt der SONST-Zweig, deshalb kommt in N20:N23 der Wert FALSCH.
In M12 habe ich deine Formel etwas korrigiert:
Durch ""&RUNDEN(F12 ... statt RUNDEN(F12 wird hier immer ein Text erzeugt.
In den SONST-Zweig habe ich "negativ" geschrieben.
Weglassen konnte man die UNDs.
Vielleicht kannst du ja damit noch etwas anfangen.
Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort

Infobox / Tutorial

Zahlen mit 3 relevanten Stellen in Excel anzeigen

Schritt-für-Schritt-Anleitung
Häufige Fehler und Lösungen
Alternative Methoden
Praktische Beispiele
Tipps für Profis
FAQ: Häufige Fragen

Schritt-für-Schritt-Anleitung

Zelle formatieren: Stelle sicher, dass die Zelle in Excel, in der du die Zahl anzeigen möchtest, richtig formatiert ist. Du kannst die Zelle als "Zahl" mit 2 Dezimalstellen formatieren.
Formel eingeben: Verwende die folgende Formel, um die Zahl auf 3 signifikante Stellen zu runden:
```
=WENN(ANZAHL(C12)=1;WENN(C12>0;RUNDEN(C12;MAX(0;3-LÄNGE(GANZZAHL(C12))));"-")
```
Diese Formel prüft, ob in Zelle C12 eine Zahl vorhanden ist, und rundet sie entsprechend.
Zusätzliche Formatierung: Wenn du sicherstellen möchtest, dass auch Zahlen wie 2.00 als 2.00 angezeigt werden, kannst du die Funktion FEST verwenden:
```
=WENN(ANZAHL(C12)=1;FEST(RUNDEN(C12;MAX(0;3-LÄNGE(GANZZAHL(C12))));2;WAHR);"-")
```
Anpassungen: Passe die Formel an deine spezifischen Anforderungen an, um sicherzustellen, dass sie die gewünschten Ergebnisse liefert.

Häufige Fehler und Lösungen

Problem: Die Zahl wird nicht im gewünschten Format angezeigt (z.B. 2 statt 2.00).
- Lösung: Stelle sicher, dass du das Zellenformat auf "Zahl" mit 2 Dezimalstellen eingestellt hast.
Problem: Die Formel liefert unerwartete Ergebnisse.
- Lösung: Überprüfe, ob die Eingabewerte korrekt sind und ob die Formel die richtige Zellreferenz verwendet.

Alternative Methoden

Verwendung von VBA: Falls du bereit bist, VBA zu nutzen, kannst du eine benutzerdefinierte Funktion erstellen, um signifikante Stellen zu bestimmen. Dies könnte jedoch komplexer sein und erfordert Programmierkenntnisse.
Formatierungsoptionen: Du kannst auch die Formatierungsoptionen in Excel nutzen, um die Anzeige von Zahlen zu steuern, ohne sie tatsächlich zu verändern.

Praktische Beispiele

Beispiel 1: Für die Zahl 0.1234 wird das Ergebnis 0.123.
Beispiel 2: Für 1.234 erhältst du 1.23.
Beispiel 3: Bei 12.34 wird das Ergebnis 12.3.
Beispiel 4: Die Zahl 2.00 wird korrekt als 2.00 angezeigt.

Verwende die bereitgestellten Formeln, um diese Beispiele in Excel nachzuvollziehen.

Tipps für Profis

Verwendung von WENN und ANZAHL: Kombiniere diese Funktionen, um sicherzustellen, dass deine Formeln nur dann aktiv werden, wenn tatsächlich Werte vorhanden sind.
Testen der Formeln: Teste deine Formeln mit unterschiedlichen Eingabewerten, um sicherzustellen, dass sie robust sind und alle möglichen Fälle abdecken.
Verwendung von LOG für signifikante Stellen: Mit der LOG-Funktion kannst du die Anzahl der signifikanten Stellen bestimmen, die du in deinen Berechnungen verwenden möchtest.

FAQ: Häufige Fragen

1. Wie kann ich sicherstellen, dass Excel die Zahl immer auf 3 signifikante Stellen rundet?
Verwende die oben genannte Formel mit der RUNDEN-Funktion und passe das Format entsprechend an.

2. Kann ich diese Methoden in jeder Excel-Version verwenden?
Ja, die beschriebenen Formeln und Funktionen sind in den gängigen Excel-Versionen verfügbar, einschließlich Excel 2010 und neuer.

3. Was kann ich tun, wenn die Formel nicht funktioniert?
Überprüfe die Zellreferenzen und stelle sicher, dass die Eingabewerte korrekt sind. Manchmal kann auch das Zellenformat das Ergebnis beeinflussen.

Beliebteste Forumthreads (12 Monate)

Zahlen mit 3 relvanten Stellen anzeigen

Forumthread: Zahlen mit 3 relvanten Stellen anzeigen

8 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Infobox / Tutorial

Zahlen mit 3 relevanten Stellen in Excel anzeigen

Schritt-für-Schritt-Anleitung

Häufige Fehler und Lösungen

Alternative Methoden

Praktische Beispiele

Tipps für Profis

FAQ: Häufige Fragen

Beliebteste Forumthreads (12 Monate)

8
Beiträge zum Forumthread

Beiträge zu diesem Forumthread