Microsoft Excel

Herbers Excel/VBA-Archiv

Werte ausgeben ohne/ ungleich 0

Betrifft: Werte ausgeben ohne/ ungleich 0 von: Andreas
Geschrieben am: 13.11.2014 11:52:08

Guten Tag zusammen,

ich habe eine Frage, mit der herzlichen Bitte um Eure Hilfe:

In 5 Spalten habe ich Zahlen (zw. 0 und 100) nun möchte ich in den nächsten 5 Spalten gern die Zahlen größer 0 in der gleichen Reihenfolge ausgeben. Bsp.

A B C D E - F G H I J
2 0 0 9 7 - 2 9 7

geht das irgendwie?

Ich danke sehr!

Andreas

  

Betrifft: mit einer Matrixformel ... von: neopa C (paneo)
Geschrieben am: 13.11.2014 11:58:24

Hallo Andreas,

... so:

 ABCDEFGHI
120097297 

Formeln der Tabelle
ZelleFormel
F1{=WENNFEHLER(INDEX(1:1;KKLEINSTE(WENN($A1:$E1<>0;SPALTE($A1:$E1)); SPALTE(A1))); "")}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4


Gruß Werner
.. , - ...


  

Betrifft: AW: Werte ausgeben ohne/ ungleich 0 von: Hajo_Zi
Geschrieben am: 13.11.2014 11:59:25

Hallo Andreas,


Tabelle4

 ABCDEFGHIJK
2820097279   

verwendete Formeln
Zelle Formel Bereich N/A
F28{=MIN(WENN(A28:E28>0;A28:E28))}$F$28 
G28:K28{=WENN(ODER(F28="";MIN(WENN($A$28:$E$28>F28;$A$28:$E$28))<F28);"";MIN(WENN($A$28:$E$28>F28;$A$28:$E$28)))}$G$28 
{} Matrixformel mit Strg+Umschalt+Enter abschließen
Matrixformeln sind durch geschweifte Klammern {} eingeschlossen
Diese Klammern nicht eingeben!!

Excel-Inn.de
Hajo-Excel.de
XHTML-Tabelle zur Darstellung in Foren, einschl. der neuen Funktionen ab Version 2007
Add-In-Version 18.20 einschl. 64 Bit



GrußformelHomepage


  

Betrifft: Thema verfehlt! von: Rudi Maintaire
Geschrieben am: 13.11.2014 12:47:57

Hallo,
die Zahlen größer 0 in der gleichen Reihenfolge ausgeben

Gruß
Rudi


  

Betrifft: AW: Werte ausgeben ohne/ ungleich 0 von: Rudi Maintaire
Geschrieben am: 13.11.2014 12:02:48

Hallo,

ABCDEFGHIJ
220097297  

ZelleFormel
F2{=WENNFEHLER(INDEX($A2:$E2;KKLEINSTE(WENN($A2:$E2<>0;SPALTE($A:$E);"");SPALTE(A1)));"")}
G2{=WENNFEHLER(INDEX($A2:$E2;KKLEINSTE(WENN($A2:$E2<>0;SPALTE($A:$E);"");SPALTE(B1)));"")}
H2{=WENNFEHLER(INDEX($A2:$E2;KKLEINSTE(WENN($A2:$E2<>0;SPALTE($A:$E);"");SPALTE(C1)));"")}
I2{=WENNFEHLER(INDEX($A2:$E2;KKLEINSTE(WENN($A2:$E2<>0;SPALTE($A:$E);"");SPALTE(D1)));"")}
J2{=WENNFEHLER(INDEX($A2:$E2;KKLEINSTE(WENN($A2:$E2<>0;SPALTE($A:$E);"");SPALTE(E1)));"")}
Achtung, Matrixformel!
Die geschweiften Klammern{} nicht eingeben,
sondern die Zelle mit
Shift + Strg + Enter
verlassen statt Enter alleine.


Gruß
Rudi


  

Betrifft: AW: Werte ausgeben ohne/ ungleich 0 von: Andreas
Geschrieben am: 13.11.2014 13:01:50

Hi Rudi Maintaire,
Danke für die Formel, dank auch an die Tipps von den anderen.

ich wollte es jetzt nach deinen Formeln umsetzten. Stehen die Werte tatsächlich in den Spalten A bis E bzw. Formeln in F bis J funktionierts prima. Sobald ich aber z.B. ne Spalte vor A einfüge (und sich die Bezüge sinnvollerweise mit ändern), dann erkennt er die beiden ersten Werte nicht mehr. Könntest du mir sagen, wie ich die Formeln anpasse.


  

Betrifft: Solche Aktionen sind für derartige Fmln ... von: Luc:-?
Geschrieben am: 13.11.2014 13:14:05

…tödlich und deshalb nicht vorgesehen, Andreas;
deine BlattStruktur sollte entweder schon feststehen oder man die Fml verstehen, den SPALTE(…) sind Zähler, die die jeweiligen Fktt benötigen und deshalb hier immer mit 1 anfangen müssen. Dir bleibt also in diesem Fall nichts anderes übrig als die Fml nachzukorri­gieren.
Gruß, Luc :-?

Besser informiert mit …


  

Betrifft: Vermeiden kannst du das wohl nur, wenn du ... von: Luc:-?
Geschrieben am: 13.11.2014 13:20:21

…partout nicht auf solche Aktionen verzichten kannst/willst, mit einem INDIREKT-Konstrukt für diese Fml-Teile, also SPALTE(INDIREKT("A:E")) bzw SPALTE(INDIREKT("A1")) usw.
Luc :-?


  

Betrifft: wie willst Du dass dann dynamisieren? ... von: neopa C (paneo)
Geschrieben am: 13.11.2014 13:37:33

Hallo Luc,

... ich hab es nicht weiter untersucht, weil INDIREKT() ;-) aber letztlich wird das wohl auf das gleiche Dilemma hinauslaufen. Oder?

Gruß Werner
.. , - ...


  

Betrifft: Wieso dynamisieren, ... von: Luc:-?
Geschrieben am: 13.11.2014 13:53:21

…Werner?
Das soll doch gerade verhindern, dass solches „dynamische“ RumGemurkse die Fml unbrauchbar macht…
Gruß, Luc :-?

Besser informiert mit …


  

Betrifft: würdest Du ... von: neopa C (paneo)
Geschrieben am: 13.11.2014 14:00:56

Hallo Luc,

... alle 5 Formeln einzeln schreiben wollen?


Gruß Werner
.. , - ...


  

Betrifft: Notfalls ja, aber das ist ja nicht wirklich ... von: Luc:-?
Geschrieben am: 13.11.2014 14:11:03

…erforderlich, Werner,
wenn man das 2.INDIREKT-Konstrukt durch SPALTEN($A:A) ersetzt.
Luc :-?


  

Betrifft: jetzt ungetestet ... von: neopa C (paneo)
Geschrieben am: 13.11.2014 14:23:07

Hallo Luc,

... dann besteht aber wieder das gleiche Problem. Oder?


Gruß Werner
.. , - ...




  

Betrifft: Wieso, es kommt doch nur auf das Ergebnis an, ... von: Luc:-?
Geschrieben am: 13.11.2014 15:02:14

…Werner;
SPALTEN($A:A)⇒1⇐SPALTEN($B:B) ←nach Einfügen neuer Spalte A
Weiter gezogen in Spalte G dann:
SPALTEN($A:B)⇒2⇐SPALTEN($B:C) ←nach Einfügen neuer Spalte A
SPALTEN hat außerdem den Vorteil, dass das Ergebnis immer ein Skalar ist, während SPALTE stets einen Vektor liefert, der ggf aus nur einem Element besteht, wie man im FmlAssi deutlich erkennen kann. Manche Fktt bzw FmlSituationen reagieren darauf unerwartet…
Luc :-?


  

Betrifft: das stimmt natürlich ... von: neopa C (paneo)
Geschrieben am: 13.11.2014 15:52:30

Hallo Luc,

... ich war vorhin im Stress und konnte es mir - wie schon geschrieben nicht genauer ansehen.
Ich war auch noch zu sehr auf Dein INDIREKT()-Angebot fixiert, dass ja nun wirklich nicht notwendig ist.


Gruß Werner
.. , - ...


  

Betrifft: Das kommt dann davon... ;-) owT von: Luc:-?
Geschrieben am: 13.11.2014 18:05:49

:-?


  

Betrifft: AW: Werte ausgeben ohne/ ungleich 0 von: Rudi Maintaire
Geschrieben am: 13.11.2014 13:14:39

Hallo,
dann in G2: {=WENNFEHLER(INDEX($B2:$F2;KKLEINSTE(WENN($B2:$F2<>0;SPALTE($A:$E);"");SPALTE(A1)));"")}

Gruß
Rudi


  

Betrifft: AW: Werte ausgeben ohne/ ungleich 0 von: Andreas
Geschrieben am: 13.11.2014 14:41:23

Hallo Zusammen,

ja so klappts!! Spalte(...) muss angepasst, also eigentlich unverändert bleiben. Allen fleißigen Antwortenden vielen Dank. Fantastisch!

Andreas


  

Betrifft: dazu brauchst einen "Fixpunkt" bzw. -Spalte ... von: neopa C (paneo)
Geschrieben am: 13.11.2014 13:34:12

Hallo Andreas,

... wo Du sicher bist keine derartigen Einfügungen/Änderungen vorzunehmen. Hier zwei mögliche Varianten:

 ABCDEFGH
120097297
220097297

Formeln der Tabelle
ZelleFormel
F1{=WENNFEHLER(INDEX($A1:$E1;KKLEINSTE(WENN($A1:$E1<>0;{1.2.3.4.5}); SPALTE(CZ1)-SPALTE($CY1))); "")}
F2{=WENNFEHLER(INDEX($A2:$E2;KKLEINSTE(WENN($A2:$E2<>0;{1.2.3.4.5}); SPALTE(Tabelle2!A1))); "")}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4

Gruß Werner
.. , - ...


 

Beiträge aus den Excel-Beispielen zum Thema "Werte ausgeben ohne/ ungleich 0"