Zellen überprüfen dann Entscheidung Msg Box

Informationen und Beispiele zu den hier genannten Dialog-Elementen:
MsgBox
Bild

Betrifft: Zellen überprüfen dann Entscheidung Msg Box
von: Rita
Geschrieben am: 06.07.2015 13:22:11

Hallo zusammen,
ich hätte eine Frage und würde mich sehr freuen wenn mir jmd. helfen könnte.
Ich war schon auf der suche nach einer ähnlichen Lösung im Netz, habe jedoch nichts gefunden oder bin einfach in VBA noch nicht soweit ähnliche Bsp. richtig für mein Bsp. zu übersetzen.
Mein Problem:
Ich habe eine Liste mit Spalten E+F+G in denen es sein kann, dass in manchen Zellen ein "#" Zeichen steht.
Bevor mein Programm abläuft würde ich gerne prüfen ob in dem o.g. Range "#" vorhanden
sind und dann in einer Msgbox entscheiden lasse:
1)sind keine # vorhanden Nachricht "alles ok"
2) wenn # in einer/mehreren Zelle(n) vorhanden:
Entscheidungsmöglichkeit (per button):
ganze Zeile löschen -> dann löscht er die Zeilen in denen ein # vorh. ist
oder:
egal wenn # vorhanden -> nachfolgendes Programm starten.
Das wäre der Hammer, wenn mir hierbei jemand helfen könnte.
Vielen Dank bereits im voraus
Liebe Grüße
Rita

Bild

Betrifft: AW: Zellen überprüfen dann Entscheidung Msg Box
von: ransi
Geschrieben am: 06.07.2015 14:24:55
Hallo Rita,
Teste mal dies :

' **********************************************************************
' Modul: Tabelle1 Typ: Element der Mappe(Sheet, Workbook, ...)
' **********************************************************************

Dim rnggesamt As Range

Option Explicit

Sub machs()
    Dim strBegriff As String
    Dim rngSuch As Range
    Dim rngGefunden As Range
    Dim firstAddress
    strBegriff = "#"
    Set rnggesamt = Nothing
    Set rngSuch = Sheets("Tabelle1").Range("E:G") 'Ich habe eine Liste mit Spalten E+F+G
    With rngSuch
        Set rngGefunden = .Find(strBegriff, , xlValues, xlPart) 'Bevor mein Programm abläuft würde ich gerne prüfen ob in dem o.g. Range "#" vorhanden
        If Not rngGefunden Is Nothing Then '2) wenn # in einer/mehreren Zelle(n) vorhanden:
            firstAddress = rngGefunden.Address
            Set rnggesamt = .Rows(rngGefunden.Row)
            Do
                Set rnggesamt = Union(rnggesamt, Rows(rngGefunden.Row))
                Set rngGefunden = .FindNext(rngGefunden)
            Loop While Not rngGefunden Is Nothing And rngGefunden.Address <> firstAddress
            If MsgBox("Hab was gefunden. Soll ich Löschen ?", vbYesNo) = vbYes Then Call Bereich_Loeschen 'Entscheidungsmöglichkeit (per button)
            Else:
            MsgBox "Nix gefunden. Mach was Anderes" '1)sind keine # vorhanden Nachricht "alles ok"
        End If
    End With
End Sub


Sub Bereich_Loeschen()
    If rnggesamt Is Nothing Then Exit Sub
    rnggesamt.Delete
    Set rnggesamt = Nothing
End Sub


ransi

Bild

Betrifft: AW: Zellen überprüfen dann Entscheidung Msg Box
von: Rita
Geschrieben am: 07.07.2015 08:12:25
Hallo ransi,
du bist der Hammer !
Ich konnte den Code genauso so übernehmen - er funktioniert super !
Vielen vielen Dank für deine Hilfe
Allerliebste Grüße
Rita

 Bild

Beiträge aus den Excel-Beispielen zum Thema "Zellen überprüfen dann Entscheidung Msg Box"