Schleife für Fußzeile

Forumthread: Schleife für Fußzeile

28.01.2014 08:18:36

Albert

Guten Morgen zusammen,
ich verwende nachfolgenden Code um die Fußzeile in allen vorhandenen Sheet zu aktualisieren.

Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)
Dim WS_Count As Integer
Dim I As Integer
'Anzahl der Sheets ermitteln
WS_Count = ActiveWorkbook.Worksheets.Count
'Start der Schleife
For I = 1 To WS_Count
With Sheets("0.Cover")
.Range("AH1").Value = ActiveWorkbook.BuiltinDocumentProperties("Title").Value
.Range("AH2").NumberFormat = "@"
.Range("AH2").Value = (ActiveWorkbook.BuiltinDocumentProperties("Subject").Value & "." & _
ActiveWorkbook.BuiltinDocumentProperties("Keywords").Value)
End With
ActiveSheet.PageSetup.LeftFooter = "&""Arial Narrow""&8" & " "
ActiveSheet.PageSetup.CenterFooter = "&""Arial Narrow""&8" & " "
ActiveSheet.PageSetup.RightFooter = "&""Arial Narrow""&8" & " "
ActiveSheet.PageSetup.LeftFooter = "&""Arial Narrow""&8" & "Dokumenten Nr. / document no.:   _
Version / revision:" & Chr(10) & ActiveWorkbook.BuiltinDocumentProperties("Title") & "                                                           " & ActiveWorkbook.BuiltinDocumentProperties("Subject") & ActiveWorkbook.BuiltinDocumentProperties("Keywords")
ActiveSheet.PageSetup.CenterFooter = "&""Arial Narrow""&8" & "Datum / date:" & Chr(10) &  _
ActiveWorkbook.BuiltinDocumentProperties("Category")
ActiveSheet.PageSetup.RightFooter = "&""Arial Narrow""&8" & "Seite / page:" & Chr(10) & "&P" _
& " / " & "&N"
Next I
End Sub

Nun hab ich aber das Gefühl, dass die Seiten nicht wirklich nacheinander aktualisiert werden, sondern die Schleife nur auf einem Sheet aktualisiert.
Könnte mir bitte jemand weiterhelfen, um
ActiveSheet.PageSetup
global zu machen.
Danke schon mal vorab.
Gruß
A.

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Schleife für Fußzeile

28.01.2014 09:29:50

selli
Danke selli, das war das richtige...

28.01.2014 15:31:40

Albert
Codevorschlag

28.01.2014 10:41:31

Erich

AW: Schleife für Fußzeile

28.01.2014 09:29:50

selli

hallo albert,
ersetze ActiveSheet. durch Sheets(I).
gruß
selli

Danke selli, das war das richtige...

28.01.2014 15:31:40

Albert

Codevorschlag

28.01.2014 10:41:31

Erich

Hi Albert,
der Teil, der Blatt "0.Cover" bearbeitet, muss doch nicht x-mal in der Schleife laufen. 1 mal vorab dürfte reichen.
Hier mein Vorschlag:


Option Explicit
Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)
Dim I As Long
With Sheets("0.Cover")
.Range("AH1").Value = Me.BuiltinDocumentProperties("Title").Value
.Range("AH2").NumberFormat = "@"
.Range("AH2").Value = Me.BuiltinDocumentProperties("Subject").Value & _
"." & Me.BuiltinDocumentProperties("Keywords").Value
End With
For I = 1 To Me.Worksheets.Count ' Anzahl der Sheets, Start der Schleife
With Sheets(I).PageSetup
.LeftFooter = "&""Arial Narrow""&8" & " "
.CenterFooter = "&""Arial Narrow""&8" & " "
.RightFooter = "&""Arial Narrow""&8" & " "
.LeftFooter = "&""Arial Narrow""&8" & "Dokumenten Nr. / document no.:" & _
" Version / revision:" & Chr(10) & _
Me.BuiltinDocumentProperties("Title") & String(50, " ") & _
Me.BuiltinDocumentProperties("Subject") & _
Me.BuiltinDocumentProperties("Keywords")
.CenterFooter = "&""Arial Narrow""&8" & "Datum / date:" & _
Chr(10) & Me.BuiltinDocumentProperties("Category")
.RightFooter = "&""Arial Narrow""&8" & "Seite / page:" & _
Chr(10) & "&P" & " / " & "&N"
End With
Next I
End Sub

Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich

Beliebteste Forumthreads (12 Monate)

Forumthread: Schleife für Fußzeile

3 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread