AGGREGAT-Frage

Bild

Betrifft: AGGREGAT-Frage
von: Herbert Grom
Geschrieben am: 11.08.2015 11:56:41

allo, evtl. hallo Werner, ;o)=)
mit dieser Formel

=WENNFEHLER(INDEX(Jahresdaten!$A$3:$A$1000;AGGREGAT(15;6;ZEILE(B$1:B$1040)/
(Jahresdaten!$F$3:$F$1000=$E$3)/(Jahresdaten!$G$3:$G$1000=$F$3);ZEILE(E1)));"")
kann ich alle vorhandenen Einträge auflisten, die den Bedingungen entsprechen.
Wie müsste diese Formel lauten, wenn ich dabei Duplikate vermeiden will?
Vielen Dank im Voraus.
Servus

Bild

Betrifft: AW: dazu noch VERGLEICH() einbeziehen ...
von: ... neopa C
Geschrieben am: 11.08.2015 13:04:58
Hallo Herbert,
... angenommen, Deine Auswertung erfolgt in Spalte C und über der ersten Formelzelle steht kein Wert aus
Jahresdaten!A$3:A$1000, dann folgende Formel:
=WENNFEHLER(INDEX(Jahresdaten!A:A;AGGREGAT(15;6;ZEILE(Z$3:Z$1000)/(Jahresdaten!F$3:F$1000=E$3)/(Jahresdaten!G$3:G$1000=F$3)/ISTNV(VERGLEICH(Jahresdaten!A$3:A$1000;C$4:C4;));1));"")
Wobei dies für den allgemeineren Fall von Textwerte in Jahresdaten!A$3:A$1000 gilt. Für Zahlenwerte geht es ohne INDEX(), wenn die Ausgabe sortiert erfolgen darf und nicht die ursprüngliche Reihenfolge beibehalten werden muss. Im letzteren Fall einfach wieder Formel wie vor.
oT: bei einem anderen als Dir, hätte ich sicherlich eine kleine Beispielarbeitsmappe eingefordert. Da hab ich jetzt wohl wieder was gut bei Dir ;-)

Gruß Werner
.. , - ...

Bild

Betrifft: AW: dazu noch VERGLEICH() einbeziehen ...
von: Herbert Grom
Geschrieben am: 11.08.2015 14:36:53
Hallo Werner,
leider funzt es noch nicht. Guckst Du bitte noch mal. Danke!
Als Dank dafür, habe ich Dir sogar eine AM hochgeladen! ;o)=)
https://www.herber.de/bbs/user/99491.xlsm
Servus

Bild

Betrifft: AW: Du hast die Formel nicht korrekt angepasst ...
von: ... neopa C
Geschrieben am: 11.08.2015 15:06:12
Hallo Herbert,
... richtig wäre in Deiner Tabelle:
=WENNFEHLER(INDEX(Jahresdaten!$A$3:$A$1000;AGGREGAT(15;6;ZEILE(A$3:A$1000) /(Jahresdaten!F$3:F$1000=D$3)/(Jahresdaten!G$3:G$1000=B$3)/ISTNV(VERGLEICH(Jahresdaten!A$3:A$1000; B$5:B5;));1));"")
wobei ich allerdings zugeben muss, dass ich hätte dazu schreiben sollen: ... wenn die Formel in C5 erstmals eingesetzt wird. Sorry.
Dafür kann ich Dir mitteilen, dass die Hilfsspalten Jahresdaten!F:G nicht nötig sind. Dazu muss die Formel nur entsprechend angepasst werden.
Gruß Werner
.. , - ...

Bild

Betrifft: AW: Du hast die Formel nicht korrekt angepasst ...
von: Herbert Grom
Geschrieben am: 11.08.2015 15:29:31
Hallo Werner,
mit Deiner neuen Formel bringt er mir nur jeden 2. Eintrag. Wie kommt das denn?
Servus

Bild

Betrifft: AW: wolltest mich wohl "austricksen"? ; -) ...
von: ... neopa C
Geschrieben am: 11.08.2015 15:54:53
Hallo Herbert,
... in meiner ersten Formel hatte ich richtig stehen: =WENNFEHLER(INDEX(Jahresdaten!A:A;AGGREGAT(...
Du hast dies wieder auf =WENNFEHLER(INDEX(Jahresdaten!$A$3:$A$1000;AGGREGAT(... geändert und ich hatte es vorhin nicht bemerkt.
Korrekt wäre bei Dir in B6 also nur:
=WENNFEHLER(INDEX(Jahresdaten!$A:$A;AGGREGAT(15;6;ZEILE(A$3:A$999)/(Jahresdaten!F$3:F$999=D$3)/(Jahresdaten!G$3:G$999=B$3)/ISTNV(VERGLEICH(Jahresdaten!A$3:A$999;B$5:B5;));1));"")
Gruß Werner
.. , - ...

Bild

Betrifft: AW: hier noch die Formel ohne die Hilfsspalten ...
von: ... neopa C
Geschrieben am: 11.08.2015 15:59:52
Hallo Herbert,
... in B5:
=WENNFEHLER(INDEX(Jahresdaten!$A:$A;AGGREGAT(15;6;ZEILE(A$3:A$999)/(JAHR(Jahresdaten!B$3:B$999)=D$3)/(MONAT(Jahresdaten!B$3:B$999)=B$3)/ISTNV(VERGLEICH(Jahresdaten!A$3:A$999;B$5:B5;));1));"")
Gruß Werner
.. , - ...

Bild

Betrifft: AW: hier noch die Formel ohne die Hilfsspalten ...
von: Herbert Grom
Geschrieben am: 11.08.2015 16:17:44
Hallo Werner,
ES KLAPPT!!!
vielen Dank für Deine Geduld. Aber kannst Du mir noch bitte kurz erklären, womit in dieser Formel die Duplikate verhindert werden?
Servus

Bild

Betrifft: AW: durch die Kombi ISTNV(VERGLEICH(...)) owT
von: ... neopa C
Geschrieben am: 11.08.2015 16:38:11
Gruß Werner
.. , - ...

Bild

Betrifft: AW: durch die Kombi ISTNV(VERGLEICH(...)) owT
von: Herbert Grom
Geschrieben am: 11.08.2015 16:51:01
Das war mir schon soweit klar, aber die Funktionsargumente kapier ich nicht.
"Suchkriterium" in der Spalte ist noch klar, aber wieso bewirkt die Angabe "Suchmatrix: B$5:B5"? das dadurch die doppelten Einträge gefiltert werden?
Fragen über Fragen! Kannst Du die Antwort mir bitte sagen! Ui, das reimt sich sogar! ;o)=)
Servus

Bild

Betrifft: AW: durch die Kombi ISTNV(VERGLEICH(...)) owT
von: ... neopa C
Geschrieben am: 11.08.2015 17:08:04
Hallo Herbert,
... die Suchmatrix beinhaltet die bereits gefundenen "Treffer" bzw. den ersten Wert ("Mitarbeiter") für den gelten muss, was ich bereits in meinem ersten Beitrag schrieb: "... und über der ersten Formelzelle steht kein Wert aus Jahresdaten!A$3:A$999"
Mit dem VERGLEICH()-Formel-Teil werden alle Werte aus Jahresdaten!A$3:A$999 gefunden, die schon in der Ergebnisliste vor der jeweiligen Formel stehen. Es interessieren allerdings zum Ergebnislisting nuist nutze ich halt ISTNV() die richtige Funktion.
Gruß Werner
.. , - ...

Bild

Betrifft: AW: hatte vergessen noch den Betreff zu ändern .
von: ... neopa C
Geschrieben am: 11.08.2015 17:12:09
Hallo Herbert,
... das tue ich sonst fast immer.
Das hat Vor- und wie alles auch Nachteile. Ich werde aber dabei bleiben immer den Betreff in meiner jeweiligen Antwort meinen Beitrag anzupassen.
Gruß Werner
.. , - ...

 Bild

Beiträge aus den Excel-Beispielen zum Thema "bedingte Formatierung: zwei Spalten vergleichen"