Formel verkürzen

Forumthread: Formel verkürzen

Formel verkürzen

Jochen

Hallo und guteb Abend,
gibt es eine Möglichkeit diese Formel zu verkürzen?:
=ZÄHLENWENN($B7:$AF7;"BOFD")*7,5+ZÄHLENWENN($B7:$AF7;"BWFD")*7,5+ZÄHLENWENN($B7:$AF7;"BMFD") *7,5+ZÄHLENWENN($B7:$AF7;"BOSD")*7,5+ZÄHLENWENN($B7:$AF7;"BMSD")*7,5+ZÄHLENWENN($B7:$AF7;"BWSD") *7,5+ZÄHLENWENN($B7:$AF7;"SD14")*7,5+ZÄHLENWENN($B7:$AF7;"ND18")*9+ZÄHLENWENN($B7:$AF7;"BMF") *6+ZÄHLENWENN($B7:$AF7;"BOF")*6+ZÄHLENWENN($B7:$AF7;"BWF")*6+ZÄHLENWENN($B7:$AF7;"FD15") *7,5+ZÄHLENWENN($B7:$AF7;"ND15")*9+ZÄHLENWENN($B7:$AF7;"FS90")*8+ZÄHLENWENN($B7:$AF7;"ÜA") *-8+ZÄHLENWENN($B7:$AF7;"FS22")*8+ZÄHLENWENN($B7:$AF7;"FS17")*8+ZÄHLENWENN($B7:$AF7;"GL72") *8+ZÄHLENWENN($B7:$AF7;"GLBE")*8+ZÄHLENWENN($B7:$AF7;"FS")*8+ZÄHLENWENN($B7:$AF7;"FD31") *7,5+ZÄHLENWENN($B7:$AF7;"SD31")*7,5+ZÄHLENWENN($B7:$AF7;"FD06")*7,5+ZÄHLENWENN($B7:$AF7;"EMS") *8
Danke und Gruß
Jochen

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Benutzer

Formel verkürzen: logo

31.12.2010 01:36:29

Hi,
=SUMME(ZÄHLENWENN($B7:$AF7;{"BOFD";"BWFD";"BMFD"}))
usw.
Salut WF

Na, das wird wohl nicht reichen,...

31.12.2010 02:03:24

Luc:-?

…Walter… ;->
GRutsch!
Luc :-?

logo - das ist der erste angefangene Block

31.12.2010 09:54:04

Hi,
... den man mit 7,5 multipliziert. Addiert werden dann die weiteren Blöcke multipliziert mit 8 etc.
WF

...oder doch gleich so wie bei mir?! ;-) owT

31.12.2010 12:05:58

Luc:-?

:-?

ich schreib doch nicht 22 Zahlen, wenn ...

31.12.2010 12:23:08

5 genügen.

Du hattest aber gar keine geschrieben,...

31.12.2010 12:27:09

Luc:-?

…Walter,
außerdem sind's 24… ;->
GRutsch, aber nicht wieder mit blauem Auge und kaputter Brille… ;-)
Gruß Luc :-?

Wohl nicht, aber mit 'ner Rahmenfunktion...

31.12.2010 02:01:27

Luc:-?

…und 2 Matrixkonstanten doch, Jochen… ;-)
=SUMMENPRODUKT(ZÄHLENWENN($B7:$AF7;{"BOFD"."BWFD"."BMFD"."BOSD"."BMSD"."BWSD"."SD14".
"ND18"."BMF"."BOF"."BWF"."FD15"."ND15"."FS90"."ÜA"."FS22"."FS17"."GL72"."GLBE"."FS"."FD31"."SD31".
"FD06"."EMS"});{7,5.7,5.7,5.7,5.7,5.7,5.7,5.9.6.6.6.7,5.9.8.-8.8.8.8.8.8.7,5.7,5.7,5.8})
Noch kürzer geht's, wenn du beide Matrixkonstanten in Hilfszellen speicherst oder benennst und dann auf die Bereiche oder Namen verweist…
$IU$1:$IU$24⇒VglTexte BOFD…EMS — $IV$1:$IV$24⇒Faktoren 7,5…8
=SUMMENPRODUKT(ZÄHLENWENN($B7:$AF7;$IU$1:$IU$24);$IV$1:$IV$24) bzw…
=SUMMENPRODUKT(ZÄHLENWENN($B7:$AF7;VglText);Faktor) für…
VglText={"BOFD"."BWFD"."BMFD"."BOSD"."BMSD"."BWSD"."SD14"."ND18"."BMF"."BOF".
"BWF"."FD15"."ND15"."FS90"."ÜA"."FS22"."FS17"."GL72"."GLBE"."FS"."FD31"."SD31"."FD06"."EMS"}
Faktor={7,5.7,5.7,5.7,5.7,5.7,5.7,5.9.6.6.6.7,5.9.8.-8.8.8.8.8.8.7,5.7,5.7,5.8}
Empfehle allerdings, die Faktoren nach Wert zu ordnen und danach dann die Reihenfolge der VglTexte festzulegen.
GRutsch, Luc :-?

AW: Formel verkürzen

31.12.2010 13:36:01

Josef

Hallo Jochen,
hier die Formeln nach Walters Vorschlag.
Tabelle1

	D
5	0

Formeln der Tabelle

Zelle	Formel
D5	=ZÄHLENWENN($B7:$AF7;"ÜA")-8+SUMME(ZÄHLENWENN($B7:$AF7;{"BMF";"BOF";"BWF"}))6+SUMME(ZÄHLENWENN($B7:$AF7;{"BOFD";"BWFD";"BMFD";"BOSD";"BMSD";"BWSD";"SD14";"FD15";"FD31";"SD31";"FD06"}))7,5+SUMME(ZÄHLENWENN($B7:$AF7;{"FS90";"FS22";"FS17";"GL72";"GLBE";"FS";"EMS"}))8+SUMME(ZÄHLENWENN($B7:$AF7;{"ND18";"ND15"}))*9

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4

Gruß Sepp

oder als Matrixformel natürlich.

31.12.2010 14:37:19

Josef

Hallo Jochen,
oder so.

Tabelle1

	A	B	C	D	E
5			8	8
6
7		ÜA		FS	EMS
8
9	ÜA	-8
10	BMF	6
11	BOF	6
12	BWF	6
13	BOFD	7,5
14	BWFD	7,5
15	BMFD	7,5
16	BOSD	7,5
17	BMSD	7,5
18	BWSD	7,5
19	SD14	7,5
20	FD15	7,5
21	FD31	7,5
22	SD31	7,5
23	FD06	7,5
24	FS90	8
25	FS22	8
26	FS17	8
27	GL72	8
28	GLBE	8
29	FS	8
30	EMS	8
31	ND18	9
32	ND15	9
33

Formeln der Tabelle

Zelle	Formel
C5	{=SUMME(WENN(B7:AF7=A9:A32;B9:B32))}
D5	{=SUMME(WENN(B7:AF7={"ÜA";"BMF";"BOF";"BWF";"BOFD";"BWFD";"BMFD";"BOSD";"BMSD";"BWSD";"SD14";"FD15";"FD31";"SD31";"FD06";"FS90";"FS22";"FS17";"GL72";"GLBE";"FS";"EMS";"ND18";"ND15"};{-8;6;6;6;7,5;7,5;7,5;7,5;7,5;7,5;7,5;7,5;7,5;7,5;7,5;8;8;8;8;8;8;8;9;9}))}

Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Matrix verstehen

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4

Gruß Sepp

...und was ist daran nun besser als bei...

31.12.2010 15:22:59

Luc:-?

…meinem Vorschlag, Sepp;
den hast du offensichtl gar nicht angesehen… :-/
GRutsch!
Luc :-?

happy hour?

31.12.2010 16:15:40

silex1

Hallo,
würd auch so funktionieren mE.
=SUMME(ZÄHLENWENN($B7:$AF7;{"FD?"."SD?"."B?FD"})*7,5)+ZÄHLENWENN($B7:$AF7;"B?F") *6+ZÄHLENWENN($B7:$AF7;"ND?")*9+ZÄHLENWENN($B7:$AF7;"ÜA") *-8
VG, Rene

Wenn nicht noch Ähnliches, nicht Betroffenes...

01.01.2011 12:03:47

Luc:-?

…existiert, René… ;-)
Ansonsten prima, dass du da Ordnung reinbringen konntest.
Alles Gute im Neuen!
Gruß Luc :-?

Beliebteste Forumthreads (12 Monate)

Forumthread: Formel verkürzen

12 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

12
Beiträge zum Forumthread

Beiträge zu diesem Forumthread