Benutzerdefinierte Symbolleiste



Excel-Version: 10.0 (Office XP)
nach unten

Betrifft: Benutzerdefinierte Symbolleiste
von: Nowack
Geschrieben am: 12.06.2002 - 13:43:03

Hallo,
Ich habe an eine Arbeitsmappe eine Symbolleiste "angehangen", die Mappe wird aber in verschiedenen Laufwerken, Ordnern,... liegen. Wie kann ich realisieren, dass die Pfadangabe beim Aufruf der Makros über die Symbolleiste unterdrückt wird!!!
Danke

nach oben   nach unten

Re: Benutzerdefinierte Symbolleiste
von: Hajo
Geschrieben am: 12.06.2002 - 13:55:40

Hallo Nowack

ich realiesiere solche Sachen immer dadurch das die Symbolleiste durch die Datei erzeugt wird. Falls Bedarf Poste ich den Code nochmal.

Gruß Hajo


nach oben   nach unten

Bitte im Fotum bleiben
von: Hajo
Geschrieben am: 12.06.2002 - 14:27:31

Hallo Nowack


ein wenig Selbstvertrauen.
in VBA in DieseArbeitsmappe den Code, hinter OnAction steht das Makro das in einem Modul sein kann.


Private Sub Workbook_Open()
    Dim cb As CommandBar
    Dim CBC As CommandBarButton
    Dim I%
    On Error Resume Next
    Set cb = Application.CommandBars.Add(Name:="Preisliste1", _
        temporary:=True, Position:=msoBarTop)
    On Error GoTo 0
    If Application.CommandBars("Preisliste1").Visible = False Then
        cb.Visible = True
        For I = 1 To 15
            Set CBC = cb.Controls.Add(Type:=msoControlButton)
            With CBC
                .Width = 50                 ' Breite der Schalter
                .Style = msoButtonCaption   ' Text auf Schaltfläche
                Select Case I
                    Case 1
                        .Caption = "IRB"
                        .OnAction = "Roboter"
                        .TooltipText = "Roboter einfügen"
                    Case 2
                        .Caption = "Ent."
                        .OnAction = "Entlader"
                        .TooltipText = "Entlader einfügen"
                    Case 3
                        .Caption = "LPM"
                        .OnAction = "LPM"
                        .TooltipText = "LPM einfügen"
                    Case 4
                        .Caption = "Bel."
                        .OnAction = "Belader"
                        .TooltipText = "Belader einfügen"
                    Case 5
                        .Caption = "PTS"
                        .OnAction = "PTS"
                        .TooltipText = "PTS Einfügen"
                    Case 6
                        .Caption = "KTS"
                        .OnAction = "Gebindetransport"
                        .TooltipText = "Gebindetransport einfügen"
                    Case 7
                        .Caption = "S.S."
                        .OnAction = "SS"
                        .TooltipText = "Schalt- und Steuerausrüstung einfügen"
                    Case 8
                        .Caption = "Aus."
                        .OnAction = "Auspacker"
                        .TooltipText = "Auspacker einfügen"
                    Case 9
                        .Caption = "Ein."
                        .OnAction = "Einpacker"
                        .TooltipText = "Einpacker einfügen"
                    Case 10
                        .Caption = "ET60.1"
                        .OnAction = "ET601"
                        .TooltipText = "ET 60.1 einfügen"
                    Case 11
                        .Caption = "ET 85"
'                        .OnAction = "ET85"
'                        .TooltipText = "ET 85 einfügen"
                        .Enabled = False
                    Case 12
                        .Caption = "Kopfpa."
                        .OnAction = "Kopfpalette"
                        .TooltipText = "Kopfpalettenaufleger einfügen"
                    Case 13
                        .Caption = "NGA"
                        .OnAction = "NGA"
                        .TooltipText = "Neuglasabheber einfügen"
                    Case 14
                        .Caption = "NGS"
                        .OnAction = "NGS"
                        .TooltipText = "Neuglasabschieber einfügen"
                    Case 15
                        .Caption = "Zu."
                        .OnAction = "Zukauf"
                        .TooltipText = "Zukauf einfügen"
                End Select
            End With
        Next I
    End If
End Sub

Private Sub Workbook_Deactivate()
'    Schaltflächen nich auswählbar bei Blattwechsel
'    With Application.CommandBars("Preisliste1")
'        For I = 1 To 15
'            .Controls(I).Enabled = False
'        Next I
'    End With
    On Error Resume Next
    If Application.CommandBars("Preisliste1").Visible = True Then
        Application.CommandBars("Preisliste1").Visible = False
    End If
End Sub

Private Sub Workbook_Activate()
    On Error GoTo neu
    If Application.CommandBars("Preisliste1").Visible = False Then
        Application.CommandBars("Preisliste1").Visible = True
    End If
    Exit Sub
neu:
    Workbook_Open
End Sub

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    On Error Resume Next
    Application.CommandBars("Preisliste1").Delete
End Sub

Private Sub Workbook_SheetSelectionChange(ByVal Sh As Object, ByVal Target As Excel.Range)
    On Error GoTo neu
    If Application.CommandBars("Preisliste1").Visible = False Then
        Application.CommandBars("Preisliste1").Visible = True
    End If
    Exit Sub
neu:
    Workbook_Open
End Sub

Gruß Hajo

nach oben   nach unten

Re: Bitte im Fotum bleiben
von: Nowack
Geschrieben am: 14.06.2002 - 06:36:26

D a n k e!
hat mir sehr geholfen!

 nach oben

Beiträge aus den Excel-Beispielen zum Thema "Benutzerdefinierte Symbolleiste"