Normalverteilungstest

Bild

Betrifft: Normalverteilungstest
von: eric
Geschrieben am: 19.08.2015 16:47:48

Hallo Leute,
ich brauche verzweifelt Eure Hilfe bei der Umsetzung einer Formel. Seht Euch am besten die Bedingungen selbst an. Ich weiß wirklich nicht, wie ich das zusammenbringen soll, es müssen so viele Vergleiche eingebracht werden:
https://www.herber.de/bbs/user/99686.xlsx
Tausend Dank bereits jetzt!! Bis jetzt konnte mir hier immer geholfen werden, ich hoffe auch diesmal.
Sollte noch Erklärungsbedarf bestehen, meldet Euch gern!
Beste Grüße
Eric

Bild

Betrifft: AW: nachgefragt ...
von: ... neopa C
Geschrieben am: 19.08.2015 17:01:30
Hallo Eric,
... müssen alle Zwischenwerte interpoliert werden? Oder reicht es, wenn die Zuordnung entsprechend dem nächsten Wert oder aber dem nächsten unteren bzw. oberen Datenwert zugeordnet wird?
Welches Ergebnis müsste z.B. für C6 und C20 ausgewiesen werden und warum (dazu konkrete Angabe vornehmen, wie ich dies zuvor abgefragt habe).
Gruß Werner
.. , - ...

Bild

Betrifft: AW: nachgefragt ...
von: eric
Geschrieben am: 25.08.2015 10:36:23
Hallo Werner,
vielen Dank, dass Du Dich der Sache angenommen hast und bitte verzeihe mir, dass ich erst jetzt dazu komme, Dir zu antworten.
...also ich verstehe den David-Test für die Normalverteilung so, dass immer der nächstgelegene Wert der entscheidende ist (bei den Counts (n) ist es aber ggf. eher der kleinere Wert, um auf Nr. sicher zu gehen). Für Deine beiden angesprochenen Zellen habe ich das wie folgt ausgewertet:
C6 --> 6,2047 --> n = 100 --> 6,360 --> "zu 1% normalverteilt" in Zelle C6
C20 --> 2,7776 --> n = 25 --> 3,150 --> "zu 1% normalverteilt" in Zelle C20
Ich hoffe Du oder jemand anderes kann mir nun weiterhelfen, diese Zellen zu automatisieren. Bin auch den ganzen Tag vor dem PC heute und kann eventuelle Fragen beantworten.
Vielen vielen Dank

Bild

Betrifft: AW: mit geschachteltem AGGREGAT(), INDEX() und ...
von: ... neopa C
Geschrieben am: 25.08.2015 11:47:25
Hallo Eric,
... eine Reihe weiterer Funktionen kombiniert, wenn immer der nächst kleinere n-Wert und dazu der nächstgrößere Datenwert aus der Datentabelle maßgebend ist, dann folgende Formel in C6 (Formel ziehend nach unten kopieren):

 ABC
3Counts (n)GWSK
4   
5   
61456,20470895zu 1% normalverteilt
71455,8448565zu 5% normalverteilt
81455,30049036normalverteilt
9   
104126,19581843zu 5% normalverteilt
11   
12314,50945294normalverteilt

Formeln der Tabelle
ZelleFormel
C6=WENNFEHLER(SVERWEIS(INDEX(Tabelle2!$2:$2;AGGREGAT(15;6;SPALTE(B1:I1)/(AGGREGAT(15;6;Tabelle2!$B$3:$I$35/(ZEILE(A$3:A$35)=VERGLEICH(A6;Tabelle2!A:A)); SPALTE(A1:H1))>B6); 1)); Tabelle2!L:S;8;); "")


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruß Werner
.. , - ...

Bild

Betrifft: AW: mit geschachteltem AGGREGAT(), INDEX() und ...
von: eric
Geschrieben am: 25.08.2015 13:24:32
Hallo Werner,
das ist schon mal großartig!! Das hätte ich NIE im Leben hinbekommen und es funktioniert super.
Zwei kleine Anmerkungen (die miteinander zusammenhängen) habe ich dennoch:
-in Zelle C10 z.B. erwarte ich "zu 10% normalverteilt" (kommt mit deiner Formel gar nicht vor), weil
-ich bei der Entscheidung zwischen zwei Werten den näherliegenden Wert als Referenz benötige
... bekommst Du das hin??? Das wäre wirklich fantastisch!!
Beste Grüße und tausend Dank jetzt schon!
Eric

Bild

Betrifft: AW: dann wird die Auswertungsformel komplexer ...
von: ... neopa C
Geschrieben am: 25.08.2015 15:02:37
Hallo Eric,
... vorzumerken wäre aber auch noch folgendes:
In meinem ersten Formelvorschlag war bei der Festlegung des SVERWEIS()-Bereichsmatrix ein Definitionsfehler unterlaufen, so dass deshalb nie "zu 10% normalverteilt" als Ergebnis kommen konnte. Dies hab ich jetzt der Vollständigkeit halber in C6 korrigiert. In vorherigen wie dieser Formel hatte/habe ich auch die Prüfung der Extrembedingung aus L3:O3 nicht vorgenommen (im Beispiel nicht gegeben).
Letzteres hab ich nun jedoch in der neuen Formel in D6 zusätzlich ergänzt. Wegen der neuen zusätzlichen Bedingung ("...bei der Entscheidung zwischen zwei Werten den näher liegenden Wert als Referenz benötige...") hab ich diese nun als echte MATRIXformel angelegt.
Beachte, dass bei evtl. Rückfragen nach heute, Du einen neuen thread aufmachen müsstest und auf diesen hier verlinken (https://www.herber.de/forum/archiv/1440to1444/t1443187.htm), weil dieser thread höchstwahrscheinlich Morgen dann zwar noch lesbar aber deaktiviert (kein neuer Beitrag dazu mehr möglich) im Archiv gelandet ist.

 ABCD
3Counts (n)GWSKWSK
4    
5    
61456,20470895zu 1% normalverteiltzu 1% normalverteilt
71455,8448565zu 5% normalverteiltzu 5% normalverteilt
81455,30049036zu 10% normalverteiltzu 10% normalverteilt
9    
104126,19581843zu 5% normalverteiltzu 10% normalverteilt
11    
12314,50945294zu 10% normalverteiltzu 10% normalverteilt
13314,18442904zu 10% normalverteiltzu 10% normalverteilt
14316,42713696zu 0,1% normalverteiltzu 1% normalverteilt
15    
161818,20037336zu 0,1% normalverteiltzu 1% normalverteilt

Formeln der Tabelle
ZelleFormel
C6=WENNFEHLER(SVERWEIS(INDEX(Tabelle2!$2:$2;AGGREGAT(15;6;SPALTE(B1:I1)/(AGGREGAT(15;6;Tabelle2!$B$3:$I$35/(ZEILE(A$3:A$35)=VERGLEICH(A6;Tabelle2!A:A)); SPALTE(A1:H1))>B6); 1)); Tabelle2!L$4:S$7;8;); "")
D6{=WENNFEHLER(WENN((B6<=MIN(INDEX(Tabelle2!B:B;VERGLEICH(A6;Tabelle2!A:A)):INDEX(Tabelle2!I:I;VERGLEICH(A6;Tabelle2!A:A))))+(B6>=MAX(INDEX(Tabelle2!B:B;VERGLEICH(A6;Tabelle2!A:A)):INDEX(Tabelle2!I:I;VERGLEICH(A6;Tabelle2!A:A)))); Tabelle2!S$3;SVERWEIS(INDEX(Tabelle2!$2:$2;1+VERGLEICH(MIN(ABS(INDEX(Tabelle2!B:B;VERGLEICH(A6;Tabelle2!A:A)):INDEX(Tabelle2!I:I;VERGLEICH(A6;Tabelle2!A:A))-B6)); ABS(INDEX(Tabelle2!B:B;VERGLEICH(A6;Tabelle2!A:A)):INDEX(Tabelle2!I:I;VERGLEICH(A6;Tabelle2!A:A))-B6); )); Tabelle2!L$4:S$7;8;)); "")}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruß Werner
.. , - ...

Bild

Betrifft: AW: dann wird die Auswertungsformel komplexer ...
von: eric
Geschrieben am: 25.08.2015 15:26:50
Hallo Werner,
das ist echt genial. Ich steige bei der Formel zwar komplett aus und weiß auch nicht, wie man sich so etwas erarbeiten kann, aber es funktioniert. Es gibt lediglich ein kleines Missverständnis, ansonsten ist alles wirklich perfekt:
Wenn der Zellwert, wie z.B. in Tabelle 1 in B12 mit 4,5094, IRGENDWO in dem Intervall zwischen 3,590 und 4,700 (n=30) liegt, dann muss in D12 "normalverteilt" stehen.
Evtl. könnte man verstehen, dass die "Extrembedingung" hieße, nur wenn der Wert GENAU IN DER MITTE liegt.
Das ist das letzte kleine Detail!
Besten Gruß und danke auch für den Tipp mit dem Thread, dass hätte ich auch nicht geahnt.

Bild

Betrifft: AW: jetzt ist es auch für mich verständlicher ...
von: ... neopa C
Geschrieben am: 25.08.2015 15:48:04
Hallo Eric,
... was Du mit Deinen Bedingung in M3 und O3 genau meintest.
In dem Fall ist die notwendige Änderung der letzten Formel zwar kaum ins Auge fallend, aber doch für das gewünschte Ergebnis doch entscheidend und für mich auch eher nachvollziehbar.

 ABE
3Counts (n)GWSK
4   
5   
61456,20470895zu 1% normalverteilt
71455,8448565zu 5% normalverteilt
81455,30049036normalverteilt
9   
104126,19581843zu 10% normalverteilt
11   
12314,50945294normalverteilt
13314,18442904normalverteilt
14316,42713696zu 1% normalverteilt
15   
161818,20037336zu 1% normalverteilt

Formeln der Tabelle
ZelleFormel
E6{=WENNFEHLER(WENN((B6>MAX(INDEX(Tabelle2!B:B;VERGLEICH(A6;Tabelle2!A:A)):INDEX(Tabelle2!E:E;VERGLEICH(A6;Tabelle2!A:A))))*(B6<MIN(INDEX(Tabelle2!F:F;VERGLEICH(A6;Tabelle2!A:A)):INDEX(Tabelle2!I:I;VERGLEICH(A6;Tabelle2!A:A)))); Tabelle2!S$3;SVERWEIS(INDEX(Tabelle2!$2:$2;1+VERGLEICH(MIN(ABS(INDEX(Tabelle2!B:B;VERGLEICH(A6;Tabelle2!A:A)):INDEX(Tabelle2!I:I;VERGLEICH(A6;Tabelle2!A:A))-B6)); ABS(INDEX(Tabelle2!B:B;VERGLEICH(A6;Tabelle2!A:A)):INDEX(Tabelle2!I:I;VERGLEICH(A6;Tabelle2!A:A))-B6); )); Tabelle2!L$4:S$7;8;)); "")}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruß Werner
.. , - ...

Bild

Betrifft: AW: jetzt ist es auch für mich verständlicher ...
von: eric
Geschrieben am: 25.08.2015 15:55:06
KLASSE!!! Der Thread kann definitiv zugemacht werden :))) Wirklich vielen vielen Dank Werner

 Bild

Beiträge aus den Excel-Beispielen zum Thema "Excel mit externen Daten befüllen in neuen Registe"