Automatisierter Zahlungsplan

https://www.herber.de/bbs/user/84916.xlsx
Sehr geehrtes Forum,
ich versuche einen flexiblen Zahlungsplan mit Abschlusszahlungen zu entwickeln. Es fehlt mir ein Automatismus, den fertigen Zahlungsplan in einer Übersicht dazustellen.
Der Zahlungsplan hat folgende Optionen:
1. Ratenzahlungen mit festen monatlichen Raten
2. Laufzeit der Raten ist von 1 24 flexibel
3. Es erfolgt am Ende der Laufzeit immer eine Abschlusszahlung
Für die Berechnung des Zahlungsplans gibt es zwei Optionen:
Reiter Abschlusszahlung - Entwicklung eines Zahlungsplans mit einer vorgegebenen Abschlusszahlung und die monatliche Rate berechnet sich automatisch.
Reiter Mtl. Raten - Entwicklung eines Zahlungsplans mit einer vorgegebenen monatlichen Rate und die Abschlusszahlung berechnet sich automatisch.
Es wird entweder der Reiter Abschlusszahlungen genutzt oder der Reiter Mtl. Raten. Niemals beide gleichzeitig. Es dürfen/müssen nur die gelb markierten Felder ausgefüllt werden.
Die Reiter Stamm, Abschlusszahlung und Mtl. Raten sind soweit in Ordnung.
Ich versuche den Reiter Zahlungsplan für Abschlusszahlungen und für Ratenzahlungen zu automatisieren. Makros wären OK. Ich danke für jeden Hinweis.
Grüße
Nidal

Beitrag zum Forumthread

Beitrag zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Nidal,
eine Formel-Lösung ist schwierung umzuzusetzen, da die auszugebende Zeilenzahl variert.
Hier mein Vorschlag mit Makros.
Ganz automatisch geht es nicht, da das Makro ja wissen muss aus welchem Blatt die Daten entnommen werden sollen. Deshalb für jedes der Blätter ein Makro, dass die Daten dann an das Makro übergibt, dass den Zahlungsplan anpasst.
Fall noch nicht geschehen, dann blende über Menüband anpassen die "Entwicklungstools" ein. Kopiere die Makros im VBA-Editor in ein allgemeines Modul der Datei.
Erstelle auf jedem der beiden Blätter eine Schaltfläche aus den Formularelementen und ordne der Schaltfläche das entsprechende Makro zu.
Gruß
Franz

'Makros in einem allgemeinen Modul
Sub MonatlicheRate() 'dieses Makro einer Schaltfläche im Blatt "Mtl. Raten" zuordnen
Dim wks As Worksheet
Set wks = Worksheets("Mtl. Raten")
With wks
Call Zahlungsplan(Raten:=.Range("C6"), Monatszahlung:=.Range("D28"), _
Waehrung:=.Range("E28"), Abschlusszahlung:=.Range("D30"), _
Startdatum:=.Range("D36"))
End With
End Sub
Sub Abschlusszahlung() 'dieses Makro einer Schaltfläche im Blatt "Abschlusszahlung" zuordnen
Dim wks As Worksheet
Set wks = Worksheets("Abschlusszahlung")
With wks
Call Zahlungsplan(Raten:=.Range("C6"), Monatszahlung:=.Range("D28"), _
Waehrung:=.Range("E28"), Abschlusszahlung:=.Range("D30"), _
Startdatum:=.Range("D36"))
End With
End Sub
Private Sub Zahlungsplan(Raten, Monatszahlung, Waehrung, Abschlusszahlung, Startdatum)
Dim Zeile As Long, ZeileLetzte As Long
Dim intMonat  As Integer
Dim wks As Worksheet
Set wks = Worksheets("Zahlungsplan")
Application.ScreenUpdating = False
With wks
ZeileLetzte = .Cells(.Rows.Count, 1).End(xlUp).Row
If ZeileLetzte > 7 Then
'löschen aller Zeilen außeer 1. Rate, Abschlusszahlung und Summe
.Range(.Rows(6), .Rows(ZeileLetzte - 2)).Delete
End If
Zeile = 4
For intMonat = 1 To Raten
Zeile = Zeile + 1
If intMonat > 1 Then
'Leerzeile für nächste rate einfügen
.Rows(Zeile).Insert
End If
.Cells(Zeile, 1) = intMonat
.Cells(Zeile, 2) = "Monatliche Rate"
.Cells(Zeile, 3) = Monatszahlung
.Cells(Zeile, 4) = Waehrung
.Cells(Zeile, 5) = DateSerial(Year:=Year(Startdatum), _
Month:=Month(Startdatum) + intMonat - 1, Day:=1)
Next
Zeile = Zeile + 1
.Cells(Zeile, 3) = Abschlusszahlung
.Cells(Zeile, 4) = Waehrung
.Cells(Zeile, 5) = DateSerial(Year:=Year(Startdatum), _
Month:=Month(Startdatum) + Raten, Day:=1)
.Activate
End With
Application.ScreenUpdating = True
End Sub

Beliebteste Forumthreads (12 Monate)

1 Beitrag zum Forumthread Beitrag zu diesem Forumthread

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

1
Beitrag zum Forumthread

Beitrag zu diesem Forumthread