AW: in Abhängigkeit des Datums kopieren!
16.04.2012 23:38:16
fcs
Hallo Snewi,
ich hoffe ich hab es richtig verstanden.
Da ein Formelansatz hier nicht funktioniert bzw. sehr kompliziert wird hier eine Makro-Lösung
Gruß
Franz
Sub DatenSammeln()
Dim wksZiel As Worksheet
Dim wksData As Worksheet
Dim Zeile_Z As Long, Spalte_Z As Long
Dim varMonat As Variant
Dim varZeile As Variant
Dim Zelle As Range
Set wksZiel = Worksheets("Tabelle1")
'Altdaten im Zielblatt löschen
With wksZiel
Spalte_Z = .Cells(2, .Columns.Count).End(xlToLeft).Column
If Spalte_Z >= 3 Then
.Range(.Cells(3, 3), .Cells(14, Spalte_Z)).ClearContents
End If
End With
For Each wksData In ActiveWorkbook.Worksheets
Select Case wksData.Name
Case wksZiel.Name, "TabelleABC"
'Diese Tabellen nicht durchsuchen
Case Else
With wksZiel
For Zeile_Z = 3 To 14 'Zeilen mit den Monaten
varMonat = .Cells(Zeile_Z, 2).Value
If InStr(1, wksData.Range("H2").Text, varMonat) > 0 Then
For Spalte_Z = 3 To .Cells(2, .Columns.Count).End(xlToLeft).Column
varZeile = .Cells(2, Spalte_Z).Value
With wksData
Set Zelle = .UsedRange.Find(What:=varZeile, LookIn:=xlValues, lookat:=xlWhole) _
End With
If Not Zelle Is Nothing Then
.Cells(Zeile_Z, Spalte_Z).Value = Zelle.Offset(1, 0).Value
End If
Next Spalte_Z
End If
Next Zeile_Z
End With
End Select
Next wksData
End Sub