Microsoft Excel

Herbers Excel/VBA-Archiv

Bedingtes Suchen

Betrifft: Bedingtes Suchen von: Sibylle Weber
Geschrieben am: 20.11.2014 16:32:12

Hallo,

in Spalte A stehen Namen, die durchsucht werden sollen.
Steht an 2. Stelle eines Namens ein e oder ein a und an 3. Stelle des Namens ein i oder ein y, so soll neben dem gefundenen Namen in Spalte B eine 1 eingetragen werden.
Wie lässt sich dies mit einer Formel erreichen?

Dank im Voraus.

Gruß
Sibylle

  

Betrifft: mit VERGLEICH() des TEIL()s eines Namens ... von: neopa C (paneo)
Geschrieben am: 20.11.2014 16:40:40

Hallo Sybylle,

... =ISTZAHL(VERGLEICH(TEIL(A1;2;2);{"ai";"ay";"ei";"ey"}))+0

und Formel nach unten kopieren.

Gruß Werner
.. , - ...


  

Betrifft: sorry, da fehlte noch eine Semikolon ... von: neopa C (paneo)
Geschrieben am: 20.11.2014 16:43:52

Hallo,

... richtig natürlich so: =ISTZAHL(VERGLEICH(TEIL(A1;2;2);{"ai";"ay";"ei";"ey"};))+0

Gruß Werner
.. , - ...


  

Betrifft: AW: sorry, da fehlte noch eine Semikolon ... von: Claus
Geschrieben am: 20.11.2014 16:53:25

da finde ich aber meinen Vorschlag logischer, weil darin die gewünschten Bedingungen direkter ablesbar sind und somit auch besser angepasst werden können, falls sich mal was ändert. (und fehlerfrei war ich auch schneller... ;-)

=WENN(UND(ODER(TEIL(A1;2;1)="a";TEIL(A1;2;1)="e");ODER(TEIL(A1;3;1)="i";TEIL(A1;3;1)="y"));1;"")


  

Betrifft: nun darüber liässt sich trefflich streiten ... von: neopa C (paneo)
Geschrieben am: 20.11.2014 16:56:52

Hallo Claus,


... ich mag bloß darüber nicht streiten ;-)


Gruß Werner
.. , - ...


  

Betrifft: AW: nun darüber liässt sich trefflich streiten ... von: Claus
Geschrieben am: 20.11.2014 17:04:16

Hallo Werner,

streiten möchte ich auch nicht, nur noch eine kurze Anmerkung dazu:

Wenn jemand eine solche Frage stellt, kennt sie / er sich wahrscheinlich wenig mit entsprechenden Excelformeln aus. (So geht es z. B. mir immer, und ich versuche dann wenigstens die Formel zu verstehen damit ich in einem ähnlichen Fall selber die Lösung finden kann) Deshalb erscheint es mir sinnvoller, eine Formel zu verwenden die möglichst exakt und gut erkennbar die genannten Bedingungen abbildet, auch wenn es eine kürzere Formel gibt.

Kann aber auch sein, dass ich das nur behaupte weil gar keine andere (kürzere) Möglichkeit zustande gebracht hätte. ;-)

Grüßle Claus


  

Betrifft: AW: Bedingtes Suchen von: Claus
Geschrieben am: 20.11.2014 16:41:37

Hallo Sibylle,

das hört sich ja stark danach an, als ob es bei euch divers unterschiedlich geschriebene Maiers gäbe.

Formel in B1:
=WENN(UND(ODER(TEIL(A1;2;1)="a";TEIL(A1;2;1)="e");ODER(TEIL(A1;3;1)="i";TEIL(A1;3;1)="y"));1;"")

Liebe Grüße
Claus


  

Betrifft: mit Zählenwenn von: Tino
Geschrieben am: 20.11.2014 16:56:33

Hallo,
meinst Du so?

 ABCDE
1aetest0 eaiy
2atest0   
3aeyla1   
4blabla0   

Formeln der Tabelle
ZelleFormel
B1=(ZÄHLENWENN($D$1;"*"&TEIL($A1;2;1)&"*")+ZÄHLENWENN($E$1;"*"&TEIL($A1;3;1)&"*")>1)*1
B2=(ZÄHLENWENN($D$1;"*"&TEIL($A2;2;1)&"*")+ZÄHLENWENN($E$1;"*"&TEIL($A2;3;1)&"*")>1)*1
B3=(ZÄHLENWENN($D$1;"*"&TEIL($A3;2;1)&"*")+ZÄHLENWENN($E$1;"*"&TEIL($A3;3;1)&"*")>1)*1
B4=(ZÄHLENWENN($D$1;"*"&TEIL($A4;2;1)&"*")+ZÄHLENWENN($E$1;"*"&TEIL($A4;3;1)&"*")>1)*1


Gruß Tino


  

Betrifft: wenn nur 1 oder nix ... von: Tino
Geschrieben am: 20.11.2014 18:44:56

Hallo,
müsste dies in eine Wennfunktion eingebaut werden.

=WENN(ZÄHLENWENN($D$1;"*"&TEIL($A1;2;1)&"*")+ZÄHLENWENN($E$1;"*"&TEIL($A1;3;1)&"*")>1;1;"")
Gruß Tino


  

Betrifft: Danke schön für alle Beiträge von: Sibylle Weber
Geschrieben am: 21.11.2014 09:43:07

Guten Morgen,

Besten Dank für alle Beiträge, die veröffentlicht wurden.
Die Aufgabe ist damit gelöst. Danke.

Gruß
Sibylle


 

Beiträge aus den Excel-Beispielen zum Thema "Bedingtes Suchen"