Microsoft Excel

Herbers Excel/VBA-Archiv

Windows Taschenrechner einblenden | Herbers Excel-Forum


Betrifft: Windows Taschenrechner einblenden von: Thomas
Geschrieben am: 06.08.2012 18:09:29

Hallo liebes Forum,

ich verwende folgendes Mini-Makro, um den Windows-Taschenrechner einzublenden.

Leider erscheint der standardmäßig immer links oben.
Gibt es hier auch die Möglichkeit, eine andere Position vorzugeben ? Z.B in der Mitte des Bildschirms ?

Sub Calculator()
Dim Explorer As Integer
Explorer = Shell("calc.exe", 1)
End Sub
VG und vielen Dank im Voraus,
Thomas

  

Betrifft: AW: Windows Taschenrechner einblenden von: Josef Ehrensberger
Geschrieben am: 06.08.2012 18:40:22


Hallo Thomas,

probier mal, ob das reicht.

' **********************************************************************
' Modul: Modul1 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Private Declare Function SetWindowPos Lib "user32" (ByVal _
  hWnd As Long, ByVal hWndInsertAfter As Long, _
  ByVal x As Long, ByVal y As Long, ByVal cx As Long, _
  ByVal cy As Long, ByVal wFlags As Long) As Long

Private Declare Function ShowWindow Lib "user32" (ByVal _
  hWnd As Long, ByVal nCmdShow As Long) As Long

Private Declare Function GetWindowRect Lib "user32" (ByVal _
  hWnd As Long, lpRect As RECT) As Long

Private Declare Function FindWindow Lib "user32" Alias _
  "FindWindowA" (ByVal lpClassName As String, ByVal _
  lpWindowName As String) As Long

Const SWP_NOMOVE = &H2
Const SWP_NOSIZE = &H1
Const HWND_TOPMOST = -1

Const SW_MAXIMIZE = 3
Const SW_MINIMIZE = 6
Const SW_RESTORE = 9

Private Type RECT
  Left As Long
  Top As Long
  Right As Long
  Bottom As Long
End Type

Sub showCalculator()
  Dim hWnd As Long, lngRet As Long
  
  lngRet = Shell("calc.exe", vbNormalFocus)
  
  hWnd = FindWindow(vbNullString, "Rechner")
  
  lngRet = SetWindowPos(hWnd, HWND_TOPMOST, Application.Left + Application.Width / 2, _
    Application.Top + Application.Height / 3, 0, 0, SWP_NOSIZE)
End Sub






« Gruß Sepp »



  

Betrifft: AW: Windows Taschenrechner einblenden von: Thomas
Geschrieben am: 06.08.2012 19:04:13

Hallo Sepp,

vielen Dank für die schnelle und tolle Antwort - das funktioniert super !! :-)

Ist mir eine große Hilfe !

Viele Grüße und einen schönen Abend noch,
Thomas


Beiträge aus den Excel-Beispielen zum Thema "Windows Taschenrechner einblenden"