doppelte daten verhindern

Informationen und Beispiele zu den hier genannten Dialog-Elementen:
MsgBox


Excel-Version: 9.0 (Office 2000)
nach unten

Betrifft: doppelte daten verhindern
von: Harry
Geschrieben am: 13.06.2002 - 21:39:14

Hallo
Habe diese Frage am 11.06.02 schon einmal gestellt.

Ich glaube ich habe es ein bißchen blöd und kompliziert erklärt.

1) Es gibt 5 Spalten die pro Zeile ausgefüllt werden müssen.
2) Es sind ca. 800 Zeilen die schon ausgefüllt sind
3) wenn ich jetzt zB in Zeile 801 diese 5 Spalten ausfülle
dürfen diese 5 Werte nicht in einen der oberen Zeilen
vorhanden sein.
4) Sollte nur ein Wert in den 5 eingegebenen Spalten anderst sein
darf die Zeile sein.
Ich hoffe es ist jetzt einigermaßen veratändlich.

mfg

Harry


nach oben   nach unten

Re: doppelte daten verhindern
von: WernerB.
Geschrieben am: 13.06.2002 - 22:18:15

Hallo Harry,

schreibe/kopiere das nachstehende Makro in das Klassenmodul des betreffenden Tabellenblattes.

- Mache dazu einen Rechtsklick auf den Tabellennamen.
- Klicke dann auf "Code anzeigen".
- Automatisch öffnen sich nun der VB-Editor und das Klassenmodul des betreffenden Tabellenblattes.
- Schreibe/kopiere das nachstehende Makro in die große weiße Fläche auf der rechten Seite.
- Zurück zum "normalen" Excel geht's mit Alt + Q.
- Fertig.

Achtung: Die Zelle in der Spalte E immer als letzte ausfüllen, sonst wird das Makro "ausgetrickst"!


Option Explicit
Private Sub Worksheet_Change(ByVal Target As Excel.Range)
Dim w0 As String, w1 As String
Dim acR As Long, laR As Long, i As Long
    If Target.Column <> 5 Then Exit Sub
    acR = Target.Row
    w0 = Cells(acR, 1).Text & Cells(acR, 2).Text & Cells(acR, 3).Text & _
      Cells(acR, 4).Text & Cells(acR, 5).Text
    laR = Cells(Rows.Count, 1).End(xlUp).Row
    For i = 1 To laR - 1
      w1 = Cells(i, 1).Text & Cells(i, 2).Text & Cells(i, 3).Text & _
        Cells(i, 4).Text & Cells(i, 5).Text
      If w0 = w1 Then
        MsgBox "Übereinstimmung mit Zeile " & i & "." & Chr(10) & _
          "Aktueller Eintrag wird gelöscht !", vbExclamation, _
          "Hinweis für " & Application.UserName & ":"
          Range("A" & acR & ":E" & acR).ClearContents
        Exit For
      End If
    Next i
End Sub

Viel Erfolg wünscht
WernerB.
nach oben   nach unten

Re: doppelte daten verhindern
von: Harry
Geschrieben am: 13.06.2002 - 22:50:35


Perfekt !!

Danke

mfg

Harry


 nach oben

Beiträge aus den Excel-Beispielen zum Thema "doppelte daten verhindern"