Diagramm-Schutz aufheben: Wie?

Hallo allerseits,
Die Blätter in meiner Arbeitsmappe schütze ich so:
For i = 1 To Worksheets.Count
Worksheets(i).Protect password:=PWD, UserInterfaceOnly:=True
Next i
Das Programm kann dann auf die Zellen zugreifen, aber leider nicht auf die Charts; offenbar müssen diese auch mit der Option "UserInterfaceOnly" für den Zugriff des Programms freigegeben werden, ansonsten sind sie durch obige Anweisung ganz geschützt.
Soviel Info hab' ich im Netz gefunden, doch wie setze ich den entsprechenden Schutz eines Charts?
Dies hier scheint die entsprechende Methode zu sein, aber ich krieg' es nicht hin, auch nach langem Suchen und Versuchen: http://msdn.microsoft.com/en-us/library/office/bb211674%28v=office.12%29.aspx
Natürlich hab' ich auch schon versucht, den Blattschutz vor dem Chart Zugriff aus- und nachher wieder einzuschalten. Dies ist aber einerseits riskant und friert in meinem Falle das Programm für ca. 4 Sekunden ein.
Danke vielmal für eure Hilfe!
Tobias

Hallo Tobias,
soweit ich aus dem Text herauslesen konnte arbeitest du mit im Tabellenblatt eingebetteten Chart-Objekten.
Die Protect- und Unprotect-Methode beziehen sich aber auf Tabellen- oder Diagrammblätter. D.h. man kann den Schutz von eingebetteten Diagrammen nicht separat aufheben/einrichten.
Ich hab beim Testen festgestellt, dass man mit
Worksheets(i).Protect Password:=PWD, UserInterfaceOnly:=True
Einige Einstellungen in den Diagrammen ändern kann - z.B. die Füllfarbe von Datenreihen
Andere Einstellungen bleiben aber gesperrt - z.B. der Text des Diagrammtitels
Dir wird also nichts anderes übrigbleiben, als für die Blätter kurzzeitig während der Ausführung des Makros den Blattschutz zu deaktivieren.
Gruß
Franz
Code-Beispiel mit dem ich verschiedene Schutzeinstellungen probiert hab.


Option Explicit
Private Const PWD = "Test"
Sub Manipuliere()
Dim i, objPoint As Point
Dim objChart As Chart, wks As Worksheet
On Error GoTo Fehler
Application.EnableCancelKey = xlDisabled 'Makro kann nicht per ESC abgebrochen werden
Application.ScreenUpdating = False
'Blattschutz aufheben
For Each wks In ActiveWorkbook.Worksheets
wks.Unprotect Password:=PWD
Next wks
For Each objChart In ActiveWorkbook.Charts
objChart.Unprotect Password:=PWD
Next objChart
'Wertänderungen in Tabelle
For i = 2 To 5
Worksheets(1).Cells(i, 2) = Rnd() * 10
Next
'Anpassung am eingebetteten Diagrammobjekt
Set objChart = Worksheets(1).ChartObjects(1).Chart
With objChart
.ChartTitle.Text = "Werte Stand: " & Format(Now, "YYYY-MM-DD hh:mm")
For i = 1 To 4
Set objPoint = .SeriesCollection(1).Points(i)
objPoint.Format.Fill.ForeColor.RGB = RGB(Red:=Int(Rnd() * 254) + 1, _
Green:=Int(Rnd() * 254 + 1), blue:=Int(Rnd() * 254) + 1)
Next
End With
'Anpassung im Diagrammblatt
Set objChart = Charts(1)
With objChart
.ChartTitle.Text = "Werte Stand: " & Format(Now, "YYYY-MM-DD hh:mm")
For i = 1 To 4
Set objPoint = .SeriesCollection(1).Points(i)
objPoint.Format.Fill.ForeColor.RGB = RGB(Red:=Int(Rnd() * 254) + 1, _
Green:=Int(Rnd() * 254 + 1), blue:=Int(Rnd() * 254) + 1)
Next
End With
Err.Clear
Fehler: 'Fehlerbehandlung
With Err
Select Case .Number
Case 0 'Alles OK
Case Else
MsgBox "Fehler-Nr.: " & .Number & vbLf & .Description
End Select
End With
'Blattschutz wieder setzen
For Each wks In ActiveWorkbook.Worksheets
wks.Protect Password:=PWD, UserInterfaceOnly:=True
Next wks
For Each objChart In ActiveWorkbook.Charts
objChart.Protect Password:=PWD, UserInterfaceOnly:=True
Next objChart
Application.EnableCancelKey = xlInterrupt
Application.ScreenUpdating = True
End Sub

Forumthread: Diagramm-Schutz aufheben: Wie?

9
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Infobox / Tutorial

Diagramm-Schutz in Excel aufheben und verwalten

Schritt-für-Schritt-Anleitung

Häufige Fehler und Lösungen

Alternative Methoden

Praktische Beispiele

Tipps für Profis

FAQ: Häufige Fragen

Beliebteste Forumthreads (12 Monate)