Microsoft Excel

Herbers Excel/VBA-Archiv

Informationen und Beispiele zum Thema Label
BildScreenshot zu Label Label-Seite mit Beispielarbeitsmappe aufrufen

Trevi Chiara neu macht Probleme

Betrifft: Trevi Chiara neu macht Probleme von: Thomas
Geschrieben am: 21.11.2012 11:10:17

Hallo zusammen,

habe eine Pivottabelle mittels vba erstellen lassen. Besteht aus einem Seitenfeld, 2 Zeilenfelder (in Tabellenform formatiert, also nebeneinander), und ein Spaltenfeld (12 Monate). Funktioniert soweit ganz gut, allerdings scheitere ich an der speziellen Formatierung des Rahmens die ich möchte. Zur Erklärung im linken pivotfield (GZ) stehen Nummern rechts daneben (TÄTIGKEIT) kann es zu jeder Nummer mehrere Einträge geben. Teilergebnisse sind nicht aktiviert (möchte keine zusätzlichen Zeilen haben).

Wie muss der Code aussehen, wenn ich eine horizontale Linie oben und unten zu jeder Nummer (GZ) haben möchte. Achtung nicht nach jeder Zeile!

Direkt die einzelnen Nummern über eine Schleife mit pivotselect anzusprechen funktioniert nicht wie gewünscht, da er den Bereich der Tätigkeit dann nicht mitselektiert.

Hat jemend eine Idee?

Grüße Thomas

  

Betrifft: AW: Trevi Chiara neu macht Probleme von: fcs
Geschrieben am: 22.11.2012 07:14:08

Hallo Thomas,

nachfolgen ein Makro zur Formatierung von Pivotbericht-Zellbereichen erstellt unter Excel 2010.

Gruß
Franz

Sub Pivot_Formatieren()
  Dim pvTab As PivotTable, pvField As PivotField, pvItem As PivotItem
  Dim rngFormat As Range
  Dim wks As Worksheet
  Set wks = ActiveSheet 'Worksheets("TabName")
  Set pvTab = wks.PivotTables(1)
  Set pvField = pvTab.PivotFields("GZ")
  For Each pvItem In pvField.VisibleItems
    Set rngFormat = pvItem.LabelRange
    With wks
      Set rngFormat = .Range(rngFormat, rngFormat.Offset(0, 1)) 'Offset auf gewünschten Wert  _
setzen
      With rngFormat
        With .Borders(xlEdgeBottom)
          .LineStyle = xlContinuous
          .Weight = xlThin
        End With
        With .Borders(xlEdgeTop)
          .LineStyle = xlContinuous
          .Weight = xlThin
        End With
      End With
    End With
  Next pvItem
End Sub



  

Betrifft: AW: Trevi Chiara neu macht Probleme von: Thomas
Geschrieben am: 22.11.2012 08:05:05

Hallo Franz,

danke dass du trotz kryptischen Betreff geantwortet hast (da war was im Cache). Erstens funktioniert deine Lösung super, zweitens habe ich gelernt, das man auch bei Pivottabellen nicht selektieren muss um eine Formatierung durchzuführen. Also zweifachen Dank!

Grüße Thomas